DataGrid, событие ButtonClick() - как правильно?

[Ennor]

Че-то я совсем затупил. Народ, напомните, как правильно прописывается событие ButtonClick() для MS DataGrid. Нужно создавать собсный комбо и подвешивать его на форму или нет?

А то свойство Button я для столбца прописал, все замечательно, но как только сделал обработчик означенного события (без единой строки кода), комбик перестал выпадать. Вот я и думаю... Нахрена я вообще с этим контролом связался?

[Konst_One]

этот бутончик только кнопочку в ячейку добавляет, а все остальное ты сам должен реализовать

конечно контрол этот не ахти какой, если есть мани, то лучше взять что-нибудь поприличней

[Ennor]

этот бутончик только кнопочку в ячейку добавляет

Не скажи, пока в коде не было точки входа для события, при нажатии на кнопку вываливалось какое-то подобие editable combo. А после добавления обработчика перестала даже эта пустышка вываливаться. Вот мне и интересно, как это вообще прописывается.

[Konst_One]

покажи свой код, может че вместе расскопаем

[Konst_One]

что-то у меня ничего не вываливается - просто кнопка висит в ячейке и все

[Ennor]

Черт! Теперь у меня тоже не получается. Но ведь вываливалось же!

Ладно. Вопрос остается в силе - что прописывать в событие ButtonClick(), чтоб вываливалось?

[Konst_One]

странно, но я обычно по этому событию показывал свой контрол (ListView или что-то еще)

[Konst_One]

На форме DataGrid1 и ListBox1:

Код: Выделить всё

Option Explicit
Dim rs As ADODB.Recordset

Private Sub DataGrid1_ButtonClick(ByVal ColIndex As Integer)
Dim i As Integer
Dim iLeft As Single
Dim iTop As Single
Dim iWidth As Single

    With Me.DataGrid1
        iLeft = .Columns(ColIndex).Left + .Left
        iWidth = .Columns(ColIndex).Width
        iTop = .Top + (.Row + 1) * .RowHeight + .HeadLines * .RowHeight + 30
    End With

    With Me.List1
        .Clear
        .BackColor = &H80000018
        For i = 1 To 10
            .AddItem "Item " & i
        Next i
        .Move iLeft, iTop, iWidth
        .ZOrder 0
        .Visible = True
    End With
   
End Sub

Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
    Me.List1.Visible = False
End Sub

Private Sub Form_Load()
Dim i As Integer

Set rs = New ADODB.Recordset

rs.Fields.Append "Field1", adVarChar, 100, adFldIsNullable
rs.Fields.Append "Field2", adInteger, , adFldIsNullable

rs.Open

For i = 1 To 10
    rs.AddNew
    rs!Field1 = "Row " & i
    rs!Field2 = i
Next i


Set Me.DataGrid1.DataSource = rs
Me.DataGrid1.Columns(1).Button = True



End Sub

Private Sub List1_Click()
    Me.DataGrid1.SetFocus
    Me.List1.Visible = False
End Sub

[Ennor]

Т.е. весь прикол свелся в отображению кнопки со стрелкой вниз, и все? Ничего встроенного в этом гриде нет? Вот подстава... Значит, придется кидать собсный комбо. Фак-каммала.

Ясно, спасибо.

[Konst_One]

не за что, спасибо надо мелкософту сказать за такой замечательный грид

[Ennor]

Дык, емнип, это же всего лишь кастрированная версия TrueDBGrid от ComponentOne. Или я путаю? В общем, какова цена, таков и вкус вина.