Автовыгрузка

[Cellard]

Тут есть ветка параллельная, про громкость при выгрузке системы http://bbs.vbstreets.ru/viewtopic.php?t=5397

Хочу расширить вопрос. В MacOS есть, кроме автозагрузки, и автовыгрузка. Понятно, что там не выгружется что-либо, а запускается, но при выходе из системы. Вопрос о ее нужности я не поднимаю, а спрашиваю, есть ли у многоуважаемого All соображения о том, как это можно реализовать?

[Amed]

Да запросто.
1) Создаём папку вместе с Autorun, в неё кидаем ярлыи программ, запускающхся "на автовыгрузку"
2) Пишем программу, постоянно сидящую в памяти и постоянно невидимую.
3) На событие Form_Unload (когда Виндуза закрываются, форма тоже закроется ) вибираем Cancel=1, запускаем все проги, что в ярлычках валяются, выгружаем программу.
4) Обрабатываем кнопку Shift (отмена автоовыгрузки)

Вроде бы так...

[Cellard]

Да, это очевидное решение. Но как быть с тем, что Винда все таки уже выгружается и начнет выкидывать сообщения: "Жду завершения приложения"? Это ведь не очень красиво и, в конце концов, не гарантирует, что все приложения из Автовыгрузки успеют выполниться. Можно ли "сказать" ОС подождать с завершением?

И пара технических вопросов заодно.
Как для всех пользователей в папке "Главное меню" (это на русском, а еще есть и английский, и немецкий etc) создать папку "Shudup" (по аналогии со "Startup" )? Иначе говоря, как в переменных ОС называется эта папка (типа %блаблабла%). Причем для всех пользователей, для каждого пользователя и для пользователя по умолчанию.
И совем уж кондовый вопрос (уж простите, ни разу не делал): как запускать .lnk?

[Tamahawk]

1) Создаём папку вместе с Autorun, в неё кидаем ярлыи программ, запускающхся "на автовыгрузку"
2) Пишем программу, постоянно сидящую в памяти и постоянно невидимую.

Пробую так

Код: Выделить всё

Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
Cancel = True
End Sub

у меня получается.


виндаХР не выключается

[Amed]

Ну так Windows выключить надо вручную: вот примерчик из API-guide:

Код: Выделить всё

'In a module
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Type LUID
    LowPart As Long
    HighPart As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub
' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_SHUTDOWN
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Restart NT
Public Sub RebootNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_REBOOT
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Log off the current user
Public Sub LogOffNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_LOGOFF
    If Force Then Flags = Flags + EWX_FORCE
    ExitWindowsEx Flags, 0
End Sub

'In a form
'This project needs a form with three command buttons
Private Sub Command1_Click()
    LogOffNT True
End Sub
Private Sub Command2_Click()
    RebootNT True
End Sub
Private Sub Command3_Click()
    ShutDownNT True
End Sub
Private Sub Form_Load()
    'KPD-Team 2000
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Command1.Caption = "Log Off NT"
    Command2.Caption = "Reboot NT"
    Command3.Caption = "Shutdown NT"
End Sub

[Ilya Vasilyev]

Но как быть с тем, что Винда все таки уже выгружается и начнет выкидывать сообщения: "Жду завершения приложения"?
Есть ключи в реестре, отвечающие:
1. За время, после истечения которого и выдается это сообщение;
2. За свойство форсированного завершения приложения при истечении таймера ожидания (его можно попросту отключить)
Осталось найти эти ключи, и в первом случае временно увеличить значение, а во втором просто отключить форсированное завершение приложений...

[Cellard]

Спасибо, достаточно. Я уже все понял Спасибо.

Утилиту, кстати, таки напишу

Последнее, по поводу .lnk
Shell "cmd /c name.lnk" - работает. Но в этом случае бессмысленно отслеживать завершение работы приложения, cmd завершается сразу
А как, все таки, вынуть инфу из .lnk. Подскажет ли кто-нибудь, какой внутренний формат у этого файла?