Поиск строки

[Dave]

Нужно написать функцию, которая возвращает номер строки с данными в определенных ячейках равными входящим параметрам, подскажите, плз, как лучше. У меня получилось только так, и то пока по коду до этого места не дошла (не тестировала):
Function FindPartner(PartnerCode As String, PartnerType As String)

FindPartner = 0

rNum = 6
Num = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 2).Text
Group = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 3).Text
Cur = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 4).Text
LanguageId = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 5).Text
PartType = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 1).Text

Do While Not (Num = "" Or Group = "" Or Cur = "" Or LanguageId = "")
If Num = PartnerCode And PartType = PartnerType Then
FindPartner = rNum
Num = ""
Else
rNum = rNum + 1
Num = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 2).Text
Group = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 3).Text
Cur = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 4).Text
LanguageId = ThisWorkbook.Sheets("Контрагенты").Cells(rNum, 5).Text
End If
Loop

End Function

[GSerg]

Код: Выделить всё

Option Explicit

Function FindPartner(ByVal PartnerCode As Long, PartnerType As String) As Long
  Dim f As Range, last As Long
  Do
    Set f = Worksheets("Контрагенты").Columns(2).Find(PartnerCode, IIf(f Is Nothing, Null, f), xlValues, xlWhole)
    If f Is Nothing Then Exit Function
    If f.Row <= last Then Exit Function
    last = f.Row
    If f.Offset(0, -1).Value = PartnerType Then
      FindPartner = f.Row
      Exit Function
    End If
  Loop
End Function

[Dave]

Спасибо, только ругался на тип ячейки, после которой нужно искать, я написала так (мне нужно с 6-ой строки искать):

Код: Выделить всё

Function FindPartner(PartnerCode As String, PartnerType As String) As Long
  Dim f As Range, fR As Range, last As Long
  last = 6
  Do
    Set f = Worksheets("Контрагенты").Columns(2).Find(PartnerCode, Cells(last, 2), xlValues, xlWhole)
    If f Is Nothing Then Exit Function
    If f.Row <= last Then Exit Function
    last = f.Row
    If f.Offset(0, -1).Value = PartnerType Then
      FindPartner = f.Row
      Exit Function
    End If
  Loop
End Function


[GSerg]

Неправильно...
Если первым поиском будет найдено partnercode, но на этой строке будет не тот partnertype, то поиск уйдёт в бесконечную петлю. Или выдаст 0, фиг его знает.

Если уж так, то вместо last=6 нужно написать
set f=worksheets("Контрагенты").cells(5,2)

А команда поиска будет Set f = Worksheets("Контрагенты").Columns(2).Find(PartnerCode, f, xlValues, xlWhole)

[Dave]

Не соглашусь, все ищет правильно (в себя не уходит), т.к. тестировала - ставила сначала строку с искомым partnercod, а partnertype был не тот - все сработало (мы же номер строки запоминаем). Но новый предложенный вариант тоже катит.

[GSerg]

А не глючит ли меня в последнее время...
Глючит