Графика в VB6

[fizik_leha]

Можно ли в VB Рисовать с помощью Line или Circle Пунктирной линией?

И вобще буду очень благодарен за полный синтаксис графических команд VB.

[GSerg]

Да легко...

1. DrawStyle проперть зацени...
2. Line (X1, Y1) - (X2, Y2)[, color[, B[F]]]
Circle (X, Y), Radius[, color]
Cls

[Konst_One]

BorderStyle=2

[fizik_leha]

Спасибо...
Хотелось бы узнать что это за зверь такой - Drawstyle? У меня в списке методов его нет...

[GSerg]

me.drawstyle
Или в дизайнере...

[Konst_One]

наверное все-таки BorderStyle (2 - Dash)

[GSerg]

Причём здесь Border?

[Konst_One]

у стандартных контролов (Line, Shape) - BorderStyle,
а для команд графики - DrawStyle

я про стандартные контролы писал, сорри

[fizik_leha]

Спасибо, помогло Drawstyle = 2
А сколько у него вообще значений?

[GSerg]

Списочек смотри в дизайнере...

[SHURUP]

А если надо штрихи (интервалы меж ними) делать длинее (короче) - тады как? Ато у меня что-то не выходило.

[tyomitch]

Можно через ExtCreatePen (PS_USERSTYLE). Пример:

Код: Выделить всё

Option Explicit
Private Type LOGBRUSH
    lbStyle As Long
    lbColor As Long
    lbHatch As Long
End Type
Private Declare Function ExtCreatePen Lib "gdi32" (ByVal dwPenStyle As Long, ByVal dwWidth As Long, lplb As LOGBRUSH, ByVal dwStyleCount As Long, lpStyle As Long) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Const BS_SOLID = 0&
Private Const PS_COSMETIC = 0&
Private Const PS_USERSTYLE = 7&
Private OldPen As Long

Private Sub Form_Load()
Dim lb As LOGBRUSH, Lengths(4) As Long
lb.lbColor = 0
lb.lbStyle = BS_SOLID
Lengths(1) = 10
Lengths(2) = 3
Lengths(3) = 5
Lengths(4) = 3
OldPen = SelectObject(hdc, ExtCreatePen(PS_COSMETIC Or PS_USERSTYLE, 1, lb, 4, Lengths(1)))
End Sub

Private Sub Form_Unload(Cancel As Integer)
DeleteObject SelectObject(hdc, OldPen)
End Sub

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
Line (0, 0)-(X, Y)
End Sub