Поправьте код, плз. Работает, но странно...

[FirstUser]

Я продолжаю решать проблему описаную здесь:
http://bbs.vbstreets.ru/viewtopic.php?t=1690
(Убрать пробелы в большом файле используя VBScript)

Желающих помочь оказалось немного, поэтому пришлось ковыряться самому

Наковырял (не без помощи http://sharig.webzone.ru/) следующее:

Код: Выделить всё

Set FSys = CreateObject("Scripting.FileSystemObject")
Set qn = FSys.GetFile("D:\data\proxystats\access2.log")
FileSize1=qn.Size


Function ReplaceAll(SourceString, ReplaceThis, WithThis)

Set fso = CreateObject("Scripting.FileSystemObject")
Set file = fso.OpenTextFile("D:\data\proxystats\access2.log", 1)

SourceString=file.readall()
ReplaceThis="  "
WithThis =" "

Dim Temp

Temp = Split(SourceString, ReplaceThis)
ReplaceAll = Join(Temp, WithThis)

End Function


Do
Dim strAfter
strAfter=ReplaceAll(SourceString, ReplaceThis, WithThis)

Set fso = CreateObject("Scripting.FileSystemObject")
Set file = fso.OpenTextFile("D:\data\proxystats\access2.log", 2, true)


file.WriteLine(strAfter)

Set FSys2 = CreateObject("Scripting.FileSystemObject")
Set qn2 = FSys2.GetFile("D:\data\proxystats\access2.log")
FileSize2=qn2.Size

Loop while FileSize1 > FileSize2

Проблема:
Выполняется долго. Делает все что нужно (пробелы удоляются), но висит в списке задач минут 10 и ест 99% CPU. Кажется, что что-то не так с Loop...

Вопрос:
Что еще в коде "не так"?
Может можно что изменить/улучшить

Спасибо!

[RayShade]

Ты бы, уважаемый, не создавал бы в цикле объекты... Вредно это для здоровья

[Vitaly1]

FirstUser
А почему обязательно VBScript, почему нельзя открыть два двочных файла, из одного брать порциями байты и засылать не пробелы в другой?..

[RayShade]

Да потому что это вообще умрет все.

Аглоритм - прочитал - убилпробелы - записал.

[skiperski]

2 FirstUser:
Ты код с закрытыми глазами писал? Если да, то понятно, если нет, то проблема где-то на генетическом уровне.

На первый раз прощается. Держи.

Код: Выделить всё

Public Function test()
   
    Dim fso, src, dst
    Dim line
   
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set src = fso.OpenTextFile("c:\1\spaces0.txt", 1)
    Set dst = fso.OpenTextFile("c:\1\spaces1.txt", 2, True)
   
    Do Until (src.AtEndOfStream)
        line = src.ReadLine
        Do While (InStr(1, line, "  "))
            line = Replace(line, "  ", " ")
        Loop
        dst.WriteLine line
    Loop
   
    dst.Close: Set dst = Nothing
    src.Close: Set src = Nothing
    Set fso = Nothing
   
End Function

Как долго выполняется?

[RayShade]

Кхм..

А не проще ли было:

Код: Выделить всё

dst.write replace(src.readall," ","",1,-1,1)


[FirstUser]

Господа!!!
Я (пока) не разбираюсь в программировании!

Если сделал неправильно, покажите как есть правильно.
ПОЖАЛУЙСТА!

Я же не прошу Вас ОС бесплатно написать. Пару строк кода.

Решение должно быть на VBScript или JScript.

Почему в цикле нельзя создавать объекты?
Это что, так критично для ресурсов?

[skiperski]

2 RayShade:
Нет, не проще.

1. Надо не все пробелы убрать, а только двойные.

2. Представь что файл на пару-тройку метров, а ты его весь вычитывыешь.

[FirstUser]

СОРРИ ПОЗДНО ОБНОВИЛСЯ!!!

2 FirstUser:
Ты код с закрытыми глазами писал? Если да, то понятно, если нет, то проблема где-то на генетическом уровне.

Спасибо!!!

Я первый раз писал буквы на Бейсике. Поэтому так плохо получилось.
(Хотя сам еще не понимаю на сколько плохо:)

[RayShade]

2 skiperski

Ну что именно там заменять это не суть важно. Ну поменяй " " и "" на " " и " " А файл то и так по любому будет вычитан. Так что какая разница как (ну если только смотря какие вообще то ресурсы у станции будут ).

[skiperski]

2 RayShade:
1. В данном случае важно

Код: Выделить всё

?replace("a     x"," ","",1,-1,1)
ax
?replace("a     x","  "," ",1,-1,1)
a   x

2. Файл будет вычитан строками, а не весь целиком. Строку прочитал, обработал, записал. Строки, конечно, могут быть длинными, но всё же не длиннее файла.

[FirstUser]

Еще раз спасибо!

Проверил. Работает как надо.