КАК проверить есть ли файл вообще ?

[MiRC]

Есть задача - нужно определить есть ли файл disk:\dir\filename , с помошью какой функции ??? Уже битый час ищу - всяких findfile вроде бы нет !!!

[RayShade]

Очень просто. Берем FileSystemObject и используем его метод GetFile.

Если вернет Nothing то файла нет.

[mad_Max]

Вроде в FSO есть специальная функция - FileExists(FileSpec As String).
А можно и без FSO

Код: Выделить всё

Function FileExist(filename As String) As Boolean
   FileExist = Dir$(filename) <> ""
End Function

[RayShade]

Код: Выделить всё

if len(dir$(filename))>0


Работать будет быстрее...

[GSerg]

Ну тогда уж

Код: Выделить всё

If Len(Dir(Filename)) Then

Ещё быстрее. А доллар не нужен, потому что Dir изначально объявлена как стринг.

[RayShade]

Alas, он не быстрее Потому что придется еще преобразовать (coerce) Int к Bool

[STING]

Dim fn As String
fn=Dir("Путь к файлу")
If fn = "" Then
MsgBox "Файл не существует!"
Else
MsgBox "Файл существует!"
End If

помоему так проще и быстрее.

[SergeySV]

Dim fn As String
fn=Dir("Путь к файлу")
If fn = "" Then
MsgBox "Файл не существует!"
Else
MsgBox "Файл существует!"
End If

помоему так проще и быстрее.

В предыдущих примерах написано тоже самое, только вместо твоего fn = "", пишут len(fn)>0. Умные дядьки говорят, что сравнение длины строк. переменной с нулем работает быстрее, чем сравнение строк. переменной с пустой строкой...

[RayShade]

Кхм... Уважаемые, а не почитать ли Вам Правила на тему повторения чужих постингов?

[Александр Андреев]

Господа!
Не используйте FSO. Он глючит под NT 4.0.

[Cyrax]

Господа!
Не используйте FSO. Он глючит под NT 4.0.

и вобще для таких элементарных вещей, как определение существования файла (и даже поиск файлов по маске, хотя это уже не совсем элементарно ), встроенных функций языка хватает с головой.

[GSerg]

Alas, он не быстрее Потому что придется еще преобразовать (coerce) Int к Bool

Код: Выделить всё

Option Explicit

Private Declare Function GetTickCount Lib "kernel32" () As Long

Private Sub Form_Load()
  Dim t As Long, vbnsRes  As Long, vbquRes As Long, vbGreater As Long, vbJust As Long, i As Long
 
  Dim tmpStr As String, tmp As Long
  Const Times As Long = 10000000
 
  tmpStr = "any stupid string to test"
 
  t = GetTickCount
  For i = 1 To Times
    If tmpStr <> vbNullString Then tmp = tmp + 1
  Next
  vbnsRes = GetTickCount - t
 
  tmp = 0
  t = GetTickCount
  For i = 1 To Times
    If tmpStr <> "" Then tmp = tmp + 1
  Next
  vbquRes = GetTickCount - t
 
  tmp = 0
  t = GetTickCount
  For i = 1 To Times
    If Len(tmpStr) > 0 Then tmp = tmp + 1
  Next
  vbGreater = GetTickCount - t
 
  t = GetTickCount
  For i = 1 To Times
    If Len(tmpStr) Then tmp = tmp + 1
  Next
  vbJust = GetTickCount - t
 
  MsgBox "Сравнение с vbNullString " & vbnsRes & vbNewLine & _
         "Сравнение с """"" & vbTab & vbquRes & vbNewLine & _
         "Больше нуля" & vbTab & vbGreater & vbNewLine & _
         "Просто так" & vbTab & vbJust _
         , , FormatNumber$(Times, 0) & " раз"
 
End Sub

Сравнение с vbNullString 2016
Сравнение с "" 1905
Больше нуля 1965
Просто так 1885