удаление из списка определенного элемента

[Xaker_S]

Как удалить из списка элемент с определенным содержимым?
Т.е. к примеру дан список:
Иванов
Петров
Сидоров
Щелкаем по кнопке и к примеру Петров удаляется.
Можно конечно использовать индекс чтобы удалить, но это неподходит-
список не статический. Т.е. надо проверить есть ли в списке Петров,
узнать его индекс, а потом удалить.
Как сделать?

[Cyrax]

дан список:
Иванов
Петров
Сидоров

допустим нужно удалить Петрова

Код: Выделить всё

Sub Del(Name As String)
    Dim i As Integer
    For i = 0 To lst.ListCount - 1
        If lst.List(i) = Name Then
            lst.RemoveItem(i)
            Exit For
        End If
    Next i
End Sub


использование

Код: Выделить всё

Del "Петров"

lst - это контрол ListBox

[Xaker_S]

Ща попробую. Спасибо

[alibek]

Если у списка свойство .Sorted=True, то можно использовать бинарный поиск, это гораздо быстрее, чем перебор.
Кроме того, можно использовать API, отсылать сообщение LB_FINDSTRING.

[Cyrax]

Если у списка свойство .Sorted=True, то можно использовать бинарный поиск, это гораздо быстрее, чем перебор.
Кроме того, можно использовать API, отсылать сообщение LB_FINDSTRING.

перебор было первое что пришло в голову, да и самое простое (хоть и не самое эффективное).
а вот про LB_FINDSTRING можно кодом, если не затруднит?

[alibek]

Ну например так:

Код: Выделить всё

Public Enum WindowMessageConstants
  cbFindString = &H14C&
  lbFindString = &H18F&
End Enum

Public Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
   ByVal hWnd As Long, _
   ByVal wMsg As WindowMessageConstants, _
   ByVal wParam As Long, _
   lParam As Any) _
  As Long

Function FindByValue(ListControl As Control, Optional ByVal Value As String) As Long
Dim I As Long, msg As Long
If TypeOf ListControl Is ComboBox Then
  msg = WindowMessageConstants.cbFindString
  If Value = vbNullString Then Value = ListControl.Text
ElseIf TypeOf ListControl Is ListBox Then
  msg = WindowMessageConstants.lbFindString
Else
  Exit Function
End If
I = SendMessage(ListControl.hWnd, msg, -1&, ByVal Value)
FindByValue = I+1
End Function


Данный код подходит и для ListBox и для ComboBox. После вызова функция сообщает индекс элемента, базирующийся с единицы, т.е. чтобы использовать на обычном ListBox, следует применять List1.ListIndex = FindByValue(List1, "Петров")-1

И еще одно. Если список сортирован (.Sorted=True), то возвращается индекс наиболее соответствующего элемента, при .Sorted=False поиск проводится по полному значению. Т.е. если всегда нужно ПОЛНОЕ соответствие, то код следует усложнить, т.е. включить в него строчку

Код: Выделить всё

If ListControl.List(I)<>Value Then I=0

[Cyrax]

2alibek: большой senx.
только поясни для тех кто в танке, если список сортированный и внем такие элементы

Ку-Ку
Кувшин
Курица
Фильм

и в функцию передается в качестве строки поиска "Фи"(т.е. часть слова), то она мне вернет индекс последнего элемента ("Фильм"). я правильно понял?
А если список не сортирован, и сделать тоже самое (передать часть слова), тоже самое получится? или нет?

[alibek]

Если список сортированный, то ищется подобная строка (отвечающая Like Text*). Если список не сортированный, то ищется точное соответствие (= Text). Но лучше проверь, я точно не помню

[Cyrax]

Если список сортированный, то ищется подобная строка (отвечающая Like Text*). Если список не сортированный, то ищется точное соответствие (= Text). Но лучше проверь, я точно не помню

чтож еще раз огромное человеческое.
проверим... появилась идейка (автозаполнение). хотя этих реализаций наверной куча целая.... но свое как-то лучше. как говорится, если хочешь чтобы все работало хорошо, сделай это сам

[skiperski]

Если список сортированный, то ищется подобная строка (отвечающая Like Text*). Если список не сортированный, то ищется точное соответствие (= Text). Но лучше проверь, я точно не помню

Одинаково ищет в обоих случаях.

появилась идейка (автозаполнение).

Ага, механизьма хорошая. Вот такая вот заготовочка. Есно, должны присутствовать декларации от alibek.

Код: Выделить всё

Private LastComboKeyAscii As Long

Private Sub Combo1_Change()
   
    Dim i%, p%
   
    Select Case LastComboKeyAscii
    Case 8, 46
    Case Else
        With Combo1
            i = FindByValue(Combo1, .Text)
            If (i) Then
                p = .SelStart
                .ListIndex = i - 1
                .SelStart = p
                .SelLength = Len(.Text) - p
            End If
        End With
    End Select
   
    LastComboKeyAscii = 0
   
End Sub

Private Sub Combo1_KeyDown(KeyCode As Integer, Shift As Integer)
    LastComboKeyAscii = KeyCode
End Sub