Vba из Vb

[K Victor A]

Подскажите! у меня такая проблема: создаю вордовский документ из VB6 заполняю его, все в порядке, сохраняю, закрываю, не закрывая свое приложение опять создаю документ пишет ошибку: 462 the remote server machine does not exist or unavailable. выключаю свое приложение, запускаю все работает. Подскажите в чем проблема может что нибудь нужно обнулять?! переменные word document и word application обнуляю!?!?!

[DeMONiZ]

Возможно это тебе поможет:
http://forum.vingrad.ru/forum/topic-205736.html

[K Victor A]

Код: Выделить всё

Call ShellExecute(Me.hwnd, "open", "Акт.rtf", "", (App.Path & "\Формуляр\"), 3)

    ActiveDocument.SaveAs FileName:="Акт.doc", FileFormat _
        :=wdFormatDocument, LockComments:=False, Password:="", AddToRecentFiles:= _
        True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:= _
        False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False

‘ сохраняет в мои документы

(процедуры заполнения документа)

ActiveDocument.Close
Word.Application.Quit



Не закрывая своего приложения опять вызываю процедуру! Пишет ту же ошибку!, после перезагрузки своего приложения опять работает один раз. Ошибку выдает на сохранении:
ActiveDocument = <the remote ser dos not exist ...> - вобщем сама ошибка 462ая
Не обращайте внимания на ShellExecute – это просто уже перебор различных вариантов, если использую:

Код: Выделить всё

Set WordApp = New Word.Application
Set WordDoc = WordApp.Documents.Open("C:\1\Акт.doc") ' Word.Application ->WordApp
WordApp.Visible = True


ChangeFileOpenDirectory _
        App.Path & "\Акты\"
    ActiveDocument.SaveAs FileName:="1.doc", _
        FileFormat:=wdFormatDocument, LockComments:=False, Password:="", _
        AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
        EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData _
        :=False, SaveAsAOCELetter:=False


WordDoc.Close
WordApp.Quit

Set WordApp = Nothing
Set WordDoc = Nothing



Все тоже самое Подскажите как исправить!?!?!?

[Vi]

У тебя проблемы с обращением к объекту Global Ворда или его глобальным функциям, например, при ActiveDocument.SaveAs происходит обращение к объекту Global и его функции ActiveDocument, т.е. Global.ActiveDocument.SaveAs. Поэтому обращайся к функциям ТОЛЬКО через созданные или полученные объекты. Вот это вот "Word.Application ->WordApp" в примере и есть замена обращения глобального объекта на свой, созданный.

Объяснение.
Некоторые объекты описаны в TLB с атрибутом appobject:

The [appobject] attribute also indicates that the functions and properties of the coclass are globally available in the current type library.

При обращении к методам этого объекта он создается автоматически (по крайней мере в VB) и его удаление лежит на приложении. Однако в этом случае Ворд при выходе в конце работы с ним РЕАЛЬНО не выходит, а прячется, потому что есть неявный объект с глобальными функциями, который создал для пользователя VB. И, что самое паскудное, работу с этим объектом блокирует из-за своего внутренней вредности, поскольку объект Application уже был завершен. Освободить объект, который создал VB, нет возможности (для этого нужно выгрузить TLB приложения Ворд). И ситуация становится патовой.

[K Victor A]

то есть ничего нельзя сделать?! я обхожу так: из приложения я создаю несколько word документов, после создания каждого сохраняю и складываю в определенную папку (закрываю) затем пишу

Код: Выделить всё

WordApp.visible = false

проблемы начинаются после того как вручную открываю word и закрываю. в памяти уже нет word application и начинается все та же ошибка. может как нить по другом это все сделать?!

[alibek]

Посты Vi — это (обычно) кладезь мудрости.
Поэтому перечитывай его сообщение, пока на тебя не снизойдет просветление.
Тогда, может быть, ты заметишь фразу

Поэтому обращайся к функциям ТОЛЬКО через созданные или полученные объекты. Вот это вот "Word.Application ->WordApp" в примере и есть замена обращения глобального объекта на свой, созданный.

[K Victor A]

Так, ну это я понял! (что нужно использовать переменные) Пример описывал с переменными и без! Все равно выводит Вот код:

Код: Выделить всё

Dim WordApp As New Word.Application
Dim WordDoc As Word.Document
On Error GoTo Oshibka

With WordApp
        .WindowState = Word.WdWindowState.wdWindowStateNormal
        .Documents.Open App.Path & "\Формуляр\Акт.rtf"
         Set WordDoc = WordApp.ActiveDocument
        .Visible = True
End With
   
    ChangeFileOpenDirectory _
        App.Path & "\Акты\"
    WordDoc.SaveAs FileName:="Акт №" & Left(Text100.Text, 8) & Mid(Text100.Text, 10, 6) & right(Text100.Text, 5) & ".rtf", _
        FileFormat:=wdFormatDocument, LockComments:=False, Password:="", _
        AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
        EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData _
        :=False, SaveAsAOCELetter:=False

With WordDoc.PageSetup
        .LineNumbering.Active = False
        .Orientation = wdOrientPortrait
…

.BookFoldPrintingSheets = 1
.GutterPos = wdGutterPosLeft
    End With

With WordApp.Selection
    .ParagraphFormat.Alignment = wdAlignParagraphLeft
    .Font.Bold = True
    .Font.Size = 12
    .TypeText Text:="Приложение 1"
…
.Font.Underline = wdUnderlineSingle
     .TypeText Text:="" & Trim(Adodc2.Recordset.Fields(5))
     
     
     
     End If
           
    End With

    WordDoc.Save
WordDoc.Close
WordApp.Quit

Set WordDoc = Nothing
Set WordApp = Nothing

MsgBox "Файл экспортирован в папку Акты", vbInformation, "Информация"


Это весь код который я использую! Без внутренностей.

В чем тогда моя ошибка?
Выводит туже ошибку когда создаю второй документ. На строке:

Код: Выделить всё

ChangeFileOpenDirectory

Помогите разобраться четыре дня топчусь на одном месте

[K Victor A]

Вот так еще делал! Все не то...

Код: Выделить всё

Dim WordApp As Word.Application
Dim WordDoc As Word.Document
On Error GoTo Oshibka

Set WordApp = New Word.Application
Set WordDoc = WordApp.Documents.Open(App.Path & "\Формуляр\Акт.rtf")

WordApp.Visible = True

    ChangeFileOpenDirectory _
        App.Path & "\Акты\"
    WordDoc.SaveAs FileName:="Акт №" & Left(Text100.Text, 8) & Mid(Text100.Text, 10, 6) & right(Text100.Text, 5) & ".rtf", _
        FileFormat:=wdFormatDocument, LockComments:=False, Password:="", _
        AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
        EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData _
        :=False, SaveAsAOCELetter:=False

[Vi]

Все вызовы должны быть через объект WordApp, потому что он обладает всеми теми функциями, которые являются глобальными.
Т.е.

Код: Выделить всё

WordApp.ChangeFileOpenDirectory App.Path & "\Акты\"

тоже.

[K Victor A]

Всем огромное спасибо! наконец то заработало! всем счастья!!!