Текст разными стилями в одной клетке таблицы

[ArtNeoX]

Из vb6 в Word создается таблица. Нужно в одной ячейке вставить текст двумя строками. Первая строка жирный текст, вторая обычным текстом.


TableWord.Cell(1, 5).Range.Select

With TableWord.Application.Selection
.InsertAfter "Строка жирным текстом" & vbCrLf
.Font.Bold = True
.EndOf
End With

With TableWord.Application.Selection
.InsertAfter "Строка не жирным текстом" & vbCrLf
.Font.Bold = False
.EndOf
End With

В результате появляется только первая строка жирным текстом, вторая не печатается. Что не так?

[Qwertiy]

Есть подозрение, что надо выделять не ячейку, а текст внутри.

[ArtNeoX]

А если текст выводится все время разный, разной длины.
Есть идеи как сделать?

[pronto]

Код: Выделить всё

   Dim wrdApp As Word.Application
   Dim wrdDoc As Word.Document
   
   Dim wrdSelection As Word.Selection
   
   ' создать экземпляр Word'ы
   Set wrdApp = CreateObject("Word.Application")
 
   ' добавить новый документ
   Set wrdDoc = wrdApp.Documents.Add
   
   Set wrdSelection = wrdApp.Selection
 
   ' создать таблицу
   wrdDoc.Tables.Add wrdSelection.Range, 2, 2, wdWord9TableBehavior
   
  ' оформить
  wrdDoc.Tables(1).Cell(1, 1).Select
   
   With wrdSelection
      .Font.Size = 12
      .Font.Bold = True
      .TypeText "Строка с жирным начертанием"
      .TypeParagraph
     
      .Font.Bold = False
      .TypeText "Строка с обычным начертанием"
   End With

   wrdDoc.Tables(1).Cell(1, 2).Select
   With wrdSelection
      .Font.Size = 14
      .Font.Bold = False
      .Font.Color = wdColorIndigo
      .TypeText "Совет: Открыть "
      .Font.Bold = True
      .TypeText "Word"
      .Font.Bold = False
      .TypeText ", нажать F1, выбрать пункт «Оглавление», найти пункт «Microsoft Word Visual Basic Reference»,"
      .Font.Size = 18
      .TypeText "читать, изучать..."
   End With

   ' сделать Верду видимой
   wrdApp.Visible = True
   
   ' освободить ссылки
   Set wrdSelection = Nothing
   Set wrdDoc = Nothing
   Set wrdApp = Nothing

[Qwertiy]

А если текст выводится все время разный, разной длины.

Вообще не представляю, на что влияет длина текста...

[ArtNeoX]

Понял, спасибо. Надо написать мой код вот так:

TableWord.Cell(1, 5).Range.Select
With TableWord.Application.Selection
.Font.Bold = True
.TypeText "Строка жирным текстом"
.TypeParagraph
.Font.Bold = False
.TypeText "Строка не жирным текстом" & vbCrLf
End With


а для чего нужно ?
' освободить ссылки
Set wrdSelection = Nothing
Set wrdDoc = Nothing
Set wrdApp = Nothing

[pronto]

Объекты в VB имеют счётчик ссылок. Это означает, что объект хранит количество ссылок на себя. Когда на объект нет ссылок (счётчик = 0), он уничтожается.

При выходе из процедуры, счётчик ссылок уменьшается на единицу — проще говоря — объект автоматически уничтожается. Поэтому в таких случаях нет надобности принудительно объектной переменной (ссылке на объект) присваивать Nothing.

В других случаях, когда необходимо уничтожить громоздкий объект до выхода из процедуры, это делать обязательно. Ещё это относится к объектам, которые объявлены глобально, так как они могут (и будут) существовать вплоть до завершения программы.

Присвоение ссылке на объект Nothing не обязательно приведёт к уничтожению объекта, так как необходимо ВСЕ ссылки на этот объект установить в Nothing. Особенно остро эта проблема возникает с рекурсивными (циклическими) ссылками:

Код: Выделить всё

Sub Foo()
  Dim Token As Object, Phrase As Object

  Set Token = CreateObject("Parser.Token")
  Set Phrase = CreateObject("Parser.Phrase")

  Set Token.Counter = Phrase
...
...
  Set Phrase.Builder = Token
...
...
End Sub

При завершении такой процедуры эти объектные ссылки образуют утечку, потому что они ссылаются сами на себя. Невозможно уничтожить ссылку обнулением объектной переменной, тут необходимо зачистить сами свойства.

То есть правильно так:

Код: Выделить всё

Set Token.Counter = Nothing
Set Phrase.Builder = Nothing

а не

Код: Выделить всё

Set Token = Nothing
Set Phrase = Nothing

Есть ещё подводный камень при использовании ключевого слова New в объявлении объектных переменных.

Код: Выделить всё

Dim Cn As New ADODB.Connection

В таком случае объект создаётся при первом обращении (использовании) к нему, а не там где было использовано ключевое слово New. Присвоение такой ссылке на объект Nothing может уничтожить его, но он будет создан заново при последующем обращении к нему. Чтобы нечаянно не плодить "зомбоков" лучше не использовать такую форму объявления, а использовать оператор New, который не обладает таким "воскрешающим" поведением.

Код: Выделить всё

Dim Cn As ADODB.Connection
Set Cn = New ADODB.Connection

[Хакер]

pronto, много кривостей.

Это означает, что объект хранит количество других объектов, которые ссылаются на него.

Объект не хранит кол-во других объектов. Объект хранит количество ссылок на себя. (И если уж быть совсем точно, то не объект хранит, а интерфейс хранит).

счётчик локально объявленного объекта уменьшается на единицу

Не существует никаких локально объявленных объектов. Локально могут быть объявленными только переменные, хранящие ссылки.

В других случаях, когда необходимо уничтожить громоздкий объект до выхода из процедуры, это делать обязательно.

Зануление ссылки не гарантирует уничтожения объекта.

рисвоение такому объекту Nothing может уничтожить его,

Присвоение ссылке, а не объекту.

[pronto]

Хакер, спасибо за уточнения! Подправил свой предыдущий пост.
Это наверное первый раз, когда я формулирую эти знания в письменном виде — от этого некоторая путанность в терминологии

[ArtNeoX]

Вообщем что объявляли Dim делаем Nothing

[Qwertiy]

Вообщем что объявляли Dim делаем Nothing

Нет. Перечитай ещё раз.