Почему мерцает длинныи Леибл - Текст при обновлении

[student-uni]

Обновляю в цикле Леибл - Текст - такои счетчик, показывающии номер итеррации цикла.
Так вот если леибл короткии - все идеально,
но если слишком широкии - то Текст в леибле мерцает.
Можно что-то сделать чтоб убрать это мерцание ?

Спасибо

[alibek]

Выводи текст через API, чтобы VB не перерисовывал сам.
Помести лейбл в контейнер (Frame или PictureBox).

[student-uni]

Поместил в контеинер - тоже самое.
Подскажите ключевые слова для поиска вывода Текста через АПИ ?

[BV]

DrawText/TextOut

[student-uni]

ерунда какая то
в событии лоад - срабатывает
а по клику кнопки - нет
В чем может быть дело ?
Спасибо

Код: Выделить всё

Option Explicit

Private Declare Function DrawText Lib "user32" Alias "DrawTextA" (ByVal hdc As Long, ByVal lpStr As String, ByVal nCount As Long, lpRect As RECT, ByVal wFormat As Long) As Long

Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Private Const DT_CENTER = &H1
Private Const DT_SINGLELINE = &H20
Private Const DT_VCENTER = &H4

Dim myRect As RECT

Private Sub Command1_Click()
  Me.ScaleMode = vbPixels
  myRect.Left = 0
  myRect.Top = 0
  myRect.Right = Me.ScaleWidth
  myRect.Bottom = Me.ScaleHeight
  DrawText Me.hdc, "Hello", Len("Hello"), myRect, DT_SINGLELINE Or DT_VCENTER Or DT_CENTER
End Sub

Private Sub Form_Load()
 
  Me.ScaleMode = vbPixels
  myRect.Left = 0
  myRect.Top = 0
  myRect.Right = Me.ScaleWidth
  myRect.Bottom = Me.ScaleHeight
  DrawText Me.hdc, "DrawText!", Len("DrawText!"), myRect, DT_SINGLELINE Or DT_VCENTER Or DT_CENTER
End Sub

[BV]

AutoRedraw?

[student-uni]

true
интересно что если я ставлю брекпоинт и пытаюсь отладить - второе слово выходит поверх первого !!!

[BV]

Я не спрашиваю, я указываю на причину. Кроме того есть Cls.

[student-uni]

Это функция обьекта напр PictureBox ?
а у меня структура
и еще PictureBox я по ссылке в функцую DrawText передать немогу

[BV]

Какая у тебя структура?
И зачем PictureBox передавать по ссылке? У него есть свойство hDC.

[Viper]

student-uni, что-то ты непонятное ответил... как то не в тему...

[dr.MIG]

Cls -- это метод. Есть и у формы, и у PictureBox. Для вывода текста, как тебе уже сказали, очищай то, куда выводишь этот текст (форму или PictureBox, используя этот самый Cls)
Осмелюсь предположить, что "не могу передать по ссылке" -- это значит, что когда автор пишет "DrawText Picture1.hdc,...", то в PictureBox ничего не отображается. Я прав? Если да, то перед вызовом функции DrawText используй Picture1.Cls и заполни структуру RECT следующим образом

Код: Выделить всё


  Picture1.ScaleMode = vbPixels
  myRect.Left = 0
  myRect.Top = 0
  myRect.Right = Picture1.ScaleWidth
  myRect.Bottom = Picture1.ScaleHeight


[student-uni]

2 dr.MIG
Спасибо получилось
вот рабочии код

Код: Выделить всё

Option Explicit

Private Declare Function DrawText Lib "user32" Alias "DrawTextA" (ByVal hdc As Long, ByVal lpStr As String, ByVal nCount As Long, lpRect As RECT, ByVal wFormat As Long) As Long

Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type

Private Const DT_CENTER = &H1
Private Const DT_SINGLELINE = &H20
Private Const DT_VCENTER = &H4



Private Sub Command1_Click()

  Dim myRect As RECT
Picture1.Cls
 
  Picture1.ScaleMode = vbPixels
  myRect.Left = 0
  myRect.Top = 0
  myRect.Right = Picture1.ScaleWidth
  myRect.Bottom = Picture1.ScaleHeight

   

  DrawText Picture1.hdc, "DrawText!", Len("DrawText!"), myRect, DT_SINGLELINE Or DT_VCENTER Or DT_CENTER
End Sub

Private Sub Command2_Click()
Dim myRect As RECT
Picture1.Cls
 
  Picture1.ScaleMode = vbPixels
  myRect.Left = 0
  myRect.Top = 0
  myRect.Right = Picture1.ScaleWidth
  myRect.Bottom = Picture1.ScaleHeight


  DrawText Picture1.hdc, "!", Len("!"), myRect, DT_SINGLELINE Or DT_VCENTER Or DT_CENTER
End Sub