По поводу того, что «Call» в VB/VBA — атавизм

[Хакер]

— Думаете в VB ключевое слово Call — атавизм? Думаете его можно убрать из языка?
— Никак нет! Не атавизм, и убрать нельзя.

Зачем же оно тогда нужно, если можно всегда обойтись без него?
А вот не всегда. Это фича

Код: Выделить всё

Public Sub Name()
    MsgBox "Я процедура Name"
End Sub

Private Sub Main()
    On Error Resume Next
    Call Name
    Name "c:\pagefile.sys" As "c:\swapfile.sys"
End Sub


А теперь попробуйте убрать Call и посмотрите, что получится. Или попробуйте придумать, как здесь обойтись без Call.

В VB есть два семейства ключевых слов: ключевые слова из одного никогда не могут быть использованы в качестве имён процедур/функций/переменных и т.п. Кл. слова из вторых — могут.

В частности, вы можете создать свойство с именем «Property»:

Код: Выделить всё

Public Property Get Property()
End Property

Public Property Let Property(ByVal vNewValue)
End Property

Зачем это может быть нужно? В таком виде, вряд ли это полезно, но если вспомнить про параметрические свойства:

Код: Выделить всё

Public Property Get Property(Property_Id_Or_Name)
    ' Какой-нибудь мудрёный код
End Property

Public Property Let Property(Property_Id_Or_Name, ByVal vNewValue)
   ' Какой-нибудь мудрёный код
End Property

даёт вам возможность делать так:

Код: Выделить всё

SomeObject.Property("Color") = xyz
SomeObject.Property("Width") = abc
SomeObject.Property("Style") = 123
Ivan.Property("Имя второй жены") = "Мария"

Или даже так:

Код: Выделить всё

SomeObject!Color = xyz
SomeObject!Width = abc
SomeObject!Style = 123
Ivan![Имя второй жены] = "Мария"

Ну в каком ещё языке возможны такие трюки?

[ger_kar]

— Думаете в VB ключевое слово Call — атавизм? Думаете его можно убрать из языка? — Никак нет! Не атавизм, и убрать нельзя.

Согласен, и кроме описанного случая, когда в принципе без Call обойтись невозможно, есть случаи, когда применение Call значительно улучшает понятность и читаемость кода, особенно если имена переменных по наименованию схожи с именами процедур. А по поводу

В VB есть два семейства ключевых слов: ключевые слова из одного никогда не могут быть использованы в качестве имён процедур/функций/переменных и т.п. Кл. слова из вторых — могут.

Благодаря этому практически все встроенные функции можно заменить на пользовательские.

[Хакер]

Благодаря этому практически все встроенные функции можно заменить на пользовательские.

Сказано абсолютно не к месту. Глупо. Встроенные функции и так не используют в своих именах ключевые слова. Так что связи — ноль.

[Proxy]

А кому и почему call не угодил? Удобно же, call msgbox вообще часто использовал, когда поравну что она возвращает, но нужна именно не одноимённая процедура, которая несколько урезана в vb6

[Хакер]

но нужна именно не одноимённая процедура

Не одноимённая процедура, а что?

[ger_kar]

А вообще какие ключевые слова можно использовать для наименования пользовательских функций? Т.е. есть ли четкий список или может определенный критерий или надо делать эксперименты и проверять получится или нет?

[Хакер]

Т.е. есть ли четкий список или может определенный критерий или надо делать эксперименты и проверять получится или нет?

Вряд ли кто-то составлял подобный список.

Да и вообще вопрос, что считать ключевым словом? Например Access и Read — это ключевые слова?

[ger_kar]

Да и вообще вопрос, что считать ключевым словом?

Да четкого критерия по сути и нет, наверное вместо термина "ключевое слово" лучше использовать "зарезервированное слово".

[Хакер]

Являются ли Access, Read и BF таковыми?

[ger_kar]

Ну Access и Lock да, а что до BF, то я такого ключевого или даже зарезервированного слова вообще не знаю.

PS: А кстати что это? Имеется ввиду BF.

[Хакер]

Речь о Read, а не о Lock
Почему же я могу объявить переменные Read, Access и BF?

S: А кстати что это? Имеется ввиду BF.

Border-Filled.

Код: Выделить всё

Me.Line (500, 500)-(1500, 1000), vbRed, BF

[Qwertiy]

А теперь попробуйте убрать Call и посмотрите, что получится. Или попробуйте придумать, как здесь обойтись без Call.

А почему квадратные скобки не помогают?

Border-Filled.

Код: Выделить всё

Me.Line (500, 500)-(1500, 1000), vbRed, BF

Ну ты вспомнил

[Proxy]

Не одноимённая процедура, а что?

Если мне не изменяет память, то в vb6 есть ещё функция msgbox, которая возвращает код нажатой пользователем кнопки. И вроде с помощью неё можно было указать заголовок окна. Сейчас не могу проверить.

[Qwertiy]

функция msgbox, которая возвращает код нажатой пользователем кнопки.

По-твоему Call вызывает не её?

[Proxy]

Я всегда считал, что там отдельная встроенная процедура и отдельная встроенная функция, одно вызывается как процедура, втрое как функция (синтаксически должно требоваться её значение, либо значение должно возвращаться call как в некоторых языках с void, в противном случае используется процедура). Может быть я изначально с чем-то перепутал call в vb6.

[Хакер]

Где ты вычитал такую ересь?
Есть всего одна функция MsgBox, обяъвленная в TLB-шке, подключенной к проекту. В библиотеке она называется rtcMsgBox, а в пространстве имён VB появляется под именем просто MsgBox. Она одна. И она возвращает номер нажатой кнопки. И она позволяет указать заголовок, конечно же.

[Proxy]

Проверил. Действительно перепутал с чем-то, мне казалось там и всплывающие подсказки разные были, с разным количеством параметров.

[ger_kar]

Я вот могу припомнить, что из встроенных процедур/функций, только под одним именем Mid прячется парочка процедура/функция. Т.е. есть и функция Mid и процедура Mid.

[NashRus]

Я вот могу припомнить, что из встроенных процедур/функций, только под одним именем Mid прячется парочка процедура/функция. Т.е. есть и функция Mid и процедура Mid.

Во как.
А еще есть оператор Mid.
Или правду думаешь, что процедуре можно присвоить значение.

[Хакер]

Во как.
А еще есть оператор Mid.
Или правду думаешь, что процедуре можно присвоить значение.

Хватит вам придумывать.

Mid$ — с точки зрения механики языка, это обычное параметрическое property. У параметрического Property, как и у обычного, непараметрического, можно получать знечение и присваивать ему новое.

[Хакер]

Полноценная обёртка над Mid$, полностью сохраняющая «синтаксис» оригинала:

Код: Выделить всё

Public Property Get MyOwnMid$(ByRef Strng As String, ByVal Start As Long, Optional Length)
    MyOwnMid = Mid$(Strng, Start, Length)
End Property

Public Property Let MyOwnMid(ByRef Strng As String, ByVal Start As Long, Optional Length, ByVal vNewValue As String)
    Mid$(Strng, Start, Length) = vNewValue
End Property


Public Sub Main()
    Dim hw As String
    hw = "Hello World"
   
    MsgBox MyOwnMid$(hw, 4, 5)
    MyOwnMid$(hw, 3, 9) = "y NashRus!"
    MsgBox hw
End Sub


Вызови и оцени. Или ты вправду думает, что процедуре можно присвоить значение свойству нельзя присвоить значение?

[NashRus]

Я про то, что нет такой процедуры Mid.

А насчет property, как вариант, может там внутри, а снаружи видно, что он:
- подсвечивается в IDE как statement, а Property не подсвечиваются так,
- в MSDN описывается как statement (mk:@MSITStore:C:\Program%20Files%20(x86)\Microsoft%20Visual%20Studio%206\MSDN\2001JAN\1033\vbenlr98.chm::/html/vakeyMid.htm),
- не показывается в Object Browser, а Property показываеются.

Насчет обертки, ну да, конечно можно так. Кто же спорит.

[Хакер]

Я специально сказал «в соответствии с механикой языка». А изнутри оно да, обрабатывается как особый случай.

[Qwertiy]

Полноценная обёртка над Mid$, полностью сохраняющая «синтаксис» оригинала:

Хм... А этот код действительно работает? Мне казалось, что Optional в свойставах не допускается...
Сейчас нет времени проверить.

[Хакер]

Ещё как допускается и работает. Но более корректная реализация свойства-обёртки была бы такой:

Код: Выделить всё

Public Property Let MyOwnMid(ByRef Strng As String, ByVal Start As Long, Optional ByVal Length, ByVal vNewValue As String)
    If IsMissing(Length) Then
        Mid$(Strng, Start) = vNewValue
    Else
        Mid$(Strng, Start, Length) = vNewValue       
    End If
End Property