Работа с DC

[arechemist]

Подскажите пожалуйста:

Из пикчур бокса хочу перекопировать изображение в DC, а из него в другой пикчур.

Напишите пожалуйста код с коментариями для токого действия.
Сам писать пробовал, но че то не работает

[Rainbow]

А... зачем?
Почему ты не можешь просто скопировать?
Picture2.Picture = Picture1.Picture?

[Amed]

BitBlt Picture2.hdc, 0, 0, 100,100, Picture1.hdc, 0, 0, vbSrcCopy

"Другой hdc" и есть Picrure2.hdc, а иначе надо создавать новый... Что, в общем-то, не нужно...

[arechemist]

ДА не в этом дело, я просто хочу врубиться как создавать DC и с ним работать...
А задачку придумал просто как пример вот.
Напишите пожалуйста код с использованием DC

[Kostyan]

Вот тебе простой примерчик, помести на форму 2 Picturebox'а, поставь у них свойства AutoRedraw=True и ScaleMode=3(Pixel), в первый загрузи какой-нибудь рисунок. В форму вставь этот код:

Код: Выделить всё

Private Sub Command1_Click()
Call BitBlt(CompDC, 0, 0, Picture1.ScaleWidth, Picture1.ScaleHeight, Picture1.hdc, 0, 0, vbSrcCopy) 'Копируем изображение из Picture1 в DC
Call BitBlt(Picture2.hdc, 0, 0, Picture1.ScaleWidth, Picture1.ScaleHeight, CompDC, 0, 0, vbSrcCopy) 'Копируем изображение из DC в Picture2
Picture2.Refresh 'Обновляем Picture2
End Sub

Private Sub Form_Load()
CompDC = CreateCompatibleDC(Picture1.hdc) 'Создаём совместимый DC
OldBM = SelectObject(CompDC, Picture1.Picture) 'Создаем в нём поле для рисунка, по параметрам совподающее с Picture1.Picture
End Sub

Private Sub Form_Unload(Cancel As Integer)
Call SelectObject(CompDC, OldBM) 'Возвращаем старый рисунок в DC
Call DeleteDC(CompDC) 'Удаляем DC
End Sub


Добавь ещё можуль к проекту и встваь туда это:

Код: Выделить всё

Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long
Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long

Public OldBM As Long, CompDC As Long


При нажатии на кнопку изображение будет копироваться из Picture1 в созданный DC, а затем из него в Picture2.

[arechemist]

Kostyan, Спасибо большое!!!