узнать свой IP

[BOO]

установлено подключение через модем
как узнать свой IP адрес

[exit]

Смотришь свой IP а потом ищешь его в реестре. Способ конечно приметивный,но для начала сойдёт

[...PaWeL...]

winsock.localip

[Amed]

Пример с использованием Winsock API из API-Guide:

Код: Выделить всё

'In a form
Private Sub Form_Load()
    'KPD-Team 1999
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    MsgBox "IP-address: " + GetIPAddress
End Sub
'In a module
Public Const MIN_SOCKETS_REQD As Long = 1
Public Const WS_VERSION_REQD As Long = &H101
Public Const WS_VERSION_MAJOR As Long = WS_VERSION_REQD \ &H100 And &HFF&
Public Const WS_VERSION_MINOR As Long = WS_VERSION_REQD And &HFF&
Public Const SOCKET_ERROR As Long = -1
Public Const WSADESCRIPTION_LEN = 257
Public Const WSASYS_STATUS_LEN = 129
Public Const MAX_WSADescription = 256
Public Const MAX_WSASYSStatus = 128
Public Type WSAData
    wVersion As Integer
    wHighVersion As Integer
    szDescription(0 To MAX_WSADescription) As Byte
    szSystemStatus(0 To MAX_WSASYSStatus) As Byte
    wMaxSockets As Integer
    wMaxUDPDG As Integer
    dwVendorInfo As Long
End Type
Type WSADataInfo
    wVersion As Integer
    wHighVersion As Integer
    szDescription As String * WSADESCRIPTION_LEN
    szSystemStatus As String * WSASYS_STATUS_LEN
    iMaxSockets As Integer
    iMaxUdpDg As Integer
    lpVendorInfo As String
End Type
Public Type HOSTENT
    hName As Long
    hAliases As Long
    hAddrType As Integer
    hLen As Integer
    hAddrList As Long
End Type
Declare Function WSAStartupInfo Lib "WSOCK32" Alias "WSAStartup" (ByVal wVersionRequested As Integer, lpWSADATA As WSADataInfo) As Long
Declare Function WSACleanup Lib "WSOCK32" () As Long
Declare Function WSAGetLastError Lib "WSOCK32" () As Long
Declare Function WSAStartup Lib "WSOCK32" (ByVal wVersionRequired As Long, lpWSADATA As WSAData) As Long
Declare Function gethostname Lib "WSOCK32" (ByVal szHost As String, ByVal dwHostLen As Long) As Long
Declare Function gethostbyname Lib "WSOCK32" (ByVal szHost As String) As Long
Declare Sub CopyMemoryIP Lib "kernel32" Alias "RtlMoveMemory" (hpvDest As Any, ByVal hpvSource As Long, ByVal cbCopy As Long)
Public Function GetIPAddress() As String
    Dim sHostName As String * 256
    Dim lpHost As Long
    Dim HOST As HOSTENT
    Dim dwIPAddr As Long
    Dim tmpIPAddr() As Byte
    Dim I As Integer
    Dim sIPAddr As String
    If Not SocketsInitialize() Then
        GetIPAddress = ""
        Exit Function
    End If
    If gethostname(sHostName, 256) = SOCKET_ERROR Then
        GetIPAddress = ""
        MsgBox "Windows Sockets error " & Str$(WSAGetLastError()) & " has occurred. Unable to successfully get Host Name."
        SocketsCleanup
        Exit Function
    End If
    sHostName = Trim$(sHostName)
    lpHost = gethostbyname(sHostName)
    If lpHost = 0 Then
        GetIPAddress = ""
        MsgBox "Windows Sockets are not responding. " & "Unable to successfully get Host Name."
        SocketsCleanup
        Exit Function
    End If
    CopyMemoryIP HOST, lpHost, Len(HOST)
    CopyMemoryIP dwIPAddr, HOST.hAddrList, 4
    ReDim tmpIPAddr(1 To HOST.hLen)
    CopyMemoryIP tmpIPAddr(1), dwIPAddr, HOST.hLen
    For I = 1 To HOST.hLen
        sIPAddr = sIPAddr & tmpIPAddr(I) & "."
    Next
    GetIPAddress = Mid$(sIPAddr, 1, Len(sIPAddr) - 1)
    SocketsCleanup
End Function
Public Function GetIPHostName() As String
    Dim sHostName As String * 256
    If Not SocketsInitialize() Then
        GetIPHostName = ""
        Exit Function
    End If
    If gethostname(sHostName, 256) = SOCKET_ERROR Then
        GetIPHostName = ""
        MsgBox "Windows Sockets error " & Str$(WSAGetLastError()) & " has occurred. Unable to successfully get Host Name."
        SocketsCleanup
        Exit Function
    End If
    GetIPHostName = Left$(sHostName, InStr(sHostName, Chr(0)) - 1)
    SocketsCleanup
End Function
Public Function HiByte(ByVal wParam As Integer)
    HiByte = wParam \ &H100 And &HFF&
End Function
Public Function LoByte(ByVal wParam As Integer)
    LoByte = wParam And &HFF&
End Function
Public Sub SocketsCleanup()
    If WSACleanup() <> ERROR_SUCCESS Then
        MsgBox "Socket error occurred in Cleanup."
    End If
End Sub
Public Function SocketsInitialize() As Boolean
    Dim WSAD As WSAData
    Dim sLoByte As String
    Dim sHiByte As String
    If WSAStartup(WS_VERSION_REQD, WSAD) <> ERROR_SUCCESS Then
        MsgBox "The 32-bit Windows Socket is not responding."
        SocketsInitialize = False
        Exit Function
    End If
    If WSAD.wMaxSockets < MIN_SOCKETS_REQD Then
        MsgBox "This application requires a minimum of " & CStr(MIN_SOCKETS_REQD) & " supported sockets."
        SocketsInitialize = False
        Exit Function
    End If
    If LoByte(WSAD.wVersion) < WS_VERSION_MAJOR Or (LoByte(WSAD.wVersion) = WS_VERSION_MAJOR And HiByte(WSAD.wVersion) < WS_VERSION_MINOR) Then
        sHiByte = CStr(HiByte(WSAD.wVersion))
        sLoByte = CStr(LoByte(WSAD.wVersion))
        MsgBox "Sockets version " & sLoByte & "." & sHiByte & " is not supported by 32-bit Windows Sockets."
        SocketsInitialize = False
        Exit Function
    End If
    'must be OK, so lets do it
    SocketsInitialize = True
End Function

[RayShade]

2 exit

Риспект! Это просто 5 с плюсом!

"Как мне узнать свой IP"

"Очень просто - берешь свой IP и ищешь его в реестре".



Это что, пятница 13 так повлияла?

[GAGArin]

Скажи какая винда и зачем и я наверно скажу как решить проблемку (сам гамаюсь по модему чаще)

[BOO]

Если сам принимаешь входящие вызова там все ясно. Но вот если ты конектишся и тот комп дает тебе IP как его узнать???

[RayShade]

Какая разница. IP то все равно твой будет, локальный. Ты вот его и узнаешь

[exit]

2 RayShade
Я имел ввиду, что найдя свой IP в реестре запоминаешь путь и обращаешся туда, чтобы узнать IP. Работает естественно только для определённого соединения.

[alibek]

установлено подключение через модем
как узнать свой IP адрес

В консоли набираешь ipconfig /all

[sanches]

ну во-первых, при соединении "через модем просто" нет никаких там IP
а во-вторых, раз уж речь (скорее всего) идет об удаленном доступе, то есть такой значок в трее, на нем щелкаешь и вылезает коно, где у узнаешь свой IP.

[v-adix]

dim MyIP as string
myip = GetIpAddress

[GAGArin]

ну во-первых, при соединении "через модем просто" нет никаких там IP
а во-вторых, раз уж речь (скорее всего) идет об удаленном доступе, то есть такой значок в трее, на нем щелкаешь и вылезает коно, где у узнаешь свой IP.

Что значит нет там никаких IP если соеденение по TCP/IP?

А вообще обычно проще установить IP явным образом и сказать тому с кем соединяешся. А перед тем как в инет идти всё вернуть. А ещё проще поставить NETBEUI и не париться с IP

[Sirik]

Нет ничего проще!!!

Добавляешь в проект компоненту WinSock Control.
Кидаешь на форму, и дай имя, например WinS.

И всё: присваеваешь переменной ST (тип String) WinS.LocalIP
См. код:

Function OprIP() As String
Dim St As String
St = WinS.LocalIP
OprIP = St
End Function

Т.Е. вызов функции OprIP и есть твой IP

[RayShade]

2 Знающий

Нет ничего проще, чем сперва прочитать топик, а потом уже НЕ давать в него ответ, приведенный 10 постингами раньше

[v-adix]

2 Знающий
Нет ничего проще, чем сперва прочитать топик, а потом уже НЕ давать в него ответ, приведенный 10 постингами раньше

а ещё проще скачать модуль который я приаттачил и не использовать никакие винсоки чтобы их потом за собой не таскать. или спользовать написанный Amed'ом гдето там наверху пример из api guide

[Sirik]

Сказавшему ранее!!!

К Вашему сведению, я не читал, что написано выше.
Просто я высказал, то что давно и так знал. Тем более работая в сети - это и ... понятно.
А если тебя "грызнуло" незнание, купи книжки и почитай на досуге...

[Sirik]

Ray...

Я не читаю сказанного выше.
Просто из своего опыта написал. Сам так юзаю.
А, тебе, что завидно, что такое не знаешь что ли?

[RayShade]

Уважаемый... Не совсем понятна Ваша логика, приведшая Вас к такому рассуждению, однако мой Вам совет - читайте внимательно топики, в которые постите, это помогает избежать лишних вопросов.

[v-adix]

Ray...

Я не читаю сказанного выше.
Просто из своего опыта написал. Сам так юзаю.
А, тебе, что завидно, что такое не знаешь что ли?

1) слушай ты не единственный кто это знает!
2) да и насчёт твоего ответа: нафига человеку мозги пудришь со своей функцией когда можно написать MyIp=Wins.LocalIP ?
3) надо читать что написано выше

[BOO]

Хорош! Пора заканчивать бесмысленную болтавнюю, т.к. ответ написан в самом начале.


RayShade



закканчивай эту тему!!!

[RayShade]

Завершим тему еще одним примером узнавание IP адресов

Код: Выделить всё


set NICs = getobject("winmgmts:\\.").instancesof("Win32_NetworkAdapterConfiguration")
for each NIC in NICs
msgbox NIC.IPAddress
next