Опять я в чайниках.. первые и последние 2 байта числа

[Eugenio]

Помогите с алгоритмом:
дано: нечто типа long.
нужно получить в виде отдельных чисел первые и последние 2 байта.
Не могу сообразить, как это проще всего сделать

[GSerg]

Код: Выделить всё

Option Explicit

'Простейшие функции для вычленения частей машинных сущностей :)

'(c) GSerg, 2004


'P.S. Через CopyMemory медленнее, через GetMem тоже :)


Public Function DWORD(ByVal Low As Integer, ByVal High As Integer) As Long
  If High And &H8000 Then
    DWORD = (High And &H7FFF) * &H10000 Or &H80000000 Or Low
  Else
    DWORD = High * &H10000 Or Low
  End If
End Function

Public Function WORD(ByVal Low As Byte, ByVal High As Byte) As Integer
  If High And &H80 Then
    WORD = (High And &H7F) * &H100 Or &H8000 Or Low
  Else
    WORD = High * &H100 Or Low
  End If
End Function

Public Function HIWORD(ByVal DblWord As Long) As Integer
  HIWORD = DblWord / &H10000
End Function

Public Function LOWORD(ByVal DblWord As Long) As Integer
  LOWORD = DblWord And &HFFFF&
End Function

Public Function HIBYTE(ByVal Wrd As Integer) As Byte
  If Wrd And &H8000 Then
    HIBYTE = (Wrd And &H7F00) / &H100 Or &H80
  Else
    HIBYTE = Wrd / &H100
  End If
End Function

Public Function LOBYTE(ByVal Wrd As Integer) As Byte
  LOBYTE = Wrd And &HFF
End Function

[Ennor]

Вот это - работает всегда, без ограничений на значение 32-го бита.

Это - в модуль:

Код: Выделить всё

Public Type tag_4
  Four As Long
End Type

Public Type tag_2_2
  Lo As Integer
  Hi As Integer
End Type

Public Function SplitLong(ByVal L As Long) As tag_2_2
Dim Z As tag_4

Z.Four = L
LSet SplitLong = Z

End Function


Это - в код формы, на форме - один кнопка:

Код: Выделить всё

Private Sub Command1_Click()
Dim Z As Long, X As tag_2_2

Z = &H64583545
X = SplitLong(Z)

MsgBox "Low  = " & Hex(X.Lo) & vbNewLine & "High = " & Hex(X.Hi) & _
vbNewLine & "Number = " & Hex(Z)
End Sub

[GSerg]

Угу
Просто сей оператор отменили в .NET, поэтому, чтобы потом было меньше огорчений...

[Ennor]

... Просто сей оператор отменили в .NET ...

Его не отменили, он остался, просто эта фишка с ним больше не работает Больше всего жалко было, если честно, все остальное еще как-то можно терпеть...

[Eugenio]

Dim Z As tag_4

Z.Four = L
LSet SplitLong = Z

End Function

Хм, интересно. Никогда не пробовал копировать даные из одного типа в другой. Ух-х ты. Просто записывает байты в той же последовательности, в которой считывает? И в результате третий и четвертый оказываются в другом поле? ну, круто..

[Eugenio]

'Простейшие функции для вычленения частей машинных сущностей

Спасибо! Я то как раз собрался VarPtr и CopyMemory юзать. Но это как-то больше нравится