Помогите создать поиск без контролов

[mihlon]

Подскажите плиз исправить ошибки. Я пытаюсь создать свой поиск по папкам для начала.

[Хакер] :: Код вырезан. Код надо оформлять правильно. А в следующий раз будет ещё и наказание.

Если же я уберу строку On Error Resume Next, то появляется ошибка № 52 "Bad file name of number"
Буду очень признателен за помощь, может у кого-нибудь есть другие варианты алгоритма поиска? будет оч полезно)

[mihlon]

Подскажите плиз исправить ошибки. Я пытаюсь создать свой поиск по папкам для начала.

Код: Выделить всё

Private Sub Search(patch As String)
Dim strPath As String, strName As String, i As Integer, flname() As String

strPath = patch
strName = Dir(strPath, vbDirectory)

On Error Resume Next

Do While strName <> ""
    If strName <> "." And strName <> ".." Then
        If (GetAttr(strPath & strName) And vbDirectory) = vbDirectory Then       
            ReDim Preserve flname(i)
            flname(i) = strPath & strName & "\"
            i = i + 1
        End If
    End If
   
    strName = Dir
Loop

If i Then
    For i = 0 To UBound(flname)
        Search flname(i)
    Next i
End If
End Sub
Private Sub Form_Load()
Search "C:\"
End Sub


Если же я уберу строку On Error Resume Next, то появляется ошибка № 52 "Bad file name of number"
Буду очень признателен за помощь, может у кого-нибудь есть другие варианты алгоритма поиска? будет оч полезно)

[mihlon]

Извините пожалуйста, я не частый здесь гость, поэтому не успел узнать всех тонкостей.

[Diamock]

Буду очень признателен за помощь, может у кого-нибудь есть другие варианты алгоритма поиска?

Уважаемый Mihlon. Указав в строке поиска Яндекса: "Рекурсивный поиск", я нашёл готовый код в первом десятке ссылок.

[Dmitriy2003]

Где Поиск

[qwertyhp]

2mihlon: У меня Ваш код выдал ошибку 52, когда наткнулся на некорректное имя сохрвнённой IE6 странички - имя содержит "?" и не читается и не удаляется. Глюк файловой системы (интересно - а что думает сама MSoft по поводу подобных сохранений, а заодно - по поводу попыток IE сохранять сверхдлинные имена файлов, даже не заморачиваясь на сервис по их укорочению?).
Ошибка с кодом 53 была выдана при запросе "Search "C:\WINDOWS"" - потребовался правый слэш.
А так вроде без нареканий. mihlon, попробуйте код на другой папке.

[Andrey Fedorov]

Держите примерчик рекурсивного поиска файлов по маске:

Код: Выделить всё

Option Explicit

Public Sub Main()
    Dim mНайденныеФайлы() As String, i As Long
    Dim s As String
   
    FindFileInFolder CreateObject("Scripting.FileSystemObject").GetFolder(Environ("ProgramFiles") & "\Internet Explorer"), _
                        "i*.exe", _
                        mНайденныеФайлы, i
    Debug.Print
    If i Then
        Debug.Print "Найдено " & i & " Файлов"
        For i = 0 To UBound(mНайденныеФайлы)
            Debug.Print "Файл " & i + 1 & vbTab & mНайденныеФайлы(i)
        Next i
    Else
        Debug.Print "Файлов не обнаружено"
    End If
End Sub

Public Sub FindFileInFolder(foo As Object, sШаблонПоискаФайла As String, mНайденныеФайлы() As String, Optional iCountFiles As Long = 0)
    Dim fo As Object, f As Object
   
    On Error Resume Next
    If iCountFiles <= 0 Then Erase mНайденныеФайлы: iCountFiles = 0
    For Each f In foo.Files
        If f.Name Like sШаблонПоискаФайла Then
            iCountFiles = iCountFiles + 1
            ReDim Preserve mНайденныеФайлы(iCountFiles - 1)
            mНайденныеФайлы(iCountFiles - 1) = f.Path
        End If
    Next f
    For Each fo In foo.SubFolders
        FindFileInFolder fo, sШаблонПоискаФайла, mНайденныеФайлы, iCountFiles
    Next fo
End Sub