НОРМАЛЬНОЕ выключение компбютера

[SeT]

Лично я знаю 3 способа выключить компьютер:
1:
Dim strComputer As String
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & _
"{impersonationLevel=impersonate,(Shutdown)}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery( _
"Select * from Win32_OperatingSystem")
For Each ObjOperatingSystem In colOperatingSystems
ObjOperatingSystem.ShutDown
Next
2:
Через функцию ExitWindowsEx()
3: Просто запустить "%windir%\system32\shutdown.exe -s -f -t 01"
Но во всех трёх случаях в XP в конце появляется уведомление, что "ВОТ ТЕПЕРЬ ПИТАНИЕ КОМПЬЮТЕРА МОЖНО ОТКЛЮЧИТЬ". Как можно всё-таки полностью выключить компьютер?

[tyomitch]

Если материнка этого не поддерживает - то никак.
Видимо, не поддерживает, раз появляется это уведомление.

[SeT]

Не, ну пообычному через ЗАВЕРШЕНИЕ РАБОТЫ получается выключить. XP Tweaker тоже нормально выключает. А как на Бейсике выключить по нормальному компьютер?

[AjaxVS]

"ВОТ ТЕПЕРЬ ПИТАНИЕ КОМПЬЮТЕРА МОЖНО ОТКЛЮЧИТЬ"

Такое сообщение выдается, вроде, при выключенной виндовой опции "Управление питанием" или что-то типа этого...
Может, ты перед тем, как выключить комп программно в ВБ, каким то образом эту галочку выключаешь? +_+

Ну просто понимаешь... ну не может такого быть +_+

[Twister]

Такое сообщение выдается, вроде, при выключенной виндовой опции "Управление питанием" или что-то типа этого...

А по-моему оно выдается в зависимости от того, какое железо...

[seelts]

Может быть...
В ExitWindowsEx различаются EWX_POWEROFF и EWX_SHUTDOWN. В первом случае омпьютер выключается, во втором доводится до состояния когда питание можно выключить...

[seelts]

В Вин9х
Shell "RUNDLL.EXE" + " user.exe,exitwindows"
вроде работало

[Ruslan Demidow]

Если материнка этого не поддерживает - то никак.
Видимо, не поддерживает, раз появляется это уведомление.

У меня на работе есть компьютер, который с кнопки выключается нормально, а вот если его выключить по сети через shutdown - он как раз и выводит такое сообщение.
Так что не факт, что от железа.

P.S. Винда на том компе 2000-ая. И он в домене.

[SeT]

Не, не от железа. Я же тремя способами выключаю, и всё равно одно и тоже.

[seelts]

можно сделать так: просто через свою прогу навести мышь на "пуск", нажать, навести на "выключение" итд... это даже красивее будет и точно сработает

[alibek]

Флаг надо устанавливать в ExitWindowEx. А вот какой, уже не помню, было на старом форуме.

В MSDN, в поиск, там есть статья на эту тему. Для поиска задай сообщение "Теперь питание можно выключать" (только на английском).

[extHack]

Exitwindows сдохла в xp
лучше через wmi выключать

[hCORe]

Она не сдохла. Просто для выруба компа теперь нужны привилегии (конкретно - SE_SHUTDOWN_NAME).

Флаг

Код: Выделить всё

EWX_FORCE Or EWX_POWEROFF

не решает проблемы?

[-=TsA=-]

Код: Выделить всё

Option Explicit
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const EWX_POWEROFF = 8
Private Const EWX_FORCEIFHUNG = 16

Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type

Type LUID
    LowPart As Long
    HighPart As Long
End Type

Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type

Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long

Sub Main()
    Dim CmdLine As String
    CmdLine = UCase$(Trim$(Command()))
    Select Case CmdLine
        Case "/L"
            Call LogOff
        Case "/R"
            Call ReBoot
        Case "/S"
            Call Shutdown
        Case "/P"
            Call PowerOff
        Case Else
            Call MsgBox("/L - Завершение сеанса" & vbCrLf & "/R - Перезагрузка" & vbCrLf & "/S - Завершение работы" & vbCrLf & "/P - Выключить питание", vbInformation + vbOKOnly, "Ключи командной строки")
    End Select
    End
End Sub

Function GetCommandLine(Optional MaxArgs)
    Dim C, CmdLine, CmdLnLen, InArg, I, NumArgs
    If IsMissing(MaxArgs) Then MaxArgs = 10
    'Приводим массив в корректный размер
    ReDim ArgArray(MaxArgs)
    NumArgs = 0: InArg = False
    'Получаем аргументы с командной строки.
    CmdLine = Command()
    CmdLnLen = Len(CmdLine)
    'Перемещаемся по всем символам в командной строке
    For I = 1 To CmdLnLen
        C = Mid(CmdLine, I, 1)
        'Тестируем на пробел или символ табуляции.
        If (C <> " " And C <> vbTab) Then
        'Если ни то и ни другое.
        'Тест на текущий аргумент.
        If Not InArg Then
        'Новый аргумент начался.
        'Тестируем на слишком большое кол-во аргументов.
        If NumArgs = MaxArgs Then Exit For
            NumArgs = NumArgs + 1
            InArg = True
        End If
            'Соединение символа с текущим аргументом.
            ArgArray(NumArgs) = ArgArray(NumArgs) & C
        Else
        'Ищем пробел или символ табуляции.
        InArg = False
        End If
    Next I
    ReDim Preserve ArgArray(NumArgs)
    'Возвращаем массив как результат ф-ции.
    GetCommandLine = ArgArray()
End Function


'Detect if the program is running under Windows NT
Private Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    Call GetVersionEx(myOS)
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function

'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    Call OpenProcessToken(hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken)
    Call LookupPrivilegeValue("", "SeShutdownPrivilege", mLUID)
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    Call AdjustTokenPrivileges(hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount))
End Sub

' Shutdown
Public Sub Shutdown()
    If IsWinNT Then
        Call EnableShutDown
    End If
    Call ExitWindowsEx(EWX_SHUTDOWN + EWX_FORCE, 0)
End Sub

' PowerOff
Public Sub PowerOff()
    If IsWinNT Then
        Call EnableShutDown
    End If
    Call ExitWindowsEx(EWX_POWEROFF + EWX_FORCE, 0)
End Sub

'ReBoot
Public Sub ReBoot()
    If IsWinNT Then
        Call EnableShutDown
    End If
    Call ExitWindowsEx(EWX_REBOOT + EWX_FORCE, 0)
End Sub

'Log Off
Public Sub LogOff()
    Call ExitWindowsEx(EWX_LOGOFF + EWX_FORCE, 0)
End Sub



PS Без комментариев