Сравнение двух массивов разной размерностью

[1]

Есть два массива:

varX и varY

varX = 1,2,3,4,5,6,7,8,15
varY = 1,5,9,15,25,64,117

Необходимо сравоить эти два массива и в переменную записать те элементы, которые есть во втором массиве (varY), и которых нет в первом (varХ).

Т.е. должно получиться varZ = 9,25,64,117.

Код: Выделить всё

    Dim varX As Variant
    Dim varY As Variant
    Dim varZ As Variant
    Dim intI As Integer
    Dim intJ As Integer

    For intI = 0 To UBound(varX)
        For intJ = 0 To UBound(varY)
            If varX(intI) <> varY(intJ) Then
                varZ = varZ & ";" & varY(intJ)
            End If
        Next intJ
     Next intI

Получаются многочисленные повторения. Подскажите как правильно реализовать.

[GSerg]

Код: Выделить всё


dim c as collection, i as long
...

set c=new collection
on error resume next
for i=lbound(vary) to ubound(vary)
  c.add clng(vary(i)), cstr(vary(i))
next
for i=lbound(varx) to ubound(varx)
  c.remove cstr(varx(i))
next
on error goto 0

for i=1 to c.count
  msgbox c(i)
next

[Antonariy]

Если массивы отсортированы (по крайней мере varY), то можно так:

Код: Выделить всё

    For intI = 0 To UBound(varX)
        intJ = 0
        While varY(intJ) <= varX(intI)
            If varX(intI) <> varY(intJ) Then
                varZ = varZ & ";" & varY(intJ)
            End If
            intJ = intJ + 1
        Wend
     Next intI

Но можно еще что-нибудь придумать.

[Konst_One]

Код: Выделить всё

Dim varX As String
Dim varY As String
Dim varZ As String
Dim ArrX() As String
Dim ArrY() As String
Dim ResultArr() As String
Dim i As Integer
Dim j As Integer

varX = "1,2,3,4,5,6,7,8,15"
varY = "1,5,9,15,25,64,117"
varZ = ""

ArrX = Split(varX, ",")
ArrY = Split(varY, ",")

j = UBound(ArrY)
For i = 0 To j
    If InStr(1, "," & varX & ",", "," & CStr(ArrY(i)) & ",") = 0 Then
        If Len(varZ) > 0 Then
            varZ = varZ & "," & ArrY(i)
        Else
            varZ = ArrY(i)
        End If
    End If
Next i

'varZ = 9,25,64,117

MsgBox varZ

[1]

Всем спасибо.

GSerg, вариант с коллекцией работает как часы. Я тоже уже хотел сделать через коллекцию, но не смог подкопаться.

Antonariy, твой вариант как-то не корректно отрабатывает.
Получаются такой результат: 1;1;1;1;1;5;1;5;1;5;1;5;9

Konst_One, твой вариант тоже работает как необходимо.