Модуль не читает длинные имена

[VERITAS]

Здраствуйте люди!

Не помню где, но я нашел когда то модуль, который позволяет проверять существование какого либо файла. Хорошая штука, очень часто использую. Но вот вдруг возникла проблема,он не читает длинные пути, больше 128 символов.
Кому интересно, может поможете:

':::::::::Module:::::::::

' пример использования
' If IsFileExists("Ваш файл") Then MsgBox ""

Option Explicit
Public Declare Function GetAsyncKeyState Lib "User32.dll" (ByVal Key As Long) As Integer

'Вызываем API
Public Declare Function OpenFile Lib "Kernel32.dll" _
(ByVal lpFileName As String, lpReOpenBuff As OpenFileProperties, _
ByVal wStyle As Long) As Long

Public Const BIF_RETURNONLYFSDIRS = 1
Public Const MAX_PATH = 260
Public Const HH_HELP_CONTEXT = &HF

'Тип данных для API
Public Type OpenFileProperties
cBytes As Byte
fFixedDisk As Byte
nErrCode As Integer
Reserved1 As Integer
Reserved2 As Integer
szPathName(500) As Variant
End Type

Public Function IsFileExists(ByVal ExistsFileName As String) As Boolean
On Error Resume Next
Dim OpenFP As OpenFileProperties
Dim Temp As String

Temp = OpenFile(ExistsFileName, OpenFP, &H4000)
If Temp = 1 Then
IsFileExists = True
Else
IsFileExists = False
End If
End Function

Public Function GetKeyState(StateKayAscii As Integer) As Boolean
On Error Resume Next
Dim GetKeyStateTemp As Long
GetKeyStateTemp = GetAsyncKeyState(StateKayAscii)
If GetKeyStateTemp <> 0 Then
GetKeyState = True
Else
GetKeyState = False
End If
End Function

'::::::END MODULE::::::
Заранее всем спасибо за оказанную помощь!

[xolod]

Позволю себе предложить замену твоей маленькой ф-ции на свою

Код: Выделить всё

Public Function Files_Exists(ByVal FilePath As String) As Boolean
  On Error Resume Next
  If (Trim$(FilePath) = "") Then Exit Function
  If Right$(FilePath, 1) = "\" Then
    Files_Exists = (Len(Dir(FilePath, vbDirectory)) > 0)
  Else
    Files_Exists = (Len(Dir(FilePath)) > 0)
  End If
End Function


притом, если укажешь директорию (к конце символ '\'), ф-ция проверит существование именно директории, а если файл - файла

[|kerish|]

Позволю себе предложить замену на одну строчку.

Код: Выделить всё

If Dir("C:\Путь_к_файлу.txt") <> "" Then MsgBox "Файл существует."

[tyomitch]

Позволю себе заметить, что Dir выдаёт ошибку для невалидного пути (например ":"), и её надо обрабатывать.

[A.A.Z.]

Код: Выделить всё

On Error GoTo ErrHandle
Dim FF&
FF = FreeFile()
Open "Z:\Bla.bla" For Input As #FF: Close #FF
MsgBox "Файл есть!"
Exit Sub
ErrHandle:
If Err.Number = 53 Then MsgBox "Файла нет!"

Супер способ!
[edit]Пока я писал этот пост, tyomitch успел исправить свой =)[/edit]

[VERITAS]

xolod , |kerish|, tyomitch & A.A.Z. - Большое спасибо, теперь все Окей!

[A.A.Z.]

Всегда пожалуйста!
ЗЫ вот только Тёмыча надо было правильно написать ;)

[tyomitch]

[edit]Пока я писал этот пост, tyomitch успел исправить свой =)[/edit]

На самом деле, а если файл существует, но недоступен для чтения (например, тот же своп) - тогда твой способ ошибётся.

[CodeName33]

А так, не должен ошибаться:

Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long

Public Function CheckFile(Name As String) As Integer
Dim S As Long
S = GetFileAttributes(Name)
If S = -1 Then CheckFile = 0: Exit Function
If S And &H10 Then CheckFile = 2: Exit Function
CheckFile = 1
End Function

' 0 - нет, 1 - файл, 2 - папка.