Resize()

[Mrakobes]

Есть некая форма, размеры которой не должны быть меньше X и Y. Если пользователь уменьшает размеры до неразрешенных, то форма сама принимает минимально возможный размер. Но при этом она сначала становится меньше. Это выглядит как полосы, обозначающие перетаскиваемые границы. Как этого избежать?

Ну, к примеру:

Код: Выделить всё

Private Sub Form_Resize()
If Me.Width < 100 Then Me.Width = 100
End Sub

[Warn]

Через Апи, чувак

В модуль

Код: Выделить всё

Global p&
Public Const WM_GETMINMAXINFO = &H24
Public Const GWL_WNDPROC = (-4)
Public MMInfo As MINMAXINFO
Public Type POINTAPI
x As Long
y As Long
End Type
Public Type MINMAXINFO
ptReserved As POINTAPI
ptMaxSize As POINTAPI
ptMaxPosition As POINTAPI
ptMinTrackSize As POINTAPI
ptMaxTrackSize As POINTAPI
End Type
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Function DefWindowProc Lib "user32" Alias "DefWindowProcA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Public Function Handler&(ByVal h&, ByVal m&, ByVal w&, ByVal l&)
If m = WM_GETMINMAXINFO Then
CopyMemory MMInfo, ByVal l, Len(MMInfo)
With MMInfo
.ptMinTrackSize.x = 500 ' Ieieiaeuiay oe?eia
.ptMinTrackSize.y = 500 ' Ieieiaeuiay aunioa
End With
CopyMemory ByVal l, MMInfo, Len(MMInfo)
Handler = DefWindowProc(h, m, w, l)
Else
Handler = CallWindowProc(p, h, m, w, l)
End If
End Function


Использование в Form_Load

Код: Выделить всё

Private Sub Form_Load()
p = SetWindowLong(hwnd, GWL_WNDPROC, AddressOf Handler)
End Sub


[Warn]

Че-то с комментами перекос.. Видать это у меня.