Доступ к файлам в скрытой папке

[Kardinalli]

Столкнулся с такой проблемой, нужно обеспечить доступ к файлам, находящимся в скрытой папке.
Получается так, запись в файл идет без проблем, а вот чтение - ни в какую. Как решить проблему?

[iGrok]

Столкнулся с такой проблемой, нужно обеспечить доступ к файлам, находящимся в скрытой папке.
Получается так, запись в файл идет без проблем, а вот чтение - ни в какую. Как решить проблему?

Что значит "ни в какую"?
Ошибку какую-то выдаёт? Тогда текст ошибки в студию. Или что ещё происходит?

У меня всё работает.

Код: Выделить всё

Option Explicit

Private mFilePath As String
Private mFolderPath As String
Private tb As Control

Private Sub Load()
Dim hF As Long, tS As String
    hF = FreeFile
    Open mFilePath For Binary As hF
        tS = Space$(LOF(hF))
        Get #hF, , tS
        tb.Caption = tS
    Close hF
End Sub

Private Sub Save()
Dim hF As Long
    hF = FreeFile
    Open mFilePath For Append As hF
        Print #hF, , tb.Caption
    Close hF
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    If Shift = vbCtrlMask Then
        If KeyCode = vbKeyS Then
            Save
        ElseIf KeyCode = vbKeyL Then
            Load
        End If
    End If
End Sub

Private Sub Form_Load()
    mFolderPath = App.Path
    mFolderPath = mFolderPath & IIf(Right$(mFolderPath, 1) = "\", "", "\") & "testfolder"
    On Error Resume Next
    MkDir mFolderPath
    SetAttr mFolderPath, vbHidden
    On Error GoTo 0
    mFilePath = mFolderPath & "\testfile.txt"

    Set tb = Me.Controls.Add("VB.Label", "txtContent")
    tb.Left = Me.ScaleLeft + 60
    tb.Top = Me.ScaleTop + 60
    tb.Width = Me.ScaleWidth - 120
    tb.Height = Me.ScaleHeight - 120
    tb.BorderStyle = 1
    tb.Visible = True

    tb.Caption = "Проверка записи и чтения файла, находящегося в скрытой папке" & vbCrLf & "Запись в файл - Ctrl-S, чтение - Ctrl-L"
End Sub

Private Sub Form_Resize()
    If Not tb Is Nothing Then
        tb.Left = Me.ScaleLeft + 60
        tb.Top = Me.ScaleTop + 60
        tb.Width = Me.ScaleWidth - 120
        tb.Height = Me.ScaleHeight - 120
    End If
End Sub


[Kardinalli]

Сорри, нашел в чем была проблема, большое спасибо!

Кстати, чтобы работать со скрытыми файлами (не папками), приходится сначала менять атрибуты файла на видимый, затем читать/записывать, затем снова менять атрибут. А есть вариант, не менять атрибуты?

[Хакер]

Нет необходимости менять атрибут, не выдумывай.

[VBTerminator]

Ошибку какую-то выдаёт? Тогда текст ошибки в студию. Или что ещё происходит?

Вероятно, у папки что-то с правами на чтение.

[Kardinalli]

Нет необходимости менять атрибут, не выдумывай.

Читается из скрытого файла без проблем, запись выдает ошибку выполнения "75".

На запись используется примерно вот такой код:
fnum = FreeFile
SetAttr Pt & "\file.ini", 0 'открыть файл для чтения,атрибут "архивный"
Open Pt & "\file.ini" For Output As #fnum
Write #fnum, ms1 '
Close #fnum
SetAttr Pt & "\file.ini", 2 'открыть файл для чтения,атрибут "скрытый"

Если исключить операции по изменению атрибута, то и выходит указанная ошибка.

[iGrok]

Если исключить операции по изменению атрибута, то и выходит указанная ошибка.

Используй For Binary вместо For Output.
Ну и соответственно, работай с файлом через Get/Put, а не Input/Write(Print).

[Kardinalli]

Используй For Binary вместо For Output.
Ну и соответственно, работай с файлом через Get/Put, а не Input/Write(Print).

Точно, этот вариант не требует предварительного изменения атрибутов, спасибо!