RGB

[VBfrv]

Приветствую всех. По поводу графики вопрос. Мне нужно разложить цвет в точке изображения на три переменные R,G, и B. Я знаю только один оператор получения цвета точки -
x = picture1.Point (i,j). Этот оператор возвращает одно число, можно ли получить информацию о точке с разбиением на R G B каналы? Заранее спасибо.

[BV]

В VC++ есть замечательные макросы -- GetR[G, B]Value... а в VB ручками, CopyMemory или побитовые операции.

Ну, или так:

Код: Выделить всё

        B = Color \ 65536: Color = Color Mod 65536
        G = Color \ 256: Color = Color Mod 256
        R = Color

[Naked]

BV это что? оно работает?

R = (color And &HFF)
G = ((color \ 256) And &HFF)
B = ((color \ 65536) And &HFF)

[alibek]

Можно еще и так.

Код: Выделить всё

Private Type RGBType
  Red As Byte
  Green As Byte
  Blue As Byte
  Alpha As Byte
End Type

Private Type CType
  Color As Long
End Type

...

Dim C1 As CType
Dim C2 As RGBType
...
LSet C2 = C1


[Денис]

И еще способ с HEX'ами:

Если преобразовать цвет в хексы, получим строку вида FFFFFFFF
Где разряды соответствуют:

Код: Выделить всё

1   2     3    4
FF  FF    FF   FF
Red Green Blue Alpha

Примечание: и этот же метод и метод с конструкциями сработает также для преобразования четырех октетов IP в одно число формата Long для перебора IP-адресов, например..

[VBfrv]

Всем огромное спасибо. Первый вариант работает. Непонятно как, но работает ) Все гениальное просто.

[nekeda]

Что непонятного? Цвет = 65536 * синий + 256 * зелёный + красный

Отсюда и формулы.

[VBfrv]

Вот теперь все предельно ясно. Но первый вариант не работает с отрицительными значениями цвета. А оператор Point частенько такие выдает. Вариант с HFF эту проблему устраняет.

[HiSER]

Ещё вариант:

Код: Выделить всё

Private Type RGBQUAD
        rgbBlue As Byte
        rgbGreen As Byte
        rgbRed As Byte
        rgbReserved As Byte
End Type

Private Declare Sub PutMem4 Lib "msvbvm60" (ddDest As Any, ByVal ddValue As Long)

Private Sub Command1_Click()
Dim col As Long
Dim rgb As RGBQUAD

col = &H102030
PutMem4 rgb, col

Me.Caption = rgb.rgbRed & " - " & rgb.rgbGreen & " - " & rgb.rgbBlue
End Sub


[Viper]

HiSER, уже было по сути тоже самое