Коллекция коллекций коллекций ...коллекций...

[newonline]

Если все будут искать в яндексе, Вам, господа хакеры, не над кем будет поиздеваться...

Нужна подсказка. Хочу (но пока немогу) реализовать такую мульку:

Создаю экземпляр объекта, этот экзмпляр содержит свойство имени, и еще кое-какие, а так же содержит коллекцию, в которую можно вновь добавить такой же экземпляр класса, который опять содержит коллекцию, в которую снова можно положить экземпляр... и т.д. Уровень вложенности - Long, пока оперативка не сдохнет.
Вообщем структура диска, в котором объекты - это файлы и папки., свойство имя - это соответственно имя файла или папки...

Это сложно сделать?

[tyomitch]

Это сложно сделать?

Нет.

[Amed]

Создай модуль класса
В нем напиши

Код: Выделить всё

Public x As clsBasic
Public sName as string
Public Param1 as string
'...
'...
'...


В коде формы пишешь

Код: Выделить всё

Dim x As clsBasic

Set x = New clsBasic

Смотри свойства x

[newonline]

Создай модуль класса
В нем напиши

Код: Выделить всё

Public x As clsBasic
Public sName as string
Public Param1 as string
'...
'...
'...


В коде формы пишешь

Код: Выделить всё

Dim x As clsBasic

Set x = New clsBasic

Смотри свойства x

А где же Collection?

[Amed]

Не мне же все писать. Шевели серым веществом

[d3drm]

Не мне же все писать. Шевели серым веществом

или коричневым...

[Amed]

Советую взять палочку

[newonline]

Оно не шевелится... почему-то

Ну объясни, я ниче не понял...(не про палочкы, а про коллекции)

[d3drm]

коллекции палочек

[newonline]

ну хорошш уже, злАдеи.
Me.подскажите.
где же автосписок коллекции (только не серых палочек)?
нY очинь нада!!!!!!!!!!!

[tyomitch]

newonline, найди в MSDN статьи под названиями "Public Collection Example: The House of Straw", "Private Collection Example: The House of Sticks", и "Creating Your Own Collection Class: The House of Bricks". Они как раз про то, что тебе нужно.
Непонятные слова из статей можешь посмотреть в Яндексе.

[newonline]

А я вот создаю телевизор который показывает телевизор , который показывает телевизор , который показывает телевизор ......

во-во, тусани-ка исходничек

[Worobjoff]

Модуль класса clsFileColl

Код: Выделить всё

Option Explicit

Private mCol As Collection
Private m_Name As String
Private m_objParent As clsFileColl

Public Property Get Name() As String
   Name = m_Name
End Property
Public Property Let Name(ByVal New_Value As String)
   m_Name = New_Value
End Property

Public Property Get objParent() As clsFileColl
   Set objParent = m_objParent
End Property
Public Property Let objParent(ByVal New_Value As clsFileColl)
   Set m_objParent = New_Value
End Property

Public Function Add(ByVal Name As String) As clsFileColl
   Dim ob As clsFileColl
   Set ob = New clsFileColl
   ob.Name = Name
   ob.objParent = Me
   mCol.Add ob, Name
   Set Add = ob
   Set ob = Nothing
End Function

Public Property Get Item(vntIndexKey As Variant) As clsFileColl
   Set Item = mCol(vntIndexKey)
End Property

Public Property Get Count() As Long
   Count = mCol.Count
End Property

Public Sub Remove(vntIndexKey As Variant)
    mCol.Remove vntIndexKey
End Sub

Public Property Get NewEnum() As IUnknown
    Set NewEnum = mCol.[_NewEnum]
End Property

Private Sub Class_Initialize()
   Set mCol = New Collection
End Sub

Private Sub Class_Terminate()
   Set mCol = Nothing
End Sub

Тест класса

Код: Выделить всё

Private Sub Command1_Click()
   Dim i As Long, j As Long, k As Long
   Dim ob1 As clsFileColl
   Dim s As String
   
   Set ob1 = New clsFileColl
   ob1.Name = "Root"
   For i = 1 To 3
      With ob1.Add("Level2_Item_" & i)
         For j = 1 To 3
            With .Add("Level3_Item_" & j)
               For k = 1 To 3
                  .Add ("Level4_Item_" & k)
               Next
            End With
         Next
      End With
   Next
   
   s = ob1.Name
   For i = 1 To ob1.Count
      s = s & vbCrLf & vbTab & ob1(i).Name
      For j = 1 To ob1(i).Count
         s = s & vbCrLf & vbTab & vbTab & ob1.Item(i).Item(j).Name
         For k = 1 To ob1(i).Item(j).Count
            s = s & vbCrLf & vbTab & vbTab & vbTab & ob1.Item(i).Item(j).Item(k).Name
         Next
      Next
   Next
   Set ob1 = Nothing
   
   MsgBox s
End Sub

Сделано визардом, слегка поправлено.

[tyomitch]

Worobjoff, ты забыл указать, как надо Procedure Attributes расставить, чтобы заработало...