Как снять защиту с определенных ячеек?

[Sandra_83]

Подскажите, pls.

Мне нужно в Excel сделать всю книгу Protected, но оставить возможность для ввода информации в ячейки определенного цвета (например, желтого).

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
On Error Resume Next
If Cells.Interior.Color = 36 Then
Cells.Locked = Fasle
Else
Cells.Locked = True
End If
ThisWorkbook.ActiveSheet.Protect (pass)
End Sub

Как нужно исправить?

[KL]

Может так:

Код: Выделить всё

Const pass = ""

Private Sub Workbook_Open()
    Dim Sh As Worksheet
    For Each Sh In Worksheets
        Sh.Protect Password:=pass, userinterfaceonly:=True
    Next Sh
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    'If Not TypeOf Sh Is Worksheet Then Exit Sub
    Sh.Cells.Locked = True
    For Each c In Sh.UsedRange
        If c.Interior.ColorIndex = 36 Then c.Locked = False Else c.Locked = True
    Next c
End Sub

Но вобще не вижу смысла в повторе этой процедуры при каждой активации листа. Может лучше так:

Код: Выделить всё

Const pass = ""

Private Sub Workbook_Open()
    Dim Sh As Worksheet
    For Each Sh In Worksheets
        Sh.Protect Password:=pass, userinterfaceonly:=True
        Sh.Cells.Locked = True
        For Each c In Sh.UsedRange
            If c.Interior.ColorIndex = 36 Then c.Locked = False Else c.Locked = True
        Next c
    Next Sh
End Sub

[Sandra_83]

Последний вариант хороший, только что-то так тоже не работает.

А "c" - это что? Не нужно ли ее объявить как переменную?

[GSerg]

Обязательно. As Range. А за код без объявления переменных отрывать ручки, ножки, и чего там ещё...

[KL]

Последний вариант хороший, только что-то так тоже не работает.

А "c" - это что? Не нужно ли ее объявить как переменную?

Что конкретно значит "не работает"?

GSerg прав - обычно сам "отрываю ручки, ножки, и чего там ещё...за код без объявления переменных", а тут в попыхах облажался

Если след. код помещенный в модуль ThisWorkbook не срабатывает при открытии файла:

Код: Выделить всё

Option Explicit
Const pass = ""

Private Sub Workbook_Open()
    Dim Sh As Worksheet, c As Range
    For Each Sh In Worksheets
        Sh.Protect Password:=pass, userinterfaceonly:=True
        Sh.Cells.Locked = True
        For Each c In Sh.UsedRange
            If c.Interior.ColorIndex = 36 Then c.Locked = False Else c.Locked = True
        Next c
    Next Sh
End Sub

то по-моему может быть только 3 реальных причины:
- не включены макросы
- код цвета полей, которые должны бы разблокироваться, не 36
- ты забыла заменить значение константы Pass на реально использованный при защите листов пароль.

[Sandra_83]

Все уже работает ))
Спасибо большущее!!!

[Sandra_83]

KL, спасибки тебе отдельное, очень мне помог

[Sandra_83]

KL, help me one more time

Очень нужна быстрая помощь.
В примере приведенном выше, как сделать так, чтобы пользователь даже при protected worksheet мог делать делать group/ungroup ячеек (мог раскрывать и сворачивать ячейки по уже имеющимся плюсикам)?