Переобразование строки из HEX в нормальный вид

[AntonGV]

Работаю с модемом с помощью AT команд. В ответ на USSD запрос (AT+CUSD=1,"*102#",15) приходит такая строка:

+CUSD: 2,"04110430043B0430043D044100200039002E0030003900200440002E002004220432043E0439002004420435043B04350444043E0...",72

Как-то ее на преобразовать в юникод. Каждые два символа - 1 байт (HEX)
Пробовал преобразовывать так:

Код: Выделить всё

  Dim t As String, i As Integer, a As Byte, o As String, b() As Byte
  t = "110430043B0430043D044100200039002E0030003900200440002E002004220432043E0439002004420435043B04350444043E043D002004430433043004340430043504420020043B044E0431043E04390020044504380442002E04170432043E043D04380020003000360036003500210020003300300440002F043C0438043D"
  ReDim b(Len(t) / 2)
  For i = 1 To Len(t) Step 2
    o = Mid(t, i, 2)
    a = Val("&h" + o)
    b((i - 1) / 2) = a
  Next i
  Text1 = b


но получается неправильно:

БаланA 9.09Р@.РТво9Ртелефо=РугадаеBРлюбо9РхиBЮЗвон8 0665! За@Ями=

Подскажите как правильно преобразовать в читабельный текст?

[alibek]

Код: Выделить всё

Function Hex2Dump(ByVal HexString As String) As Byte()
  Dim buff() As Byte, I As Long, N As Long
  N = Len(HexString) / 2
  ReDim buff(0 To N - 1)
  For I = 0 To N - 1
    buff(I) = Val("&h" & Mid$(HexString, 1+2*I, 2))
  Next I
  Hex2Dump = buff
End Function

Если там действительно юникод, то затем StrConv.
Но мне думается, что на USSD-запрос приходит UTF.

[AntonGV]

alibek, Тоже самое получается, что и у меня в первом посте
Строка получается только на половину читаемая. Если сравнивать то что приходит, и то что должно быть, то получается так:
приходит:       1104;3004;3B04;3004;3D04;4100;2000;3900;2E00;3000;3900;2004;4000;2E00;2004;2204;3204;3E04;3900;2004;4204...
должно быть: 1104;3004;3B04;3004;3D04;4104;2000;3900;2E00;3000;3900;2000;4004;2E00;2000;2204;3204;3E04;3904;2000;4204...
Везде есть "04"... Как это можно исправить? ведь эти "сбои" находятся в произвольных местах текста

Но мне думается, что на USSD-запрос приходит UTF.

Здесь пишут, что ответ приходит в юникоде.

[alibek]

Здесь пишут, что ответ приходит в юникоде.

Наверняка ошибаются.

[HiSER]

Ломал ломал голову пока не увидел что байты перевёрнуты

Код: Выделить всё

Private Sub Command1_Click()
MsgBox USSDConv("04110430043B0430043D044100200039002E0030003900200440002E002004220432043E0439002004420435043B04350444043E043D002004430433043004340430043504420020043B044E0431043E04390020044504380442002E04170432043E043D04380020003000360036003500210020003300300440002F043C0438043D")
End Sub

Private Function USSDConv(lpStr As String) As String
Dim i As Long
USSDConv = String$(Len(lpStr) \ 2, 0)
For i = 1 To Len(USSDConv) Step 2
Mid$(USSDConv, i, 1) = Chr$(CLng("&H" & Mid$(lpStr, i * 2 + 1, 2)))
Mid$(USSDConv, i + 1, 1) = Chr$(CLng("&H" & Mid$(lpStr, i * 2 - 1, 2)))
Next i
USSDConv = StrConv(USSDConv, vbFromUnicode)
End Function


[Хакер]

Ужасный код

Вот код в два раза быстрее, чем твой, и действительно делающий конвертацию (а твой код потеряет все неASCII символы во время StrConv...).

Код: Выделить всё

Private Function USSDConv(lpStr As String) As String
    Dim i As Long
    USSDConv = String$(Len(lpStr) \ 4, 0)
    For i = 0 To Len(USSDConv) - 1
        Mid$(USSDConv, i + 1, 1) = ChrW$(CLng("&H" & Mid$(lpStr, i * 4 + 1, 4)))
    Next i
End Function

Можно убыстрить ещё в нескольк раз, отказавшись от двух Mid$, Chr, конкатенации с "&H" и превращения строки в число, заюзав байтовые массивы и обычную математику.

[AntonGV]

Большое спасибо, все работает