Прозрачность формы, но не контролов на ней!

[Jenizix]

Выставляем у формы св-во BorderStyle = 0

Код: Выделить всё

Option Explicit

Private Declare Function CreateRectRgn Lib "gdi32" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function CombineRgn Lib "gdi32" (ByVal hDestRgn As Long, ByVal hSrcRgn1 As Long, ByVal hSrcRgn2 As Long, ByVal nCombineMode As Long) As Long
Private Declare Function SetWindowRgn Lib "user32" (ByVal hWnd As Long, ByVal hRgn As Long, ByVal bRedraw As Boolean) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long

Private Const RGN_OR = 2

Private Sub TranspForm(ByVal frm As Form)
    Dim WindowRgn As Long ' тут будет храниться регион, по которому в последствии будет вырезано окно
    Dim ctrlRgn As Long ' тут будет храниться регион текущео конрола
    Dim ctrl As Control ' текущий контрол
   
    WindowRgn = CreateRectRgn(0, 0, 0, 0) ' создаем пустой регион
   
    On Error Resume Next
    For Each ctrl In frm.Controls ' перебираем все контролы на форме
        ctrlRgn = CreateRectRgn(frm.ScaleX(ctrl.Left, frm.ScaleMode, vbPixels), frm.ScaleY(ctrl.Top, frm.ScaleMode, vbPixels), frm.ScaleX(ctrl.Left + ctrl.Width, frm.ScaleMode, vbPixels), frm.ScaleY(ctrl.Top + ctrl.Height, frm.ScaleMode, vbPixels))  ' создаем регион текущего контрола
        CombineRgn WindowRgn, WindowRgn, ctrlRgn, RGN_OR ' комбинируем его с регионом WindowRgn
    Next
   
    SetWindowRgn frm.hWnd, WindowRgn, True ' вырезаем окно по региону WindowRgn
   
    DeleteObject ctrlRgn
End Sub

Private Sub Form_Load()
    TranspForm Me ' вызываем ф-ию которая делает форму прозрачной
End Sub

Вот и все! Юзайте!!!

[Ramzes]

Особого интереса разбираться нет, но работает криво
ГОСПОДА, Юзайте .NET (Там это все свойствами (обычными) сделать можно

[zaf]

Особого интереса разбираться нет, но работает криво
ГОСПОДА, Юзайте .NET (Там это все свойствами (обычными) сделать можно

А чем .NET отличается от VB?
Они похожи?
Есть русская версия .NET ?

[Ramzes]

zaf
http://bbs.vbstreets.ru/viewtopic.php?t=24230

[Конь]

Ну что можно сказать?.. Работает, действительно, криво.
Что я заметил:
1. Не работает с линиями.
2. Круглые и овальные Shape вырезаются в форме прямоугольника.
3. Че-то там орет про Timer.

А так, вроде со стандартными контролами нормально работает.

[Хакер]

Естественно, кирпич изначально расчитан на прямоугольные контролы. Так что с шейпами и лайнами будут проблемы. А так же со всеми прозрачными кнопками.

[Конь]

Хакер
И как тогда быть? Я сейчас взялся писать программу, а на форме исключительно шейпы и лайны:)

[Хакер]

Отскринить экран под формой, и нарисовать это на форме.

[Kovu]

Ну ещё можно сделать все контролы невидимыми временно(шейпы и лайны) и сделать Path по ним, затем PathToRegion, и контролы обратно видимыми.
<--800

[nikivas]

вот код:

Код: Выделить всё

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" (ByVal hWnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long
Private Const LWA_COLORKEY = &H1
Private Const LWA_ALPHA = &H2
Private Const LWA_ALPHAANDCOLORKEY = &H3
Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_LAYERED = &H80000
Private Const CLR_Black = &H0&
Private Const CLR_Fon = &HFF8080
Private X As Byte


Public Sub SetTransparent2(hWnd As Long, Layered As Byte, ID_Color As Variant)
Dim Ret As Long
    Ret = GetWindowLong(hWnd, GWL_EXSTYLE)
    Ret = Ret Or WS_EX_LAYERED
    SetWindowLong hWnd, GWL_EXSTYLE, Ret
    SetLayeredWindowAttributes hWnd, ID_Color, Layered, LWA_COLORKEY
    End Sub

Private Sub Form_Click()
End
End Sub

Private Sub Form_Load()
Form1.BackColor = &HFF8080
SetTransparent2 Form1.hWnd, X, CLR_Fon
End Sub