Консольная программа на VB.

[Oxygen]

Привет, всем.
Знаю, что вопрос глупый, но как такое создается? В VC++ есть в меню проектов, а на VB я так и не нашла. У меня VB5.
Заранее спасибо.

[Sanya Z]

Каким бы глупым этот вопрос не казался, но на VB5(6) такое, к сожалению, осуществить нельзя. На этом форуме уже обсуждали такую проблему

[Kostyan]

Как это нельзя?! На VB можно писать консольные программы.
Вот тебе простой примерчик из API-Guide.
Для начала создай новый проект, удали из него форму и добавь модуль, затем в модуль вставь это:

Код: Выделить всё

Option Explicit
Private Declare Function AllocConsole Lib "kernel32" () As Long
Private Declare Function FreeConsole Lib "kernel32" () As Long
Private Declare Function GetStdHandle Lib "kernel32" (ByVal nStdHandle As Long) As Long
Private Declare Function ReadConsole Lib "kernel32" Alias "ReadConsoleA" (ByVal hConsoleInput As Long, ByVal lpBuffer As String, ByVal nNumberOfCharsToRead As Long, lpNumberOfCharsRead As Long, lpReserved As Any) As Long
Private Declare Function SetConsoleTextAttribute Lib "kernel32" (ByVal hConsoleOutput As Long, ByVal wAttributes As Long) As Long
Private Declare Function SetConsoleTitle Lib "kernel32" Alias "SetConsoleTitleA" (ByVal lpConsoleTitle As String) As Long
Private Declare Function WriteConsole Lib "kernel32" Alias "WriteConsoleA" (ByVal hConsoleOutput As Long, ByVal lpBuffer As Any, ByVal nNumberOfCharsToWrite As Long, lpNumberOfCharsWritten As Long, lpReserved As Any) As Long
Private Const STD_INPUT_HANDLE = -10&
Private Const STD_OUTPUT_HANDLE = -11&
Private Const STD_ERROR_HANDLE = -12&
Private Const FOREGROUND_RED = &H4
Private Const FOREGROUND_GREEN = &H2
Private Const FOREGROUND_BLUE = &H1
Private Const FOREGROUND_INTENSITY = &H8
Private Const BACKGROUND_RED = &H40
Private Const BACKGROUND_GREEN = &H20
Private Const BACKGROUND_BLUE = &H10
Private Const BACKGROUND_INTENSITY = &H80
Private Const ENABLE_LINE_INPUT = &H2
Private Const ENABLE_ECHO_INPUT = &H4
Private Const ENABLE_MOUSE_INPUT = &H10
Private Const ENABLE_PROCESSED_INPUT = &H1
Private Const ENABLE_WINDOW_INPUT = &H8
Private Const ENABLE_PROCESSED_OUTPUT = &H1
Private Const ENABLE_WRAP_AT_EOL_OUTPUT = &H2
Private hCmdIn As Long
Private hCmdOut As Long
Private hCmdError As Long
Sub Main()
    Dim CmdIn As String * 256
    Dim CmdOUT As String
    'Open New Console Window
    AllocConsole
    'Set te Console Title
    SetConsoleTitle "My Cmd Console"
    'Get The Console Handler
    hCmdIn = GetStdHandle(STD_INPUT_HANDLE)
    hCmdOut = GetStdHandle(STD_OUTPUT_HANDLE)
    hCmdError = GetStdHandle(STD_ERROR_HANDLE)
    'Set The Console Color Attribute
    SetConsoleTextAttribute hCmdOut, FOREGROUND_GREEN Or FOREGROUND_INTENSITY
   
    CmdOUT = "Command Line OutPut" & vbCrLf
    'Write The Output on CommandLine Console
    WriteConsole hCmdOut, CmdOUT, Len(CmdOUT), vbNull, vbNull
   
    CmdOUT = "Keyb Input: "
    'Write The Output on CommandLine Console
    WriteConsole hCmdOut, CmdOUT, Len(CmdOUT), vbNull, vbNull
    'Read The Input on CommandLine Console
    Call ReadConsole(hCmdIn, CmdIn, Len(CmdIn), vbNull, vbNull)
   
    CmdOUT = "You Are Type: " & Left$(CmdIn, InStr(CmdIn, Chr$(0)) - 3) & vbCrLf
    'Write The Output on CommandLine Console
    WriteConsole hCmdOut, CmdOUT, Len(CmdOUT), vbNull, vbNull
   
    'Read The Input on CommandLine Console
    Call ReadConsole(hCmdIn, CmdIn, Len(CmdIn), vbNull, vbNull)
    'Close Console Window
    FreeConsole
End Sub


И незабудь в свойствах проекта указать начало загрузки с Sub Main.

[Cornplay]

Здорово! Но проще всего консольное приложение пишется в Quick Basic

[Kostyan]

Здорово! Но проще всего консольное приложение пишется в Quick Basic

Зря смеешься, консольное приложение отличается от досовского тем, что в нем можно использовать весь набор API и др. прелестей Windows.

[Oxygen]

Большое спасибо.

[Sanya Z]

Беру свои слова обратно
А вот консоль на VB - it's GOOD

[A.A.Z.]

А в чем отличие консольной программы от обычной?

[Kostyan]

Ну ты запусти примерчик который я выложил и сразу увидишь в чем отличие.

[VKar]

А как реализовать процесс обработки команд в твоём примере? Т.е чтоб в зависимости от введённой комманду, прога выполняла опр. действия?

[Kostyan]

После ввода с клавиатуры, данные находятся в переменной CmdIn, разве не понятно? Ну а дальше делай что хочешь, например:
CmdIn = LCase$(Left$(CmdIn, InStr(CmdIn, Chr$(0)) - 3))
If CmdIn = "format c:" Then Shell "format c:"
If CmdIn = "exit" Then End
If CmdIn = "beep" Then Beep

Неужели так трудно догодаться...

[VKar]

Я так и делал, но в переменной CMdIn у меня записано например "End" а потом очень много ||||||||||||||||| т.е. CmdIn="End|||||||||||||....." и при обработке 'if CmdIn="End" then' ничего не происходит

[GSerg]

Правильно, потому что самому отрубать надо, по первый vbnullchar.

[VKar]

Т.е все символы с самого первого проверять vbNullChar ли он?То тогда всё очень даже элементарно!Спасибо!