про масштаб

[tatarin]

Что типа в этом роде:

Код: Выделить всё

Dim PointY() As Integer
Dim I As Integer
Dim kX As Single
Dim kY As Single
Dim HighPoint As Integer
Dim LastX As Integer
Dim LastY As Integer

Const PointsCount = 20


Private Sub Form_Load()
Randomize Timer
LastX = 0
LastY = Picture1.Height

ReDim PointY(1 To PointsCount) As Integer

For I = LBound(PointY) To UBound(PointY)
    PointY(I) = Int(Rnd * Picture1.Height \ 2)
Next I

kX = Picture1.Width / (UBound(PointY) - LBound(PointY))

For I = LBound(PointY) To UBound(PointY)
    If PointY(I) > HighPoint Then
        HighPoint = PointY(I)
    End If
Next I

kY = Picture1.Height / HighPoint / 2

For I = LBound(PointY) To UBound(PointY)
    Picture1.Line (LastX, LastY)-(I * kX, Picture1.Height - PointY(I) * kY), vbBlue
    LastX = I * kX
    LastY = Picture1.Height - PointY(I) * kY
Next I
End Sub

что это - че-то не разберусь... если можно - кратенько опишите

[Zoomie]

PointY - массив точек (а точнее их Y)
kX - коэффицент по X, т.е то расстояние между каждой точкой
kY - коэффицент по Y, служит для того чтобы самая высокая точка помещалась на графике
HighPoint - Y самой высокой точки
LastX - X предыдущей точки, служит для связывания 2х точек линией
LastY - Y предыдущей точки, служит для связывания 2х точек линией

Const PointsCount = 20 - константа, которой я задал кол-во точек

Код: Выделить всё

LastX = 0
LastY = Picture1.Height

Устанавливаем начальные координаты в нижний левый угол

Код: Выделить всё

ReDim PointY(1 To PointsCount) As Integer

Объявляем массив точек

Код: Выделить всё

For I = LBound(PointY) To UBound(PointY)
    PointY(I) = Int(Rnd * Picture1.Height \ 2)
Next I

Устанавливаем каждой точке случайные координаты

Код: Выделить всё

kX = Picture1.Width / (UBound(PointY) - LBound(PointY))

Получаем раастояние между точками по X,т.е. ширину делим на кол-во точек. UBound - верхняя граница массива, LBound - нижняя

Код: Выделить всё

For I = LBound(PointY) To UBound(PointY)
    If PointY(I) > HighPoint Then
        HighPoint = PointY(I)
    End If
Next I

Ищем Y самой высокой точки.

Код: Выделить всё

kY = Picture1.Height / HighPoint / 2

Устанавливаем коэф. kY.

Код: Выделить всё

For I = LBound(PointY) To UBound(PointY)
    Picture1.Line (LastX, LastY)-(I * kX, Picture1.Height - PointY(I) * kY), vbBlue
    LastX = I * kX
    LastY = Picture1.Height - PointY(I) * kY
Next I

Рисуем график






[/b]

[_Step_]

А почему забываем про свойство SCALE ??? Удобно ведь им пользоватся!

[Zoomie]

Конечно Scale мщжет многое упростить