Люди помогите....

[Yurik]

Привет всем!!!
У меня такая трабла я сижу и не пойму почему у меня не получается реализовать такую штуку....

есть вот такая вот строка 1,2,3,4,5,11,3,18,2
надо чтобы прога сделал следующее с этой строкой --- она должна пошагово показать сначала 1 потом 2 потом 3 потом 4 и так далее до конечного числа в этой строке......короче говоря прога должна выдирать числа заключенные между запятыми и показывать их!

Плиз помогите я уже час зад праю!

[Yurik]

Кстати вот то, что я напарил....я решил что лучше сразу направить программу на сверку двух текстовых полей ..... то есть есть поле

1,2,11,5
и поле
2,5

программа приведенная ниже посути должна убрать из первой строки те числа после запятых, которые совпадают с числами из второй строки , в примере с этими строками программа должна убрать числа 2 и 5......

в проге приведенной ниже есть глюк она уберет 2 и все а 5 не трогает думаю ошибка в коде кнопки....но я пока не придумал как перелопатить код!!!!!!!!!

Код: Выделить всё

Public Function ReplaceStr(ByVal strMain As String, strFind As String, strReplace As String) As String
    Dim lngSpot As Long, lngNewSpot As Long, strLeft As String
    Dim strRight As String, strNew As String
    lngSpot& = InStr(LCase(strMain$), LCase(strFind$))
    lngNewSpot& = lngSpot&
    Do
        If lngNewSpot& > 0& Then
            strLeft$ = Left(strMain$, lngNewSpot& - 1)
            If lngSpot& + Len(strFind$) <= Len(strMain$) Then
                strRight$ = Right(strMain$, Len(strMain$) - lngNewSpot& - Len(strFind$) + 1)
            Else
                strRight = ""
            End If
            strNew$ = strLeft$ & strReplace$ & strRight$
            strMain$ = strNew$
        Else
            strNew$ = strMain$
        End If
        lngSpot& = lngNewSpot& + Len(strReplace$)
        If lngSpot& > 0 Then
            lngNewSpot& = InStr(lngSpot&, LCase(strMain$), LCase(strFind$))
        End If
    Loop Until lngNewSpot& < 1
    ReplaceStr$ = strNew$
End Function

Private Sub Command2_Click()
Dim i As Integer
For i = 1 To Len(Text2.Text)
    If Mid((Text2.Text), i, 1) = "," Then
        MsgBox Mid((Text2.Text), 1, i - 1)
        Text1.Text = ReplaceStr(Text1.Text, Mid((Text2.Text), 1, i - 1), "")
    End If
Next i
End Sub

Люди помогите!!!!!!1

[Rainbow]

Напишу, только проверить негде - так что не бей сильно

Код: Выделить всё

Dim arrNumbers() as String
arrNumbers = Split("1,2,3,4,5,6,7,8", ",")

Dim i as Long
For i = LBound(arrNumbers) to UBound(arrNumbers)
     msgbox arrNumbers(i)
Next

Короче, есть функция Split, которая принимает строку и разделитель. Переданную строку разобьет на части и вернет массив строк. Потом можешь по этому массиву пробежаться и делать с его элементами, что тебе заблагорасудится...

[Yurik]

2 Rainbow: Блин спасибо.....ох()еть как помог....все ша спать пойду вот что значит долго не програмить и ночью програмить.....такой спасительный оператор забыл....а может даже и не вспомнил если бы не ты!!!!

Спасибо выручил! Пойду Спать!
УРАААААААА!

[X-BOND]

Да, еще не все верят, что бывают девушки программеры....

[Rainbow]

Да ладно вам
Настоящие девушки-программеры - это действительно большая редкость А у нас на форуме, между прочим, если присмотреться, то девушек-программеров не так и мало

[Vi]

Кстати,

Код: Выделить всё

Private Sub Form_Load()
  Dim arrNumbers() As String, arrNumbers2() As String
  Dim res As String, i As Long
 
  arrNumbers = Split("1,2,11,5,33", ",")
  arrNumbers2 = Split("2,5", ",")
 
  For i = 0 To UBound(arrNumbers2)
    arrNumbers = Filter(arrNumbers, arrNumbers2(i), False)
  Next
  res = Join(arrNumbers, ",")
  Unload Me
End Sub


На выходе res == "1,11,33"

[alibek]

Обалдеть... Сколько живу, по функцию Filter() не слышал
Я знаю, Vi один из разработчиков VB

[Yurik]

Vi, ну а ты вообще меня удивил ...я про Filter вообще не знал до сегоднешнего дня.....

Блин спасибо всем!

[Rainbow]

Если честно, я тоже не слышала...

Но будь осторожен с Filter - уничтожит все вхождения
(протестируй на строчке "2,2,1,2,11,5,1222,33,55,5,5")

Я бы написала по-другому:

Код: Выделить всё

Dim str1 As String
Dim str2 As String
Dim sDelim As String
str1 = "2,2,1,2,11,5,1222,33,55,5,5"
str2 = "2,5"
sDelim = ","

Dim arrStr2() As String
arrStr2 = Split(str2, sDelim)

Dim i As Long, sFind As String
For i = LBound(arrStr2) To UBound(arrStr2)
    sFind = arrStr2(i)
   
    'уничтожить все внутренние вхождения
    str1 = Replace(str1, sDelim & sFind & sDelim, sDelim)

    'уничтожить вхождения в начале строки
    If Left$(str1, Len(sFind) + Len(sDelim)) = sFind & sDelim Then
        str1 = Right$(str1, Len(str1) - Len(sFind) - Len(sDelim))
    End If

    'уничтожить вхождения в конце строки
    If Right$(str1, Len(sFind) + Len(sDelim)) = sDelim & sFind Then
        str1 = Left$(str1, Len(str1) - Len(sFind) - Len(sDelim))
    End If
Next