Где он лежит ...

[SeT]

Помогите, кто может. Трабла такая...
Мне нужно слепить программку для поиска файла, который хранится на жёстком диске. Как это осуществить? Поиск реальных результатов не дал. Только по детальней, пожалуйста ...

[ANDLL]

А может за тебя написать?
Для перечисления файлов используется Dir, для открытия Open, для чтения Line Input, для закрытия Close...

[SeT]

ANDLL Мне нужно найти какой-то файл (н.р. gens.exe). Как это сделать?

[Konst_One]

Апишки сам найдешь и рекурсию по директориям сделаешь

Код: Выделить всё

'**********************************************
'* Function FindFile is From Planet-Source-Code
'* Strongly modified by Carlos 09-10-99
'***********************************************
Public Sub FindFile(ByVal path As String, ByVal ftype As String)
       Dim hFile As Long, ts As String, WFD As WIN32_FIND_DATA
       Dim result As Long, sAttempt As String, szPath As String
       Dim strtemp
       If ProgressCancel Then Exit Sub
       Form4.ProgressBar1.Value = 1
       szPath = path & "*.*" & Chr$(0)
       'Start asking windows for files.
       putfileinpath path, ftype
       hFile = FindFirstFile(szPath, WFD)
       
       Do
         If WFD.dwFileAttributes And FILE_ATTRIBUTE_DIRECTORY Then
          'Hey look, we've got a directory!
             ts = StripNull(WFD.cFileName)
             If Not (ts = "." Or ts = "..") Then
                 'Don't look for hidden or system directories
                 If Not (WFD.dwFileAttributes And (FILE_ATTRIBUTE_HIDDEN Or FILE_ATTRIBUTE_SYSTEM)) Then
                     'Search directory recursively
                     FindFile path & ts & "\", ftype
                 End If
             End If
           End If
           WFD.cFileName = ""
           result = FindNextFile(hFile, WFD)
           Label1.Caption = "Searching in: " & path
           DoEvents
          If Form4.ProgressBar1.Value = Form4.ProgressBar1.Max Then Form4.ProgressBar1.Value = 1
          Form4.ProgressBar1.Value = Form4.ProgressBar1.Value + 1
        Loop Until result = 0
       
       FindClose hFile
End Sub

[ANDLL]

Код: Выделить всё

Option Explicit
Dim mSearchedFile As String
Dim mSearchFlags As Long

Private Sub Form_Load()
    mSearchedFile = "kernel32.dll"
    mSearchFlags = vbDirectory Or vbHidden Or vbSystem 'По вкусу...
    SearchFile "C:\WINDOWS\"
    End
End Sub

Public Sub SearchFile(ByRef lpDir As String) 'Отыскивает файл в дерикториях и поддиректориях
    Dim str As String, dirs() As String
    str = Dir(lpDir, mSearchFlags)
    ReDim dirs(0)
    Do While str <> ""
        If str <> ".." And str <> "." Then
            If GetAttr(lpDir & str) And vbDirectory Then
                dirs(UBound(dirs)) = str
                ReDim Preserve dirs(UBound(dirs) + 1)
            Else
                If str = mSearchedFile Then 'Здесь собственно можно делать с файлом все, что угодно
                    MsgBox "Файл найден: " & lpDir & str, vbInformation
                End If
            End If
        End If
        str = Dir
    Loop
    Dim I As Long
    For I = 0 To UBound(dirs) - 1
        SearchFile lpDir & dirs(I) & "\"
    Next
End Sub


Уже ответили? Ну так уж выложу, раз старался...

[Konst_One]

вот старый проектик, может кто продолжит идею. часть еще более старого проекта с PlanetSourceCode

[SeT]

Спасибоньки-и-и-и!!!!!!!!!!!!!