Установка ударения ChrW(769) и отслеживание

[Diamock]

Здравствуйте Уважаемые!

Есть вопрос...

Реализую программную установку ударения в MS Word.
Код процедуры установки ударения.

Код: Выделить всё

Public Sub AddAcccent(VowelStress As Boolean)
    If VowelStress = True Then
        Selection.TypeText Text:=ChrW(769)
    Else
        Exit Sub
    End If
End Sub

Проверка, куда ставится ударение.

Код: Выделить всё

Public Function VowelStress(Letter As String) As Boolean
    Select Case Letter
        Case "А"
            AddAcccent True
           
        Case "а"
            AddAcccent True
           
        Case "а?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."
           
        Case "А?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."
           
        Case Else
            MsgBox "Вы пытаетесь поставить ударение на согласную букву «" & Selection.Previous.Text & "»" & " Что не предусмотренно правилами русского языка." & vbCrLf & _
            "Для установки ударения курсор должен стоять после гласной буквы.", vbOKOnly, "ГрафоманЪяк ПП. Версия: " & ProjectVersion
    End Select
   

End Function

Как исключить повторную установку ударения?
Эти фрагменты кода не обрабатывают исключения.

Код: Выделить всё

        Case "а?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."
           
        Case "А?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."

[kibernetics]

Код: Выделить всё

Public Function VowelStress(Letter As String) As Boolean
    Select Case Letter
        Case "А"
            AddAcccent True
           
        Case "а"
            AddAcccent True
           
        Case "а?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."
           
        Case "А?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."


в бейсике можно так упростить кейс селект:

Код: Выделить всё

Public Function VowelStress(Letter As String) As Boolean
    Select Case Letter
        Case "А", "а"
            AddAcccent True
           
        Case "а?", "А?"
            MsgBox "Вы пытаетесь поставить ударение второй раз."


второе, если ты ищешь свой символ, то не надо "?",
вместо него надо
Case "A" & ChrW(769)

[Михаил Орлов]

И вам доброго здоровья.

1. У вас сильно избыточный синтаксис. Код:

Код: Выделить всё

Public Sub AddAcccent(VowelStress As Boolean)
    If VowelStress = True Then
        Selection.TypeText Text:=ChrW(769)
    Else
        Exit Sub
    End If
End Sub

Лучше заменить на:

Код: Выделить всё

Public Sub AddAcccent(VowelStress As Boolean)
    If VowelStress Then Selection.TypeText Text:=ChrW(769)
End Sub

2. Я бы сделал так (необходимо, либо выделить 1 символ, на который вы ставите ударение, либо поставить курсор перед этим символом):

Код: Выделить всё

Option Explicit

Sub MyTstSub()

Const Vowels As String = "АЕЁИОУЮЯаеёиоуюя" ' добавь, если что пропустил :-). английские гласные сюда же

Dim sSelected As String
Dim nVPos As Long

sSelected = Selection.Text

If Len(sSelected) = 2 And AscW(Right(sSelected, 1)) = 769 Then

    MsgBox "Вы пытаетесь поставить ударение второй раз."

ElseIf Len(sSelected) > 1 Then

    MsgBox "Выделите только 1 символ"

Else

    nVPos = InStr(1, Vowels, sSelected, vbBinaryCompare)
    If nVPos Then

        With Selection
            nVPos = .Start + 1
            .Start = nVPos
            .End = nVPos
            .TypeText ChrW(769)
        End With
   
    Else
        MsgBox "Вы пытаетесь поставить ударение на согласную букву ... (дальше сами напишете)"

    End If

End If

End Sub

[Diamock]

Уважаемые! Спасибо!

Буду мучить VBA!