Ручное формирование .res файлов

[tyomitch]

Близко к тому, чтобы заработало

Странный прикол с выводом строк: если пишешь

Код: Выделить всё

Open "H:\a.bin" For Binary As #1
    Put #1, , StrConv("Hello", vbUnicode)
    Put #1, , "-- delimiter --"
    Dim s As String
    s = StrConv("Hello", vbUnicode)
    Put #1, , s
Close

То в a.bin будет (hex):
08 00 0A 00 48 00 65 00 6C 00 6C 00 6F 00 2D 2D
20 64 65 6C 69 6D 69 74 72 20 2D 2D 48 00 65
00 6C 00 6C 00 6F 00

Жирным выделена сама строка "Hello" в Unicode, подчеркнут заголовок Unicode-строки.

То есть, если пишем

Код: Выделить всё

Put #1, , StrConv("Hello", vbUnicode)

- то получаем полноценный Юникод, а если

Код: Выделить всё

Dim s As String
s = StrConv("Hello", vbUnicode)

- то полноценный ANSI с Unicode-кодированием "внутри".

Забавно... Из-за этого и глючила запись строк. Теперь, вроде, поправил. Как только что-нибудь заработает - сразу выложу рабочую версию. ОК?

Только при чём тут строки?
Открываем Object Browser, видим:

Function StrConv(String, Conversion As VbStrConv, [LocaleID As Long])

Обращаем внимание, что она возвращает Variant.

Т.е. в первом случае ты пишешь в файл вариант, а во втором - строку. Никаких чудес.

[hCORe]

А ты думал?!..

[BV]

А что бы вам ICQ не завести-то?...

[hCORe]

BV:
1) Мне самому интересно, чем все это кончится.
2) Хочу, чтобы все остальные узнали, как правильно писать стрингтейблы в файл ресурсов.
3) Лениво заводить ICQ.
______________

Модифицированная версия. Пишет всего две строчки (английскую и русскую) в .res-файл. Длина - 96 байт. Т.е. кратна 32. Нет! Не работает! Зато файл, сгенерированный стандартным редактором ресурсов, имеет длину в 116 байт (не кратную 32) и отлично открывается.

Думаю, нужно делать паддинг для каждой строки.
А еще - у меня неправильно подсчитывается длина данных. Длину паддинга я НЕ добавляю!

Исходники прилагаются.

[tyomitch]

А ты думал?!..

Да, я думал.



Сейчас посмотрю новую версию.

[tyomitch]

Вот так работает

Код: Выделить всё

Comparing files Form1.frm and FORM1.NEW
***** Form1.frm
Private Sub Form_Load()
    Dim strings(1) As String
    Dim i As Integer
***** FORM1.NEW
Private Sub Form_Load()
'Ты же сам только что квотил, что строк должно быть ровно 16?
    Dim strings(15) As String
    Dim i As Integer
*****

***** Form1.frm

    For i = 0 To 1
        rh.datasize = rh.datasize + LenB(strings(i))
***** FORM1.NEW

    For i = LBound(strings) To UBound(strings)
        rh.datasize = rh.datasize + LenB(strings(i))
*****

***** Form1.frm

    For i = 0 To 1
        Put #l, , CInt(Len(strings(i)))
        strings(i) = StrConv(strings(i), vbUnicode)
        Put #l, , strings(i)
    Next i
***** FORM1.NEW

    For i = LBound(strings) To UBound(strings)
        Put #l, , CInt(Len(strings(i)))
        Put #l, , CStr(StrConv(strings(i), vbUnicode))
    Next i
*****

***** Form1.frm

    Dim p As Long
    p = 32 - (LOF(l) Mod 32)
    If p = 32 Then p = 0
    Put #l, LOF(l) + p, CByte(0)
    Close #l
***** FORM1.NEW

' Выравниваться должны заголовки, а не конец файла
'    Dim p As Long
'    p = 32 - (LOF(l) Mod 32)
'    If p = 32 Then p = 0
'    Put #l, LOF(l) + p, CByte(0)
    Close #l
*****


[hCORe]

Теперь дошло... Буду писать версию с двумя таблицами.

Скоро выложу.

[hCORe]

Выкладываю новую версию. Работает, но чуть кривовато. Сравниваем ресурс "Embedded into the Library.res" и сгенерированный программой из библиотеки "language1033.dll" ресурс. Все строки из исходного файла есть, но находятся в неправильном порядке (по ID). Странно...

[tyomitch]

Все строки из исходного файла есть, но находятся в неправильном порядке (по ID). Странно...

Не просто в неправильном, а в противоположном.
Запусти цикл в другую сторону, что ли?

[hCORe]

И точно...
Поправим!

[hCORe]

Поправлено. Зато - не работает на совершенно пустяковом проекте.

Мое мнение: надо делать паддинг для заголовков (RESHEADER). Другой вопрос - как определить, что он нужен...

Проект прилагается:

[tyomitch]

Мое мнение: надо делать паддинг для заголовков (RESHEADER). Другой вопрос - как определить, что он нужен...

Дык он всегда нужен.
Перед концом файла - не нужен. А перед заголовком - всегда нужен.
Вроде бы, это было в твоём мануале указано?

[Shura]

Меня сюда tyomitch направил, говорит мы тут проект разрулили по строковым ресурсам. Я и поверил Скачал - не работает . Тогда мессаги уже читать взялся и тут увидел что... Только вы не обижайтесь, бывалые и продвинутые, но вы тут просто уже заработались до зеленых чертиков
Это ж надо было до такого додуматься - DWORD превратить в 32 байта!!! И обсуждают, чтобы еще такого по ним выровнять. Фестиваль юмора просто, повеселили старика, спасибо вам, ребята.

Будем смотреть дальше. А вообще нужно бы добавить элементарную, но очень (мне по крайней мере) оказавшуюся нужной фичу - указание локали для генерируемой Unicode строки. Благо в VB6 (в VB5 еще не было) делается это элементарно:

Код: Выделить всё

Put #l, , CStr(StrConv(arrStrings(i), vbUnicode, НужнаяНамЛокаль))

PS Нравится мне этот форум: до сих пор мой ник еще никто не занял

[hCORe]

До фиолетовых чертиков заработались. Я уже даже не помню, работает мой последний вариант (не выложенный сюда) или нет...

[Shura]

До фиолетовых чертиков заработались. Я уже даже не помню, работает мой последний вариант (не выложенный сюда) или нет...

О том, который не выложен, я не знаю, а вот LocaHelper3.rar не работает точно. Ему как минимум не хватает вот такой корректировки:

Код: Выделить всё

...
        rh.headersize = Len(rh)
       
        Dim newPos&
        newPos = Seek(1)
        newPos = newPos + IIf(((newPos - 1) Mod 4), 4 - (newPos - 1) Mod 4, 0)
       
        Put #l, newPos, rh
        For i = a To b
            Put #l, , CInt(Len(arrStrings(i)))
            Put #l, , CStr(StrConv(arrStrings(i), vbUnicode))
        Next i

[hCORe]

LocaHelper 3 доработан. Мой способ несколько другой. Я дописываю паддинг в конец. Вот полный вариант процедуры CreateRes модуля mdlLanguage:

Код: Выделить всё

Public Sub CreateRes(sPath As String, arr() As String)

    Dim rh As RESHEADER
   
    Dim l As Byte
    l = FreeFile
    On Error Resume Next
    Kill sPath
    Err.Clear
    Open sPath For Binary As #l
   
    'пустой заголовок - 16 байт
    Dim sc(31) As Byte
    sc(0) = 0
    sc(1) = 0
    sc(2) = 0
    sc(3) = 0
    sc(4) = &H20
    sc(5) = 0
    sc(6) = 0
    sc(7) = 0
    sc(8) = &HFF
    sc(9) = &HFF
    sc(10) = 0
    sc(11) = 0
    sc(12) = &HFF
    sc(13) = &HFF
    sc(14) = 0
    sc(15) = 0
   
    Dim f As Long
       
    Put #l, , sc
   
    Dim a As Long, b As Long, c As Long, i As Long, z As Long
       
    a = 0
    b = 15
    c = 7
   
    Dim arrStrings() As String
   
    Dim v As Long
   
    Const ZZA As Integer = 5        'количество строк до 101 - 1
   
    If (UBound(arr) - LBound(arr) + ZZA) Mod 16 <> 0 Then
        z = 16 - (UBound(arr) - LBound(arr) + ZZA) Mod 16 - 1
    Else
        z = UBound(arr) - LBound(arr) + ZZA - 1
    End If
   
    ReDim Preserve arrStrings(0 To UBound(arr) - LBound(arr) + z + ZZA)
   
    For i = LBound(arr) To UBound(arr)
        arrStrings(ZZA + i - LBound(arr)) = arr(i)
    Next
   
       
    Do
       
        rh.datasize = 0
       
        For i = a To b
            rh.datasize = rh.datasize + LenB(arrStrings(i))
        Next
       
        'плюс информационные поля для строк
        rh.datasize = rh.datasize + 32
       
        rh.dataversion = 0
        rh.flags = 0
        rh.id = CLng("&H" & Hex$(c) & "FFFF")     'таблица c
        rh.language = 0     'lang neutral, sublang neutral
        rh.type = &H6FFFF   'RT_STRING
        rh.headersize = Len(rh)
               
        Put #l, , rh
        For i = a To b
            Put #l, , CInt(Len(arrStrings(i)))
            Put #l, , CStr(StrConv(arrStrings(i), vbUnicode))
        Next i
        a = a + 16
        b = b + 16
        c = c + 1
       
        'выравнивание по границам DWORD (32 бита [4 байта])
        Dim j As Long
        j = 4 - LOF(l) Mod 4
        If j = 4 Then j = 0
        Put #l, LOF(l) + j, CByte(0)
       
    Loop Until a >= UBound(arrStrings) + 1
       
    Close #l

End Sub

На всех примерах, что у меня есть, работает. Правильно говорил кто-то из писателей: чтобы решить проблемы с материалом, надо дать ему "отлежаться".

[Shura]

LocaHelper 3 доработан. Мой способ несколько другой. Я дописываю паддинг в конец.

Хрен редьки не слаще . Хотя обычно, говоря о выравнивании, имеют ввиду выравнивание именно вначале.
Ну, так что, ты дальше русификации ресурсов не собираешься идти? Например в локализацию на другие языки. Вот у меня тут были проблемы с Немецкими ресурсами. Все хваленые компиляторы (например тот же Resource Builder) обломались правильно их cкомпилить, только микрософтовский RC.exe смог, да и то только после добавления весьма экзотической (не описанной даже в его справке) директивы в RC-скрипт.

[hCORe]

Хрен, конечно, редьки не слаще, но работает. А другой язык можно задать через rh.language и в третьем параметре StrConv. Дальше я идти собираюсь, но на данный момент меня вполне устраивает версия "альфа", которую я доделал полчаса назад.

[Shura]

А другой язык можно задать через rh.language и в третьем параметре StrConv..

Сначала наступи на эти грабли, а потом уж говори. rh.language всего-лишь запишет пару байтиков в заголовок ресурса, но никак не изменит Unicode строк в ресурсе. Да и с чего они будут меняться-то? А третий параметр в StrConv - рулит.

Ладно, буду сам под себя переписывать код, как и предполагалось, собсна, изначально.

[hCORe]

Я и сказал: rh.language установит атрибут языка, а StrConv позволит нормально записать национальные символы этого языка.

[hCORe]

Когда сделаешь проект для себя, выложи для других. Очень уж хочется посмотреть

[Shura]

Я и сказал: rh.language установит атрибут языка, а StrConv позволит нормально записать национальные символы этого языка.

Мне как раз и не нужен был немецкий атрибут (меня нейтральный вполне устраивает), мне главное, чтобы у немцев строки немецкие были видны, а не киргуду (умляуты немецкие пропадают, точнее подменяются на символы ?).

Когда сделаешь проект для себя, выложи для других. Очень уж хочется посмотреть

С какой стати? Я же буду делать его для себя. Да и тебе он не понравится, ибо ничего смешного там не будет (например 32 байтных DWORD-ов .