usercontrol событие

[iolaus]

У меня есть узер контрол. я располагаю его на форме. у формы есть событие связаное с этим контролом, например клик. все работае на ура.

Если этот юзер контрол не выкладывать на форму, а загружать во время работы:

With Me.Controls.Add("Project1.CSE", "CSE", Me)
.Top = 0
.Left = Me.Width - .Width
.Visible = True
End With

то событие связаное с этим контроло уже не работает!!!
также неработает такое свойство как height и width

Почему? может мне кто подсказат?

Заанее спасибо

[GSerg]

Почему?

Очевидно потому, что ты просто включил в код процедуру CSE_Click в надежде, что она подхватится обработчиком нового контрола, чего, разумеется, не будет.
Нажми F1 и почитай про WithEvents. Или поищи его в поиске, он выделен красным.

[iolaus]

ну так это для работы с классами, а у меня то узер контрол. что-то я не понимаю как это применть в моем случае...

подскажите плз....

[EUGY]

Код: Выделить всё


Option Explicit
Private WithEvents CSE1 As VBControlExtender

Private Sub CSE1_ObjectEvent(Info As EventInfo)
Select Case Info.Name
Case "Click"
    Debug.Print "click"
End Select
End Sub

Private Sub Form_Load()
With Me.Controls.Add("Project1.CSE", "CSE1", Me)
.Top = 0
.Left = Me.Width - .Width
.Visible = True
End With
Set CSE1 = Me.Controls("CSE1")
End Sub


[iolaus]

Огромное спасибо!!!! именно то что надо.

[GSerg]

Зачем так сложно?

Код: Выделить всё

option explicit
Private WithEvents CSE1 As CSE

Private Sub CSE1_Click
  Debug.Print "click"
End Sub

Private Sub Form_Load()
  Set CSE1 = Me.Controls.Add("Project1.CSE", "CSE1")

  With CSE1
    .Move Me.Width - .Width, 0
    .Visible = True
  End With
End Sub

[iolaus]

короче я понял в чем я идиот. я не делал SET.
Спасибо всем.
Первый вариан мне если честно удобнее даже.

[iolaus]

Еще вопрос.
я так понял что withevents с массивамине работает.

можно ли как динамически загружать массив узерконтролов с последующей обрадоткй их событий?

[GSerg]

Слабо воспользоваться поиском?
http://bbs.vbstreets.ru/viewtopic.php?p=37547#37547

[EUGY]

Первый вариан мне если честно удобнее даже.

код приведенный GSerg "чуть-чуть не работает", в том смысле, что
он предполагает "оболочку Property Get/Let"
которой может и не быть у контрола.

Debug.Print CSE1.Width 'Error 461

[GSerg]

Что за "оболочка"?

[EUGY]

Что за "оболочка"?

Код: Выделить всё

Dim m_Width As Integer

Public Property Get Width() As Integer
    Width = m_Width
End Property

Public Property Let Width(ByVal New_Width As Integer)
    m_Width = New_Width
    'PropertyChanged "Width"
End Property


[GSerg]

Выложи сюда аттачем юзерконтрол, пожалуйста, у которого не будет свойства Width.

[EUGY]

Не надо иронии.
Создайте в проекте UserControl без свойств, событий и методов
и динамически положите его на форму, потом Debug.Print UserControl1.Width

И выложите аттачем юзерконтрол, у которого будет свойство Width.

[GSerg]

Какой забавный баг компилятора...
Впрочем, это не отменяет сути. Любой UserControl наследует от Control, и потому изначально автоматически обладает свойством Width и ешё рядом других полезных свойств.
Почему компилятор не просекает это, неизвестно, но от кода юзерконтрола это не зависит, а уж включать собственный код для Width и вовсе вредно.
Переменную CSE1 кастуешь к типу Control, и компилятор резко прозревает.
Но то, прозрел он или нет, не оказывает влияния на наличие Width у юзерконтрола. Оно есть. Унаследовано. И его не может не быть.

[EUGY]

dynamic.zip
http://www.codeguru.com/forum/showthrea ... g+controls

[iolaus]

воспользовался вот чем:

код формы

Код: Выделить всё

Private txtdoug() As DtextBox

Private Sub Form_Load()
Dim i As Integer
For i = 0 To 4
ReDim Preserve txtdoug(i)
Set txtdoug(i) = New DtextBox
txtdoug(i).MyMake Me, i
With Form1.Controls("dtext" & i) ' TxtAny
.Left = 700
.Top = 700 + 500 * i
.Width = 1240
.Height = 240
.Text = .Name
.Visible = True
End With
Next i

End Sub


код класса

Код: Выделить всё

Private WithEvents txtdoug As TextBox

Public Sub MyMake(Fname As Form, i As Integer)
Set txtdoug = Fname.Controls.Add("vb.textbox", "Dtext" & i, Fname)
End Sub

Private Sub txtdoug_Click()
ShoMsg txtdoug
End Sub

Private Sub ShoMsg(txtAny As TextBox)
MsgBox txtAny.Name
End Sub


но есть проблема в том что событие возникает в классе в не в форме на которой расположен элемент.

Как можно это поправить?

[iolaus]

разобрался. можно просто создать публичную функцию на форме и обратиться к ней через parent

[iolaus]

вот про добавление события например width к usercontrol все понятно.

а как например добавить такую штуку как Controls к Usercontrol, чтобы можно было получать список controlов используемых в нем???

[Viper]

Стоит заценить кнопку Правка