DataCombo можно подсунуть отфильтрованный рекордсет?

[shady]

Код: Выделить всё

Private Sub dcRegTown_MouseUp(Index As Integer, Button As Integer, Shift As Integer, x As Single, y As Single)
Select Case Index
    Case 0
        On Error Resume Next
        rstTowns.Filter = "IDReg=" & dcRegTown(0).BoundText
       
        Set dcRegTown(1).RowSource = rstTowns
            dcRegTown(1).ListField = "Name"
            dcRegTown(1).BoundColumn = "ID"
            dcRegTown(1).Enabled = True
End Select
End Sub


в тестовой гриде по соседству прекрасно отражает отфильтрованное..
или же придется запросом рекордсет создавать?

[alibek]

После Filter сделай Requery.

[shady]

После Filter сделай Requery

сделал. тоже самое. весь рекордсет не отфильтрован и вываливается в комбо.
в таблице городов 176 000 записей, решил отказаться от этой идеи, по причине некоторой задержки при загрузки формы, сделал так:

Код: Выделить всё

Set rstTowns = New ADODB.Recordset
            rstTowns.Open "SELECT ID, IDReg, Name FROM Towns WHERE IDReg=" & dcRegTown(0).BoundText & "ORDER BY Name", conn

[Antonariy]

Отфильтруй и сделай копию. Сам пользуюсь таким способом.

Код: Выделить всё

Public Function CreateRSCopy(rsSource As ADODB.Recordset, Optional StructOnly As Boolean = False, Optional CurRecord As Boolean = False) As ADODB.Recordset
Dim rsCopy As ADODB.Recordset
Dim f As ADODB.Field
Dim i As Long
    Set rsCopy = New ADODB.Recordset
    For Each f In rsSource.Fields
        With f
            rsCopy.Fields.Append .Name, .Type, .DefinedSize, .Attributes And adFldIsNullable
            If .Type = adNumeric Then
                rsCopy.Fields(.Name).Precision = .Precision
                rsCopy.Fields(.Name).NumericScale = .NumericScale
            End If
        End With
    Next f
    rsCopy.open
    If StructOnly Then GoTo finish
    If rsSource.RecordCount > 0 Then
        If Not CurRecord Then rsSource.MoveFirst
        Do While Not rsSource.EOF
            rsCopy.AddNew
            For i = 0 To rsSource.Fields.Count - 1
                rsCopy.Fields(i).Value = rsSource.Fields(i).Value
            Next i
            If CurRecord Then GoTo finish
            rsSource.MoveNext
        Loop
        rsSource.MoveFirst
        rsCopy.MoveFirst
    End If
finish:
    Set CreateRSCopy = rsCopy
    Set rsCopy = Nothing
End Function

[alibek]

Antonariy, зачем такие сложности?
Если уж Requery не подошел (уж не знаю, почему, может используется DAO), то можно выставить фильтр и сделать Set rs = rs.OpenRecordset.

[Antonariy]

А как должно подойти Requery? Я попробовал не отключая соединения сделать Requery отфильтрованному рекордсету - ноль внимания, фунт презрения.

Updates the data in a Recordset object by re-executing the query on which the object is based.
...
Calling this method is equivalent to calling the Close and Open methods in succession.

Каким боком тут фильтр?

И что за OpenRecordset? ADO Recordset не имеет такого метода.

[alibek]

OpenRecordset к DAO относился. Там мало было фильтр или сортировку назначить, нужно было запрос обновить.

[Antonariy]

Везде понаписано ADODB.Recordset, а ты DAO проталкиваешь?

[alibek]

Ну проглядел, проглядел
В ADO Requery не нужен. Но там и фильтр должен работать сразу, без обновления рекордсета. Поэтому Requery я для эксперимента предложил.