Как поворачивать Label или Picture Box

[Rostik Ultra (2)]

Как поворачивать Label или Picture Box на определённый угол ?

[Viper]

Как это не прискорбно, но никак. по крайней мере я такого способа не знаю. надо брать другой контрол

[tyomitch]

А, солидный дядька вернулся?
Rostik, где незасвеченный айпишник надыбал?

[kirrun]

tyomitch

Хех.. Мало ли проксей!

[Rostik Ultra (2)]

Как это не прискорбно, но никак. по крайней мере я такого способа не знаю. надо брать другой контрол

У меня есть пример , только получается медленно ( юзай прикреплённый файл )

У кого какие соображения по теме ??

[Rostik Ultra (2)]

А, солидный дядька вернулся?
Rostik, где незасвеченный айпишник надыбал?

Здарова !!

Вот ссылка на форум , там есть большой список проксей

http://hardwarezone.fastbb.ru/re.pl?2-00000012-000-0-0-0-1104417786-0

[Viper]

Дык есть разница между поворотом КОНТРОЛА и поворотом его содержимого. Код посморю, подумаю

[Viper]

Первый вариант должен работать очень быстро, но есть проблема с функцией SetWorldTransform. У меня она почему то выдет ошибку

Код: Выделить всё


Private Sub Rotate3()
    picTwo.Cls
    picOne.ScaleMode = vbPixels
    picTwo.ScaleMode = vbPixels
    'угол поворота в радианах
    Dim da As Double: da = HScroll1.Value * pi / 180
    'матрица преобразования
    Dim XF As XFORM
    XF.eM11 = Cos(da)
    XF.eM12 = Sin(da)
    XF.eM21 = -Sin(da)
    XF.eM22 = Cos(da)
    'устанавливаем расширенный графический режим
    SetGraphicsMode picTwo.hdc, GM_ADVANCED
    'поворачиваем мир на нужный угол
    Dim r As Long: r = SetWorldTransform(picTwo.hdc, XF) 'возвращает 0, что указывает на ошибку
    'копируем изображение
    BitBlt picTwo.hdc, (picTwo.ScaleWidth - picOne.ScaleWidth) / 2, (picTwo.ScaleHeight - picOne.ScaleHeight) / 2, picOne.ScaleWidth, picOne.ScaleHeight, picOne.hdc, 0, 0, vbSrcCopy
End Sub


Кстати вопрос, что я не так делаю с SetWorldTransform?

Второй вариант работает довольно шустро, но все таки не столь быстро как хотелось бы

Код: Выделить всё


Private Sub Rotate4()
    picOne.ScaleMode = vbPixels
    picTwo.ScaleMode = vbPixels
    Dim da As Double: da = HScroll1.Value * pi / 180
    'создаем контекст устройства памяти
    Dim memDC As Long: memDC = CreateCompatibleDC(picTwo.hdc)
    Dim memBmp As Long: memBmp = CreateCompatibleBitmap(picTwo.hdc, picTwo.ScaleWidth, picTwo.ScaleHeight)
    Dim oldBmp As Long: oldBmp = SelectObject(memDC, memBmp)
    Dim nX As Integer, nY As Integer
    Dim nX1 As Integer, nY1 As Integer
    Dim dX2 As Double, dY2 As Double
    Dim dX3 As Double, dY3 As Double
    For nX = 0 To picTwo.ScaleWidth
        nX1 = nX - picTwo.ScaleWidth \ 2
        For nY = 0 To picTwo.ScaleHeight
            nY1 = nY - picTwo.ScaleHeight \ 2
            'поворачиваем картинку на угол da
            dX2 = nX1 * Cos(-da) + nY1 * Sin(-da)
            dY2 = nY1 * Cos(-da) - nX1 * Sin(-da)
            'получаем центр нашего исходного picture box
            dX3 = dX2 + picOne.ScaleWidth \ 2
            dY3 = dY2 + picOne.ScaleHeight \ 2
            'If data point is in picOne, set its color in picTwo
            If dX3 > 0 And dX3 < picOne.ScaleWidth - 1 _
                And dY3 > 0 And dY3 < picOne.ScaleHeight - 1 Then
                'устанавливаем пиксели в памяти
                SetPixelV memDC, nX, nY, GetPixel(picOne.hdc, CLng(dX3), CLng(dY3))
            End If
        Next nY
    Next nX
    'копируем картинку в PictureBox
    BitBlt picTwo.hdc, 0, 0, picTwo.ScaleWidth, picTwo.ScaleHeight, memDC, 0, 0, vbSrcCopy
    'удаляем созданные объекты
    SelectObject memDC, oldBmp
    DeleteObject memBmp
    DeleteDC memDC
End Sub


полная версия на прицепленом файле

[tyomitch]

XFORM криво объявлена - все её члены должны быть As Single. Тогда работает, я проверил.

[A.A.Z.]

http://bbs.vbstreets.ru/viewtopic.php?t=5434

[Viper]

После изменения XFORM и более точного вызова SetWorldTransform все работает очень шустро.

Код: Выделить всё


Private Sub Rotate3()
    picTwo.Cls
    picOne.ScaleMode = vbPixels
    picTwo.ScaleMode = vbPixels
    'угол поворота в радианах
    Dim da As Double: da = HScroll1.Value * pi / 180
    'матрица преобразования
    Dim XF As XFORM
    XF.eDx = picTwo.ScaleWidth / 2
    XF.eDy = picTwo.ScaleHeight / 2
    XF.eM11 = Cos(-da)
    XF.eM12 = Sin(-da)
    XF.eM21 = -Sin(-da)
    XF.eM22 = Cos(-da)
    'устанавливаем расширенный графический режим
    SetGraphicsMode picTwo.hdc, GM_ADVANCED
    'смещаем и поворачиваем мир на нужную величину
    SetWorldTransform picTwo.hdc, XF
    'копируем изображение
    BitBlt picTwo.hdc, -picOne.ScaleWidth \ 2, -picOne.ScaleHeight \ 2, picOne.ScaleWidth, picOne.ScaleHeight, picOne.hdc, 0, 0, vbSrcCopy
End Sub


полная версия прицеплена.

Версию A.A.Z. еще не смотрел.

[Sasha_karasov]

А не скажете формулу для вращения точки на угол A

[tyomitch]

А не скажете формулу для вращения точки на угол A

см. в коде Viper, она там есть.

[Viper]

Обещанный анализ версии от A.A.G.

В ней три варианта реализации поворота картинки, причем они работают как с применением сглаживания пикселей так и без оного.

Первый вариант по сути аналогичен методу от Rostic_Utra(2), но с некоторой оптимизацией, крутит картинку за 206 мс со сглаживанием и за 89 мс без сглаживания.

Второй вариант делает тоже самое, но использует при этом функции API GetPixel и SetPixel вместо свойств PictureBox. Соответственно 172 мс и 65 мс. Думаю, если вместо SetPixel использовать SetPixelV будет работать быстрее.

Третий метод записывает в память Bitmap, критит его там и рисует полученную картинку на PictureBox. Работает за 28 мс и за 23 мс. Собственно это аналогично моему способу с повортом картинки в конексте устройства памяти. Только у меня реализация попроще через BitBlt.

Метод с SetWorldTransform поворачивает картинку за 6 мс.

Исходный вариант (Rostic_Utra(2)) за 350 мс.

Все крутилось в готовом exe-файле на Pentium III с часотой процессора 866 МГц и памятью 512 МБ.

З.Ы. Скорость вращаения зависит и от размера картинки - картинка A.A.G меньше чем у Rostic_Utra(2)

Делайте выводы.

[GSerg]

SetWorldTransform не работает на Win95/98/Me.
Делайте выводы.

[Viper]

SetWorldTransform не работает на Win95/98/Me.
Делайте выводы.

Эт точно, с 95 года к машинам с Win95/98/ME не подходил - про не работу на них многих API функций даже и не вспоминаю.

Если без SetWorldTransform то стоить крутит через контекст памяти

[tyomitch]

Обещанный анализ версии от A.A.G.
...
З.Ы. Скорость вращаения зависит и от размера картинки - картинка A.A.G меньше чем у Rostic_Utra(2)

А это кто такой?