Методики построения палитры цветов

[Cryonyx]

Привет всем. Собственно, несколько вопросов кроме сабжа:
1. Как строить цвета не на основе функции RGB, а, скажем, по Hue./Sat./Lum. (эта фишка реализована во всех графических редакторах, даже в Пайнте)
2. Можно ли устроить при помощи DirectX или других способов быструю перерисовку рабочей области, где собственно и сторится палитра (допустим, это некий пикчербокс)? Перерисовка средствами VB меня не устраивает, так как она слишком медленная
3. Как сделать палитру в 3D? (Ну, к примеру, есть у нас некая объёмная сфера,и нужно на её поверхности разместить все возможные цвета)

Пока это всё, что пришло на ум. По мере поступления буду ещё дописывать вопросы

[alibek]

А вопросы в чем?

Цветовые пространства описаны тут: http://www.easyrgb.com/math.html

[Cryonyx]

Кхм. Это немного не то. За ссылку, конечно, спасибо. Пригодится.
Но меня больше интересует то, как можно мостроить палитру всех цветов на небольшом (относительно) пикчербоксе (хотя бы как в стандартном окошке выбора цвета)..

[tyomitch]

А никак.
В стандартном окошке выбора цвета далеко не все цвета нарисованы. Это невозможно: их 16 миллионов.
Именно поэтому оно состоит из поля и слайдера, а не одного поля.

[Cryonyx]

Оке. А как реализовать хотя бы такое окошко?

[GSerg]

Поюзать прямо его же?

[Cryonyx]

Не, это-то мне и не интересно. Я хочу реализовать подобное сам, а для этого мне нужно понять, каким образом строится данна палитра.

[GSerg]

GradientFill?

[Cryonyx]

Можно поподробней?
Хотя я думаю, что это вряд ли будет то, что надо, ведь на той же палитре в пайнт не градиентная заливка, а фиг знает что (либо градиент в 3D )

[GSerg]

Дык задавай сколько надо точек градиента, и вперёд...

[Cryonyx]

Ламоботский вопорс: как?
Я пока умею только обычный град делать

[tyomitch]

Держи прототип пикера.

Код: Выделить всё

Option Explicit
Private Declare Function ColorHLSToRGB Lib "shlwapi" (ByVal wHue As Integer, ByVal wLuminance As Integer, ByVal wSaturation As Integer) As Long
Private Hue As Integer, Saturation As Integer

Private Sub Form_Load()
Width = 256 * Screen.TwipsPerPixelX + (Width - ScaleWidth)
Height = 256 * Screen.TwipsPerPixelY + (Height - ScaleHeight)
AutoRedraw = True: ScaleMode = vbPixels
For Hue = 0 To 239
    For Saturation = 0 To 239
        PSet (Hue, 239 - Saturation), ColorHLSToRGB(Hue, 120, Saturation)
    Next
Next
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Y < 240 Then
    If X < 240 Then
        Hue = X
        Saturation = 239 - Y
        Dim Luminance As Integer
        For Luminance = 0 To 239
            Line (240, 239 - Luminance)-(255, 239 - Luminance), ColorHLSToRGB(Hue, Luminance, Saturation)
        Next
    ElseIf Y < 256 Then
        Line (0, 240)-(255, 255), ColorHLSToRGB(Hue, Y, Saturation), BF
    End If
End If
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button Then Form_MouseDown Button, Shift, X, Y
End Sub


"Падибагал, спасибо." (c)

[BV]

2 tyomitch

Цвет можно брать и с GetPixel.

Да... Ещё у тебя нужно 256 - Y считать, а не Y.

[tyomitch]

Цвет можно брать и с GetPixel.

Угу. И что с ним дальше делать? Переводить в HSL, а потом обратно?

[BV]

Зачем? Я говорил про эту строчку:

Код: Выделить всё

Line (0, 240)-(255, 255), ColorHLSToRGB(Hue, Y, Saturation), BF

[tyomitch]

Ладно, ладно, я ступил.
Падибаганый вариант:

Код: Выделить всё

Option Explicit
Private Declare Function ColorHLSToRGB Lib "shlwapi" (ByVal wHue As Integer, ByVal wLuminance As Integer, ByVal wSaturation As Integer) As Long

Private Sub Form_Load()
Width = 256 * Screen.TwipsPerPixelX + (Width - ScaleWidth)
Height = 256 * Screen.TwipsPerPixelY + (Height - ScaleHeight)
AutoRedraw = True: ScaleMode = vbPixels
Dim Hue As Integer, Saturation As Integer
For Hue = 0 To 239
    For Saturation = 1 To 239
        PSet (Hue, 239 - Saturation), ColorHLSToRGB(Hue, 120, Saturation)
    Next
Next
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Y < 240 Then
    If X < 240 Then
        Dim Luminance As Integer
        For Luminance = 1 To 239
            Line (240, 239 - Luminance)-(255, 239 - Luminance), ColorHLSToRGB(X, Luminance, 239 - Y)
        Next
    ElseIf Y < 256 Then
        Line (0, 240)-(255, 255), Point(X, Y), BF
    End If
End If
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button Then Form_MouseDown Button, Shift, X, Y
End Sub


[SHURUP]

Конечно знать как делать такую картинку полезно, но ИМХО в программе его лучше не строить а просто загрузить из файла или ресурса (быстрее будет)

[tyomitch]

Стандартный пикер строит (один раз при загрузке).
Наверное, его авторы лучше знают, как лучше.

[Cryonyx]

Слушайте, а почему все значения HLS колеблются в диапазоне [0;239], а не [0;255]
Я, конечно понимаю, что если подставить значания вне этого диапазона, получаются весьма занятные результаты с интересными побочными эффектами , но всё же почему

[Amed]

Формула для пересчета цвета из HLS в RGB какая там?

[Cryonyx]

Ты меня спрашиваешь?
Я б тоже хотел это знать

[tyomitch]

Слушайте, а почему все значения HLS колеблются в диапазоне [0;239], а не [0;255]

По прихоти MS, имхо. Больше непочему.

Почему в часе 60 минут, а не 80? Потому же: кому-то так захотелось.

[alibek]

Почему в часе 60 минут, а не 80? Потому же: кому-то так захотелось.

Вовсе нет
Это наследие одной древней 60-ричной системы исчисления.

[alibek]

Слушайте, а почему все значения HLS колеблются в диапазоне [0;239], а не [0;255]

Потому что 240 делится нацело на шесть, а 256 нет.

[tyomitch]

alibek, а почему не 252 тогда? Тем более, частное получается символичное...

[alibek]

Потому что 240 допускает больше целых степеней деления Т.е. "правильные" цвета выражаются целыми числами.
240 можно разделить нацело на 2, на 3, на 4, на 5, на 6, на 8, на 10, на 12, на 16, на 20, на 24, на 30, на 40, на 60, на 80, на 120. Ни у какого другого числа нету стольки делителей.

[BV]

2 alibek

Сам догадался? Или есть ссылка на тему?

[alibek]

Сам, все сам.

[Info_m.be_free]

Я когда то занимался этим вопросом - самое простое - действительно брать готовую палитру и с нее стягивать цвета, формулы перевода РГБ в HSB, HLS, HSV и другие проще искать на сайтах фотошопщиков... но есть один момент который я нарыл - человеческий глаз воспринимает цвета по разному поэтому для построения хорошей палитры недостаточно одной формулы преобразования.

[Cryonyx]

Ну хорошо, с виндовой палитрой мы разобрались. Может тогда есть у кого идеи, как сделать палитру а-ля фотошоп (стандартная)
просто реально интересно узнать, как всё это делается "у больших дядечек" (с)