функции или API

[ВуД]

Кто знает функции или API для выключения, перезагрузки, спящего режима, ждущего режима компьютера?

[GB826]

Кто знает функции ИЛИ API

:о)) впечатляет вопрос !

В поиск! ссылку не знаю!

Public Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long

[tyomitch]

ExitWindowsEx
SetSystemPowerState

[keks-n]

Угу, ExitWindowsEx выключает и перезагружает... Особенно на NT

[GSerg]

keks-n
Угу... выключает и перезагружает... а разве нет?..

[AjaxVS]

GSerg
Да вроде как остается картинка "Теперь питание компа можно вырубить"... Куда это годится?

[Хакер]

Ещё можно запускать Shutdown.exe с различными параметрами. Чтобы их узнать нужно из ком. строки запусить его с параметром /?

[ВуД]

VB 6.0 для XP

[Twister]

Да вроде как остается картинка "Теперь питание компа можно вырубить"... Куда это годится?

А разве присутствие данной картинки не обусловлено типом мать-платы?

[Хакер]

VB 6.0 для XP

А я ем пельмени, и что? К чему это вообще?

[Хакер]

Да вроде как остается картинка "Теперь питание компа можно вырубить"... Куда это годится?

А разве присутствие данной картинки не обусловлено типом мать-платы?

Ох опередил...

Данная картинка свойственна для Win9x - лежит она в файле logout.sys если мне не изменяеет память. Просто некоторые мамки вырубаются не успевая показать эту картинку...

[Twister]

VB 6.0 для XP

Имелось ввиду, что автору нужна функция, которая будет работать в ХР, а программа на VB6. Тёмыч уже сказал ...

[tyomitch]

Да вроде как остается картинка "Теперь питание компа можно вырубить"... Куда это годится?

А разве присутствие данной картинки не обусловлено типом мать-платы?

Ох опередил...

Данная картинка свойственна для Win9x - лежит она в файле logout.sys если мне не изменяеет память. Просто некоторые мамки вырубаются не успевая показать эту картинку...

Данная картинка свойственна для всех без исключения версий Винды.
У Win9x она, действительно, лежит в файле logos.sys
И чего из этого?

[Хакер]

tyomitch, а с чего такая уверенность что у всех? Прочитал где или ты каким то образом выяснил?

И если да то почему-то я не разу не видел её XP

[Twister]

У меня дома ХР с такой (она выглядит по другому) картинкой, потому что мать старая...

[tyomitch]

tyomitch, а с чего такая уверенность что у всех? Прочитал где или ты каким то образом выяснил?

Видел собственными глазами.

И если да то почему-то я не разу не видел её XP

А Гейтса ты видел? Может, его тоже выдумали?

[Хакер]

Выдумали, гады микромягкие

Ну раз есть так, есть буду знать...

ЗЫ. Ох как всем нравится на меня поорать...

[Twister]

ЗЫ. Ох как всем нравится на меня поорать...

Ну кто ж орал-то? Просто тебе пояснили, в чем ты не прав...

[Хакер]

А тут

[ANDLL]

На кого ж орать то? Юстас умотал на исходники.ру видать. patriot_kz я уже давно не видел, хотя топики и посты были отменные я вам скажу. Кто остался в списке?

[Хакер]

ANDLL, ну и где же они тогда регистрируются???

На кого ж орать то?

IMHO ни на кого не надо орать. Всё надо делать в дружественной обстановке...

[tyomitch]

ANDLL, ну и где же они тогда регистрируются???

Прикинь: нигде

[Хакер]

LШутка да?

[ANDLL]

ANDLL, ну и где же они тогда регистрируются???

Кто они? Юзвери или logon.sys'ы?

[tyomitch]

ANDLL, ну и где же они тогда регистрируются???

Кто они? Юзвери или logon.sys'ы?

Я так понял, что библиотеки.

[keks-n]

keks-n
Угу... выключает и перезагружает... а разве нет?..

На Win98 всё прекрасно, а вот под Win2000(и если мне не изменяет память то и на WinXP) ни выключение, ни перезагрузка посредством сией функции не прокатывают Там надо юзать InitiateSystemShutDown

[Viper]

На Win98 всё прекрасно, а вот под Win2000(и если мне не изменяет память то и на WinXP) ни выключение, ни перезагрузка посредством сией функции не прокатывают Там надо юзать InitiateSystemShutDown

Все прекрасно работает на NT и ее потомках (я про ExitWindowsEx), а вот на Win95 и ее родсттвенники InitiateSystemShutdown не работает...

Окно типа "Питание можно отключить..." разное для разных ОС, а его появление или непоявление зависит от мамы (а иногда еще и от видеокарты), а не от ОС

[ANDLL]

Все прекрасно работает на NT и ее потомках

...Если только процессу выбить соответствующие привелегии.

[Viper]

...Если только процессу выбить соответствующие привелегии.

Ну это само собой...

[Lumen]

Вот код из API Guide, выключающий. перезагружающий комп в NT/2000/XP:

Код: Выделить всё

'In a module
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Type LUID
    LowPart As Long
    HighPart As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub
' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_SHUTDOWN
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Restart NT
Public Sub RebootNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_REBOOT
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Log off the current user
Public Sub LogOffNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_LOGOFF
    If Force Then Flags = Flags + EWX_FORCE
    ExitWindowsEx Flags, 0
End Sub

'In a form
'This project needs a form with three command buttons
Private Sub Command1_Click()
    LogOffNT True
End Sub
Private Sub Command2_Click()
    RebootNT True
End Sub
Private Sub Command3_Click()
    ShutDownNT True
End Sub
Private Sub Form_Load()
    'KPD-Team 2000
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Command1.Caption = "Log Off NT"
    Command2.Caption = "Reboot NT"
    Command3.Caption = "Shutdown NT"
End Sub


По поводу картинок на мониторе после выключения - это зависит от материнской платы. На новых новые мамки формата ATX вырубаются без всяких картинок, старые же (AT) так не могут.
ЗЫ: Вообще-то эта тема уже избитая, поднимали её много раз. В следующий раз сначала воспользуйся поиском.