Collection из своего типа

[Tolking]

Прошу прощения за вопрос, который описан везде, где только можно, но я туплю:

в Declarations пишу

Код: Выделить всё

Private Type client
id As Long
End Type

Dim cnnct As New Collection


в srv_ConnectionRequest

Код: Выделить всё

  Dim cln As client
  cln.id = requestID
  cnnct.Add cln, requestID


Выдается ошибка: Only public user defined types defined in public object modules can be used as parameters or return types for public procedures of class modules or as fields of public user defined types

Я же не пытаюсь передавать и возвращать UDT как параметр

Спасибо за внимание.

[GSerg]

А, по-твоему, Add - не метод, а cln - не параметр?

[Tolking]

Логично...

Хорошо... Вынес тип в модуль обозвал его пабликом, там же создал колекцию. Ошибка, та же

В колекцию можно собирать UDT или только числа, строки, классы?

И строку

Код: Выделить всё

Dim cln As client

Я вывел опытным путем это правильно? Или есть другой способ создания переменной пользовательского типа?

[Viper]

Собственно проблема здесь в том, что коллекции хранят свои элементы в виде типа Variant, а тип Variant не может хранить в себе определенные пользователем типы. Так что вместо UDT юзай класс и будет тебе счастье

[GSerg]

Variant может хранить в себе что угодно.
Просто для UDT надо, чтобы у него был GUID. А GUID у него появится, если объявить этот UDT как публичный в ActiveX dll или ActiveX exe.

[Viper]

Ну да, или так.

[Tolking]

Ясно... Спасибо.

Еще вопрос: как VarPtr() обратно в переменную привратить? Типа память копировать?

[Tolking]

А GUID у него появится, если объявить этот UDT как публичный в ActiveX dll или ActiveX exe.

Можно подробнее для таких как я?

[GSerg]

New project - ActiveX Dll
Объявить public type в модуле класса.
Тогда он передастся в коллекцию.

[Tolking]

Спасибо.

[Faust]

Еще вопрос: как VarPtr() обратно в переменную привратить? Типа память копировать?

Есть такая полезная API-функция, как RtlMoveMemory. Оч-чень много зависит от того, как ее объявить. К примеру:

Код: Выделить всё


Private Declare Sub StrToStr Lib "kernel32" Alias "RtlMoveMemory" (Dst As Any, Src As Any, ByVal ByteLen As Long)
Private Declare Sub PtrToStr Lib "kernel32" Alias "RtlMoveMemory" (Dst As Any, ByVal pSrc As Long, ByVal ByteLen As Long)
Private Declare Sub StrToPtr Lib "kernel32" Alias "RtlMoveMemory" (ByVal pDst As Long, Src As Any, ByVal ByteLen As Long)
Private Declare Sub PtrToPtr Lib "kernel32" Alias "RtlMoveMemory" (byVal pDst As Long, byVal pSrc As Long, ByVal ByteLen As Long)

Private Type Vec2
  x as single
  y as single
End Type
Const memVec2Len=8

Private Sub Main()
Dim v As vec2,pv as long,w as vec2, pw as long
pv=VarPtr(v)
pw=VarPtr(w)
v.x=1
v.y=2
StrToStr w,v,memVec2Len
Debug.Print w.x, w.y
v.x=3
v.y=4
PtrToStr w,pv,memVec2Len
Debug.Print w.x, w.y
v.x=5
v.y=6
StrToPtr pw,v,memVec2Len
Debug.Print w.x, w.y
v.x=7
v.y=8
PtrToPtr pw,pv,memVec2Len
Debug.Print w.x, w.y
End Sub


ЗЫ. Ежели ничего не слажал, то должно работать...
ЗЗЫ. А почему это буквосочетание pv так подозрительно выделено подстветкой синтаксиса???