Сделать форму MDIchild-ом во время работы программы

[Mongoose]

Как с помощью API изменять свойство mdichild окна? Через стандартные свойства только во время разработки работает...

[hCORe]

Создавай окно через CreateWindow со стилем WS_CHILD. После создания окна изменить его "принадлежность" нельзя.

[Mongoose]

У меня уже есть, скажем, Form1 с некоторым набором контролов и т.д. Как её сделать child-ом с помощью CreateWindow?

[hCORe]

Нельзя. Нужно создать новое окошко с нужным стилем. Вручную. Кстати, в .NET Framework это делается автоматически - убивается окно со старым стилем и создается точно такое же новое.

Может быть, нужного тебе эффекта можно добиться, эмулируя поведение child-окна, ну, например, функцией SetParent?

[Mongoose]

SetParent уже сделал... В принципе и меню-список Child-окон вручную сделать можно... А как сделать чтобы при перемещении окна за границы родительского появлялись полосы прокрутки? Для обычных childов работает, а для полученных с помощью SetParent - нет!

[Ennor]

Блин. А сделать два одинаковых окна, одно из которых MDIChild, а другое - нет, не судьба? Ибо в данном случае это ограничение со стороны архитектуры Windows. Бу дезигн.

Один из тех редких случаев, когда самое топорное решение оказывается самым эффективным по количеству затраченных усилий (в т.ч. умственных).

[ANDLL]

2hCORe: Почтие все окна имеют стиль WS_CHILD, так как являются "детьми" десктопа. Твой способ ему совсем не поможет.
Боюсь, что это вообще не возможно... Но попытаться можно.

2Mongoose: У MDI-формы есть потомок класса MDIClient, попробуй установить его как родителя.

[Mongoose]

2Ennor: Таких окон около 15-20 будет... Соответственно делать 30-40? Не слишком ли?
2ANDLL: Так и делал... Не помогло =(

[Naked]

Можно и возможно.

Создаем новый проэкт (по умолчанию создается форма, назовем Form1 и в свойствах ставим MDIChild = Да), добавляем MDIForm обзываем MDIForm1, добавляем еще одну форму с названием tmpChild.

в модуле формы MDIForm1 пишем
Private Sub MDIForm_Load()
tmpChild.Show
End Sub

Private Sub MDIForm_Unload(Cancel As Integer)
End
End Sub


в модуле формы tmpChild пишем
Private Sub Form_Click()
Call HookChildForm(hWnd)
End Sub

Private Sub Form_Unload(Cancel As Integer)
Call UnHookChildForm(hWnd)
End Sub


пишем в модуле Module1
Option Explicit

Declare Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function DefMDIChildProc Lib "user32" Alias "DefMDIChildProcA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Const GWL_EXSTYLE = (-20)
Public Const GWL_STYLE = (-16)
Public Const WS_EX_MDICHILD = &H40
Public Const WS_CHILD = &H40000000
Public Const GWL_WNDPROC = (-4)

Public ChildWndProc As Long
Dim MDIClient As Long
Dim GWL As Long

Sub HookChildForm(hWnd As Long)
MDIClient = GetWindow(MDIForm1.hWnd, 5)
Call SetParent(hWnd, MDIClient)

GWL = GetWindowLong(hWnd, GWL_STYLE)
Call SetWindowLong(hWnd, GWL_STYLE, GWL Or WS_CHILD)

GWL = GetWindowLong(hWnd, GWL_EXSTYLE)
Call SetWindowLong(hWnd, GWL_EXSTYLE, GWL Or WS_EX_MDICHILD)

ChildWndProc = SetWindowLong(hWnd, GWL_WNDPROC, AddressOf ChildWindowProc)
End Sub

Sub UnHookChildForm(hWnd As Long)
Call SetWindowLong(hWnd, GWL_WNDPROC, ChildWndProc)
End Sub

Function ChildWindowProc(ByVal hWnd As Long, ByVal message As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Select Case message

Case Else
ChildWindowProc = DefMDIChildProc(hWnd, message, wParam, lParam)
End Select
End Function

Конец.

[Naked]

а говорили что невозможно, ограничения винды...

[ANDLL]

Интересно, кто такое говорил? Процетируй. Особенно на счет ограничения винды

[keks-n]

ANDLL

Ибо в данном случае это ограничение со стороны архитектуры Windows. Бу дезигн.

[Ennor]

Совершенно верно, это был я. И я это говорил не просто так.

Наличие стиля класса окна WS_EX_MDICHILD в природе еще не означает, что этот стиль можно изменить в рантайме у уже созданного окна. Слегка причесав код твоего примера (из-за обилия форм приходится некоторое время колдовать со свойством Startup Object, ну и оконная процедура там ни к чему) и запустив его, можно увидеть, что некоторая степень подобия достигается, но - не более того. Один из найденных косяков: после "смены" стиля окна на дочернее максимизировать дочернее окно, после чего максимизировать MDI-окно. Инвольтировать на увиденное одну минуту.

Аналогичный пример - свойство Style контрола Listbox. Если контрол создан со стилем Checkbox, то убрать чеки невозможно, иначе как задестроив окно и создав его заново с нужным стилем. Таких мест в Windows - считанные единицы, но они есть.

[Mongoose]

2Ennor: У меня ничего противоестественного не возникает, если максимизировать дочернее окно, после чего максимизировать MDI-окно. :-/

2Naked: У меня работает твой код, но он в принципе не завершается корректно =) Всегда убивает IDE =) Возможно это из-за "end" в "MDIForm_Unload" Сейчас не хватает времени, чтобы разобраться... Но спасибо! =)

Хотя есть пара минусов всё-таки... Это окно не попадает в список child-окон и в его меню отсутствует пункт "следующее окно".. Поэтому мне больше подойдёт наверное простой setparent + не давать окнам выходить за пределы родителя =) А максимизировать мне и не надо, все окна имеют стиль toolwindow =)