UNICODE и API

[ANDLL]

Вопрос такой:
если я пишу

Dim A as String
A="string"

то в A содержиться строка типа WCHAR.
Соответственно есть API

Public Declare Function StrRest(ByVal string1 as String) as Long

В переводе на C это выглядит как

long StrRest(WCHAR* string1)

Ан нет. Почему-то нужный результат виден только при использвании LPSTR. А с использованием WCHAR происходят проблемы. Как будто VB приобразует строку перед передачей функции в ANSI? Так ли это, и как от этого избавиться

[GSerg]

Да, это так. Преобразует всегда во всех функциях, объявленных через declare. Лечится просто - объявить параметр as long, а передавать strptr(string1).

[ANDLL]

Это совершенно плохо. Не подходит такой вариант с VarPtr, т.к. передаеться сразу значение, т.е. "параметр", а не переменная(к пр. SimpleFunc("parametr"))

Можно конечно использовать StrConv, но это тоже не подходит. Может можно как-то поменять объявление?

[tyomitch]

Ты будешь удивлён, но StrPtr("literal data") прекрасно работает.

[ANDLL]

Пардон. Что есть StrPtr? В чем отличие от VarPtr?

[tyomitch]

Указатель на данные строки, тогда как VarPtr - указатель на дескриптор (BSTR) строки.

BTW, VarPtr("literal data") тоже прекрасно работает.

[TEH3OP]

Сабж.

1) Прописать функцию так:

Код: Выделить всё

Public Declare Function StrRest(ByRef string1 as Byte) as Long


, а работать с функцией так:

Код: Выделить всё

Dim abytTest() as Byte
Dim lngAPIReturn as Long

abytTest = "Мама мыла папу." & vbNullChar
lngAPIReturn = StrRest(abytTest(0))


2) Писать TLB'шку... но это долго рассказывать. Если интересно поищи в инете инфу про "IDL"-язык.

[tyomitch]

Сабж.

1) Прописать функцию так:

Код: Выделить всё

Public Declare Function StrRest(ByRef string1 as Byte) as Long


, а работать с функцией так:

Код: Выделить всё

Dim abytTest() as Byte
Dim lngAPIReturn as Long

abytTest = "Мама мыла папу." & vbNullChar
lngAPIReturn = StrRest(abytTest(0))


Ну нахрена, нахрена, НАХРЕНА городить байтовые массивы?!
Всё же уже GSerg правильно сказал!
Объявление:

Код: Выделить всё

Public Declare Function StrRest(ByVal string1 as Long) as Long


Вызов:

Код: Выделить всё

Dim lngAPIReturn as Long

lngAPIReturn = StrRest(StrPtr("Мама мыла папу."))


[ANDLL]

Указатель на данные строки, тогда как VarPtr - указатель на дескриптор (BSTR) строки

Т.е. StrPtr=VarPtr+4???

[TEH3OP]

2 tyomitch: я не говорю, что этот способ самый наилучший, зачем делать такое лицо. Я просто рассказал про то, что есть такой способ.
Кстати, BSTR -- это НЕ дескриптор. >;-\

2 ANDLL: Там всё немного хитрее. Главное, что такой код

Код: Выделить всё

Dim lngPtr as long
Dim bstTest as String
bstTest = "Здесь был Я!"
lngPtr = StrPtr(bstTest)
StrRest lngPtr


-- опасен и може привести к неожиданному результату, вплоть до Memory Exeption'на.
А вот такой:

Код: Выделить всё

Dim bstTest as String
bstTest = "Здесь был Я!"
StrRest StrPtr(bstTest)


или

Код: Выделить всё

Dim bstTest as String
bstTest = "Здесь был Я!"
StrRest VarPtr(VarPtr(ByVal bstTest)) 'вроде так... сорры VB нет под рукой, чтобы проверить.


будет вполне нормально работать.

[ANDLL]

typedef WCHAR OLECHAR;
...
typedef OLECHAR* BSTR;

Т.е. BSTR это все-таки дескриптор(указатель).

Господа! Чтите MSDN - це великая рукопись! К примеру там указано простейшее решение моей проблемы(сам недавно нашел):

Код: Выделить всё

Public Declare Function StrRest(ByRef str as String) as Long


И соответственно:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;//Учитываем длину заголовка
   ...
}


Вот как все иногда просто! VB не преобразует строку в ASCII если она передаеться по адресу.
Между тем спасибо всем, кто принимал участие в обсуждении.

[tyomitch]

Указатель на данные строки, тогда как VarPtr - указатель на дескриптор (BSTR) строки

Т.е. StrPtr=VarPtr+4???

StrPtr==*VarPtr
т.е.

Код: Выделить всё

Option Explicit

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Sub Main()
Dim s As String, l As Long
s = "Hello!"
CopyMemory l, ByVal VarPtr(s), 4
Debug.Print l, StrPtr(s)
End Sub


- вернёт два одинаковых числа.

[tyomitch]

2 tyomitch: я не говорю, что этот способ самый наилучший, зачем делать такое лицо. Я просто рассказал про то, что есть такой способ.
Кстати, BSTR -- это НЕ дескриптор. >;-\

Вопрос терминологии. Я специально назвал BSTR, чтобы было понятно, что я имею в виду.

2 ANDLL: Там всё немного хитрее. Главное, что такой код

Код: Выделить всё

Dim lngPtr as long
Dim bstTest as String
bstTest = "Здесь был Я!"
lngPtr = StrPtr(bstTest)
StrRest lngPtr


-- опасен и може привести к неожиданному результату, вплоть до Memory Exeption'на.

С чего это вдруг? Жду аргументации.

Код: Выделить всё

Dim bstTest as String
bstTest = "Здесь был Я!"
StrRest VarPtr(VarPtr(ByVal bstTest)) 'вроде так... сорры VB нет под рукой, чтобы проверить.


будет вполне нормально работать.

Такой точно не будет. Ты передаёшь адрес адреса BSTR-а, т.е. OLECHAR***

[tyomitch]

И соответственно:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;//Учитываем длину заголовка
   ...
}


Непонятно, почему нужно увеличивать str. Ты этот код проверял?
Мне кажется, что в данном случае (BSTR*str) *str указывает на первый символ строки, (*str + 2) - на второй и т.д.
У тебя же получается нечётный адрес, где имхо ничего лежать не может.

[Vi]

Господа! Чтите MSDN - це великая рукопись! К примеру там указано простейшее решение моей проблемы(сам недавно нашел):

Код: Выделить всё

Public Declare Function StrRest(ByRef str as String) as Long


И соответственно:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;//Учитываем длину заголовка
   ...
}


Вот как все иногда просто! VB не преобразует строку в ASCII если она передаеться по адресу.

Ты заблуждаешься! VB всегда преобразует строки, передаваемые во ВНЕШНИЕ процедуры как по "ByVal str As String", так и по "ByRef str As String". Это так называемый формат ABSTR (вот про него можешь поискать в MSDNе), т.е. указатель BSTR, но данные там в ANSI.

[Ennor]

Брюс МакКинни в своей книге "Hardcore Visual Basic" утверждает, что басик в принципе не позволяет работать с юникод-версиями АПИ-шных функций, за исключением одного-единственного способа - через TLB. Так что... думайте сами, нужно оно вам или нет.

[tyomitch]

Брюс МакКинни в своей книге "Hardcore Visual Basic" утверждает, что басик в принципе не позволяет работать с юникод-версиями АПИ-шных функций, за исключением одного-единственного способа - через TLB. Так что... думайте сами, нужно оно вам или нет.

Код: Выделить всё

Option Explicit

Private Declare Function MessageBoxW Lib "user32" (ByVal hWnd As Long, ByVal lpText As Long, ByVal lpCaption As Long, ByVal wType As Long) As Long

Sub Main()
MessageBoxW 0, StrPtr("VB прекрасно может работать с Unicode API!"), StrPtr("Наглый гон!"), vbInformation
End Sub


[GSerg]

[Ennor]

2 tyomitch:
Хм. А кто тебе сказал, что туда передается действительно Unicode-данные? Вот иероглифов или диакритики туда насуй и посмотри... А корректное отображение русского - это не доказательство.

[tyomitch]

2 tyomitch:
Хм. А кто тебе сказал, что туда передается действительно Unicode-данные? Вот иероглифов или диакритики туда насуй и посмотри... А корректное отображение русского - это не доказательство.

Эх ты, конструктивный критик... А самому проверить в облом? Работает!

Код: Выделить всё

Option Explicit

Private Declare Function MessageBoxW Lib "user32" (ByVal hWnd As Long, ByVal lpText As Long, ByVal lpCaption As Long, ByVal wType As Long) As Long
Sub Main()
Dim Proof As String
Proof = "Диакритика: " & ChrW(&HC1) & ChrW(&HD5) & ChrW(&HE9) & vbCrLf & _
        "Греческий: " & ChrW(&H39E) & ChrW(&H3B3) & ChrW(&H3C7) & vbCrLf & _
        "Еврейский: " & ChrW(&H5D0) & ChrW(&H5E4) & ChrW(&H5E9) & vbCrLf & _
        "Арабский: " & ChrW(&H626) & ChrW(&H63A) & ChrW(&H64A) & vbCrLf & _
        "Тайский: " & ChrW(&HE04) & ChrW(&HE18) & ChrW(&HE2C) & vbCrLf & _
        "Ещё надо?"
MessageBoxW 0, StrPtr(Proof), StrPtr("Наглый гон!"), vbInformation
End Sub


[Ennor]

Хм. Действительно, работает. Кстати, насчет моего утверждения - МакКинни писал о VB5, вообще-то. Интересно, кто-нить может проверить это на пятом басике?

[NetVille]

2Ennor: Проверил на 5-м и на 6-м - всё работает.

[Ennor]

Ну что я могу сказать... Значит, МакКинни облажался. С другой стороны, лично мне еще ни разу не требовалось посылать WCHAR-строки апишкам, хотя то, что это принципиальное ограничение снято, не может не радовать. Правда, остается еще один важный вопрос: как передавать юникод, если строка является частью структуры? Думаю, опять-таки потребуется эксперимент.

[tyomitch]

Ну что я могу сказать... Значит, МакКинни облажался.

Когда я обнаружил, что в книге Аппельмана есть грубые ошибки, для меня это тоже было потрясением...
Так что: авторы книг не боги, и к тому, что они пишут, нужно подходить со здоровым недоверием.

С другой стороны, лично мне еще ни разу не требовалось посылать WCHAR-строки апишкам, хотя то, что это принципиальное ограничение снято, не может не радовать. Правда, остается еще один важный вопрос: как передавать юникод, если строка является частью структуры? Думаю, опять-таки потребуется эксперимент.

Если передавать не их сами, а их адрес - всё работает.

Код: Выделить всё

Option Explicit

Private Declare Function MessageBoxW Lib "user32" (ByVal hWnd As Long, ByVal lpText As Long, ByVal lpCaption As Long, ByVal wType As Long) As Long
Type SameAsString
    Data As String * 256
End Type

Sub Main()
Dim Proof As SameAsString
Proof.Data = "VB прекрасно может работать с Unicode-строками даже в структурах!"
MessageBoxW 0, VarPtr(Proof), StrPtr("МакКинни нас всех нае***!"), vbInformation
End Sub


[GSerg]

Маленькое уточнение: varptr(proof.data). Это только в данном конкретном случае указатели совпадают

ЗЫ: А я вот что-то вообще книжек этих не читал

[tyomitch]

Маленькое уточнение: varptr(proof.data). Это только в данном конкретном случае указатели совпадают

Ты не понял сути проблемы. Надо не передать Unicode-строку, хранящуюся в структуре, а передать структуру, содержащую в себе Unicode-строку. Так что у меня всё правильно. И действительно, это просто в данном конкретном случае указатели совпадают.

[ANDLL]

И соответственно:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;//Учитываем длину заголовка
   ...
}


Непонятно, почему нужно увеличивать str. Ты этот код проверял?
Мне кажется, что в данном случае (BSTR*str) *str указывает на первый символ строки, (*str + 2) - на второй и т.д.
У тебя же получается нечётный адрес, где имхо ничего лежать не может.

Да, проверял. Если к примеру str=15, то после str++, str будет равно 17.(Так работает оператор инкремента с указателями).
Сдвигать надо, что бы учесть длинну заголовка BSTR.(т.е. *str указывает на число символов в строке, а дальше уже идет сама строка)

[tyomitch]

И соответственно:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;//Учитываем длину заголовка
   ...
}


Непонятно, почему нужно увеличивать str. Ты этот код проверял?
Мне кажется, что в данном случае (BSTR*str) *str указывает на первый символ строки, (*str + 2) - на второй и т.д.
У тебя же получается нечётный адрес, где имхо ничего лежать не может.

Да, проверял. Если к примеру str=15, то после str++, str будет равно 17.(Так работает оператор инкремента с указателями).
Сдвигать надо, что бы учесть длинну заголовка BSTR.(т.е. *str указывает на число символов в строке, а дальше уже идет сама строка)

Действительно, то, что инкрементируется по два, я выпустил из виду. Но всё равно непонятно: BSTR-то указывает на первый символ строки, т.е. длина должна лежать в *(*str - 4).
Да и вообще, у тебя получается, что длина строки занимает два байта. Так не бывает.
Проверь, пожалуйста, тщательнее. Мне кажется, ты теряешь первый символ строки. BSTR указывает не на начало строки в памяти, а на её первый символ - это правда.

[ANDLL]

Длина строки конечно, по-идее должна быть DWORD(4 байта), а не WORD(2 байта).

В-общем так:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;
   MessageBoxW(NULL,*str,L"Строка",0);
   return 0;
   ...
}


И:

Код: Выделить всё

Private Declare Function StrRest Lib "X-Lib.dll" (ByRef xStr As String) As Long

StrRest "VB-String"


И сее работает. Если убрать str++, то не работает.

Я пока еще не совсем вник, но могу сказать, что операция str++ увеличивает str не на два байта.
Объяснение: str есть BSTR* -> OLECHAR**. sizeof(OLECHAR*) равно DWORD(т.е. 4, т.к. указатель)
Не проверял, но по идее так.

[tyomitch]

Длина строки конечно, по-идее должна быть DWORD(4 байта), а не WORD(2 байта).

В-общем так:

Код: Выделить всё

long StrRest(BSTR*str)
{
   str++;
   MessageBoxW(NULL,*str,L"Строка",0);
   return 0;
   ...
}


И:

Код: Выделить всё

Private Declare Function StrRest Lib "X-Lib.dll" (ByRef xStr As String) As Long

StrRest "VB-String"


И сее работает. Если убрать str++, то не работает.

Я пока еще не совсем вник, но могу сказать, что операция str++ увеличивает str не на два байта.
Объяснение: str есть BSTR* -> OLECHAR**. sizeof(OLECHAR*) равно DWORD(т.е. 4, т.к. указатель)
Не проверял, но по идее так.

Ааа! Слушай, здорово!
До меня доходит
Попробуй так:

Код: Выделить всё

long StrRest(BSTR*str)
{
   MessageBoxA(NULL,*str,"Строка",0);
   return 0;
   ...
}