Ввод только цифр

[Чудик]

Как определить, что в TextBox введены только цифры?

[Amed]

Код: Выделить всё

Private Sub Text1_KeyPress(KeyAscii As Integer)
If InStr(1, "1234567890.", Chr(KeyAscii)) = 0 Then KeyAscii = 0
End Sub

Только надо обрабатывать ещё нажатия BackSpace и Delete... Это - задание на дом

[Чудик]

Благодарю!

[A.A.Z.]

Можно так:

Код: Выделить всё

Sub Text1_KeyPress(KeyAscii As Integer)
Select Case KeyAscii
Case Asc("0") To Asc("9"), Asc("."), vbKeyBack, vbKeyDelete
Case Else
KeyAscii = 0
End Select
End Sub

[Amed]

Кстати, надо ещё учесть, что в разных странах разные разделители целой и дробной частей числа. Надо вытаскивать данные о текущем разделителе. Где найти, как вытащить, - не знаю . Спроси у Яндекса.

[A.A.Z.]

Код: Выделить всё

Option Explicit

Private Const LOCALE_SDECIMAL As Long = &HE&
Private Const LOCALE_USER_DEFAULT As Long = &H400&

Private Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long

Private Function GetSeparator$()
Dim Buf$, Ret&
Buf = String$(256, 0)
GetSeparator = Left$(Buf, GetLocaleInfo(LOCALE_USER_DEFAULT, LOCALE_SDECIMAL, Buf, Len(Buf)))
End Sub

Sub Text1_KeyPress(KeyAscii As Integer)
Select Case KeyAscii
Case Asc("0") To Asc("9"), Asc(GetSeparator), vbKeyBack, vbKeyDelete
Case Else
KeyAscii = 0
End Select
End Sub

Я спросил у Яндекса, я спросил у Рамблера, я спросил... Нет, только MSDN остается

[ism]

Как определить, что в TextBox введены только цифры?

Код: Выделить всё

if IsNumeric(Text1.text) then msgbox "Цифры"

[GSerg]

Как определить, что в TextBox введены только цифры?

Код: Выделить всё

Option Explicit

Private Declare Function GetWindowLong Lib "user32.dll" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Private Const ES_NUMBER As Long = &H2000&
Private Const GWL_STYLE As Long = -16

Private Sub Form_Load()
  Text1.Text = vbNullString
  SetWindowLong Text1.hwnd, GWL_STYLE, GetWindowLong(Text1.hwnd, GWL_STYLE) Or ES_NUMBER
End Sub

[A.A.Z.]

Гы Кстати, а если сделать вставку (правка->вставить) в текстбокс, то все равно не поможет

[Amed]

Всё просто, как колумбово яйцо!

P.S. может, сделать класс "Ввод в textbox только цифр 10 способами"?

[A.A.Z.]

Можно Тогда надо еще вот это вставить

Код: Выделить всё

Private Sub Text1_Change()
Static OldText As String
If IsNumeric(Text1.Text) Then OldText = Text1.Text Else Text1.Text = OldText
End Sub

Предварительно в введя чего-нибудь в текстбокс из Form_Load

[Andrey Fedorov]

Кстати, надо ещё учесть, что в разных странах разные разделители целой и дробной частей числа. Надо вытаскивать данные о текущем разделителе. Где найти, как вытащить, - не знаю . Спроси у Яндекса.

Узнать разделитель - проще не бывает - безо всякого API:

Format$(0,".")

А еще - я предпочитаю в KeyPress при нажатии на запятую/точку просто ставить нужный разделитель - получается удобней...