Дата модификации

[Nicky]

Как _правильно_ менять даты (в частности, дату модификации) файла.
Пользую пример к функции SetFileTime из API_Guide, но напрягает один момент: дата меняется, но файл остается залоченым, до закрытия программы ни удалить, ни переименовать. После CloseHandle проверяю
через

Код: Выделить всё


Function GetLastAPIError() As String
  Dim sBuff As String
 
  sBuff = Space$(200)
  FormatMessage FORMAT_MESSAGE_FROM_SYSTEM, ByVal 0&, GetLastError, LANG_NEUTRAL, sBuff, _
    Len(sBuff), ByVal 0&
  GetLastAPIError = left$(sBuff, InStr(1, sBuff, vbNullChar) - 1)
End Function


Возвращает "Операция успешно завершена". Прошу помощи

[Viper]

Правильная последовательность действий:

1. Открыть файл при помощи CreateFile
2. Установить нужное время через SetFileTime
3. Закрыть файл через CloseHandle

[Nicky]

Клиника... Создал новый проект, в него запихнул пример из API_Guide, проверил - все ок, дата меняется, файл не лочится. Туда же бросил мою функцию смены даты (99.9% пример из API_Guide, но все равно решил проверить) - тоже ок. Первой строкой в существующем проекте ставлю вызов функции смены даты - дата меняется, файл лочится. Закрываю IDE, повторяю - то же самое. Закрываю IDE, проверяю в новом проекте - все ок. Что за .....?

[Viper]

код в студию.... если конечно в нем дело, в чем уже есть сомнения

[Nicky]

Код: Выделить всё

'вот так ---------------------- это мой вызов, все остальное из API_Guide
'моя функция в конце
'
'
'
'
'
'
'This project needs a Common Dialog box, named CDBox.
'  (To add the Common Dialog Box to your tools menu, go to Project->Components (or press CTRL-T)
'   and select Microsoft Common Dialog control)

Public Enum eFileTimeModif
  lCreationTime = 0
  lLastAccessTime = 1
  lLastWriteTime = 2
End Enum

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type
    Private Type SYSTEMTIME
    wYear As Integer
    wMonth As Integer
    wDayOfWeek As Integer
    wDay As Integer
    wHour As Integer
    wMinute As Integer
    wSecond As Integer
    wMilliseconds As Integer
End Type
Private Const GENERIC_WRITE = &H40000000
Private Const OPEN_EXISTING = 3
Private Const FILE_SHARE_READ = &H1
Private Const FILE_SHARE_WRITE = &H2
Private Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" (ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, ByVal lpSecurityAttributes As Long, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long
Private Declare Function GetFileTime Lib "kernel32" (ByVal hFile As Long, lpCreationTime As FILETIME, lpLastAccessTime As FILETIME, lpLastWriteTime As FILETIME) As Long
Private Declare Function SetFileTime Lib "kernel32" (ByVal hFile As Long, lpCreationTime As FILETIME, lpLastAccessTime As FILETIME, lpLastWriteTime As FILETIME) As Long
Private Declare Function SystemTimeToFileTime Lib "kernel32" (lpSystemTime As SYSTEMTIME, lpFileTime As FILETIME) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function LocalFileTimeToFileTime Lib "kernel32" (lpLocalFileTime As FILETIME, lpFileTime As FILETIME) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim m_Date As Date, lngHandle As Long
    Dim udtFileTime As FILETIME
    Dim udtLocalTime As FILETIME
    Dim udtSystemTime As SYSTEMTIME
    m_Date = Now 'Format(Now, "DD-MM-YY")

    'Set the dialog's title
    CDBox.DialogTitle = "Choose a file ..."
    'Set the dialog's filter
    CDBox.Filter = "All Files (*.*)|*.*"
    'Show the 'Open File'-dialog
    CDBox.ShowOpen
   
    MySetFileTime CDBox.FileName, Now, lLastWriteTime '-----------------------типа вызов моей функции

    udtSystemTime.wYear = Year(m_Date)
    udtSystemTime.wMonth = Month(m_Date)
    udtSystemTime.wDay = Day(m_Date)
    udtSystemTime.wDayOfWeek = Weekday(m_Date) - 1
    udtSystemTime.wHour = Hour(m_Date)
    udtSystemTime.wMinute = Minute(m_Date)
    udtSystemTime.wSecond = Second(m_Date)
    udtSystemTime.wMilliseconds = 0

    ' convert system time to local time
    SystemTimeToFileTime udtSystemTime, udtLocalTime
    ' convert local time to GMT
    LocalFileTimeToFileTime udtLocalTime, udtFileTime
    ' open the file to get the filehandle
    lngHandle = CreateFile(CDBox.FileName, GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE, ByVal 0&, OPEN_EXISTING, 0, 0)
    ' change date/time property of the file
    SetFileTime lngHandle, udtFileTime, udtFileTime, udtFileTime
    ' close the handle
    CloseHandle lngHandle
    MsgBox "The date of the file '" + CDBox.FileName + "' has been changed to" + Str$(m_Date), vbInformation + vbOKOnly, App.Title
End Sub




Function MySetFileTime(sFile As String, dDate As Date, Optional lTimeModif As eFileTimeModif) 'типа моя функция
  Dim ftCreationTime As FILETIME, ftLastAccessTime As FILETIME, ftLastWriteTime As FILETIME
  Dim ftFileTime As FILETIME, ftLocalTime As FILETIME, stSystemTime As SYSTEMTIME
  Dim hFile As Long

  stSystemTime.wYear = Year(dDate)
  stSystemTime.wMonth = Month(dDate)
  stSystemTime.wDay = Day(dDate)
  stSystemTime.wDayOfWeek = Weekday(dDate, vbMonday)
  stSystemTime.wHour = Hour(dDate)
  stSystemTime.wMinute = Minute(dDate)
  stSystemTime.wSecond = Second(dDate)
  stSystemTime.wMilliseconds = 0

  SystemTimeToFileTime stSystemTime, ftLocalTime
  LocalFileTimeToFileTime ftLocalTime, ftFileTime
  hFile = CreateFile(sFile, GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE, ByVal 0&, _
    OPEN_EXISTING, 0, 0)
 
  GetFileTime hFile, ftCreationTime, ftLastAccessTime, ftLastWriteTime
  Select Case lTimeModif
    Case lCreationTime: ftCreationTime = ftFileTime
    Case lLastAccessTime: ftLastAccessTime = ftFileTime
    Case lLastWriteTime: ftLastWriteTime = ftFileTime
  End Select
  SetFileTime hFile, ftCreationTime, ftLastAccessTime, ftLastWriteTime
  CloseHandle hFile
End Function


Чистый копипаст с API_Guide

Ну, и как я уже говорил, в новом проекте все на ура, в существующем первой строкой кода делаю вызов MySetFileTime - лочится.
Уже и функции задекларировал как в примере (у меня были Public), и свойства проекта сравнил - одинаково, и тестирую с одним и тем же файлом. Один фиг...

[Viper]

мдя... это называется найди два отличия

[Nicky]

?
Единственное, что добавил, это то, что можно менял дату создания, доступа, модификации, но фактически пользую только модификации.
Ну еще добавил перечисление

Код: Выделить всё

Public Enum eFileTimeModif
  lCreationTime = 0
  lLastAccessTime = 1
  lLastWriteTime = 2
End Enum


И все...