Вопрос по CommonDialog

[Алексей К.]

А можно чтобы CommonDialog1.ShowOpen работал на выбор папки, а не файла? Нужно получить путь, но не к файлу - надо найти путь к папке). Т.е. выбираем папку в диалоге( заходим в нее) и жмем открыть. Типа как в setup`ах - укажите куда устанавливать.
Может это и не через Commondialog делается. Подскажите как сделать такую штуку.

[ChelDm]

Можно наверно так я просто не поимню, а посмотреть сейчас негде

Dim s as variant
dim k as variant

k=commondialgo1. (вообщем не помню там свойство которое возвращает только имя файла)

s=Mid(commondialog1.filename,1,len(commondialog1.filename)-len(k))

смысл в том что из строки с именем файлы, с его путями вырезаем все кроме самого имени файла. Дома посмотрю скину пример

[Алексей К.]

Это понятно. а мне надо так:
Допустим есть путь: с:\1\2\3\4\5\6
Мне нужно определить путь только к папке "2". Т.е. в ней нет файлов- одни подкаталоги. А commondialog требует файл для открытия

[ChelDm]

Тогда видимо нужно в строке с путем к файлу искать необходимый католог, а потом найдя енту позицию вырезать с начала до ентой позиции

[RayShade]

А может, не городить огорода, а поискать по форуму магическое слово SHBrowseForFolder?

[Алексей К.]

Спасибо! Магическое слово найдено

[FaKk2]

А может, не городить огорода, а поискать по форуму магическое слово SHBrowseForFolder?

Снимаю шляпу

Непонятный алгоритм поиска, случайно выдал верный результат. Чудо, да и только

А чтоб, просто так не флудить, запостю на всякий пожарный код из АПИ-Гайда

Код: Выделить всё

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo

    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If

    MsgBox sPath
End Sub


[RayShade]

Непонятный алгоритм поиска, случайно выдал верный результат. Чудо, да и только

Он только кириллицу криво ищет А английские слова - только подноси

[alibek]

Предлагаю свой вариант.
Он длинее, зато позволяет задавать первоначальную папку

Код: Выделить всё

'Choose folder
Private Enum BrowseFlagsEnum
  bifBrowseForComputer = &H1000&
  bifBrowseForPrinter = &H2000&
  bifBrowseIncludeFiles = &H4000&
  bifBrowseIncludeURLs = &H80&
  bifShareable = &H8000&
  bifDontGoBelowDomain = &H2&
  bifEditBox = &H10&
  bifReturnFSAncestors = &H8&
  bifReturnOnlyFSDirs = &H1&
  bifStatusText = &H4&
  bifUseNewUI = &H40&
  bifValidate = &H20&
End Enum
Private Enum BrowseMessages
  'Messages from browser
  bffmInitialized = 1
  bffmSelChanged = 2
  bffmValidateFailedA = 3 'lParam:szPath ret:1(cont),0(EndDialog)
  bffmValidateFailedW = 4 'lParam:szPath ret:1(cont),0(EndDialog)
  'Messages to browser
  bffmSetStatusTextA = (WM_USER + 100)
  bffmEnableOk = (WM_USER + 101)
  bffmSetSelectionA = (WM_USER + 102)
  bffmSetSelectionW = (WM_USER + 103)
  bffmSetStatusTextW = (WM_USER + 104)
#If Win32 Then
  bffmSetStatusText = bffmSetStatusTextW
  bffmSetSelection = bffmSetSelectionW
  bffmValidateFailed = bffmValidateFailedW
#Else
  bffmSetStatusText = bffmSetStatusTextA
  bffmSetSelection = bffmSetSelectionA
  bffmValidateFailed = bffmValidateFailedA
#End If
End Enum
Private Type BrowseInfo
  hWndOwner As Long
  pIDLRoot As Long
  pszDisplayName As Long
  lpszTitle As Long
  ulFlags As BrowseFlagsEnum
  lpfnCallback As Long
  lParam As Long
  iImage As Long
End Type
Private BrowsePath As String
Private Declare Function SHBrowseForFolder Lib "shell32" (lpBI As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)

Private Sub RemoveNullChar(ByRef Text As String)
Dim I As Long
I = InStr(Text, vbNullChar)
If I > 0 Then Text = Left$(Text, I - 1)
End Sub

Public Function dlgBrowseFolder(OwnerForm As Form, ByRef Path As String, Optional ByVal Title As String, Optional ByVal AllowExtStyle As Boolean = False, Optional ByVal AllowManualEnter As Boolean = False) As Boolean
Dim BI As BrowseInfo, lpIDList As Long
Const MaxPath As Long = 1024&
BrowsePath = Path
Title = StrConv(Title, vbFromUnicode)
With BI
  If OwnerForm Is Nothing Then
    .hWndOwner = 0&
  Else
    .hWndOwner = OwnerForm.hWnd
  End If
  .pIDLRoot = 0&
  .pszDisplayName = 0&
  .lpszTitle = StrPtr(Title)
  .ulFlags = bifReturnOnlyFSDirs Or IIf(AllowExtStyle, bifUseNewUI, 0&) Or IIf(AllowManualEnter, bifEditBox, 0&)
  .lpfnCallback = FnPtr(AddressOf BrowseCallbackProc)
  .lParam = 0&
  .iImage = 0&
End With
lpIDList = SHBrowseForFolder(BI)
If lpIDList <> 0 Then
  Path = String$(MaxPath, 0)
  SHGetPathFromIDList lpIDList, Path
  CoTaskMemFree lpIDList
  RemoveNullChar Path
  dlgBrowseFolder = True
End If
End Function

Public Function BrowseCallbackProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal lParam As Long, ByVal lpData As Long) As Long
Select Case uMsg
  Case BrowseMessages.bffmInitialized
    SendMessage hWnd, BrowseMessages.bffmSetSelectionA, True, ByVal BrowsePath
End Select
BrowseCallbackProc = 0&
End Function


Юзать:

Код: Выделить всё

Dim P As String
P = "C:\TEMP"
If dlgBrowseFolder(Me, P, "Choose folder", True, False) Then
  MsgBox P
End If


[RayShade]

(задумчиво подперев голову рукой)

..... и зачем этому форуму поиск? Все равно его не юзают, а ответы переписывают....

[XATTAB]

Вот один из самых наиболее простых способов решения траблы твоей.
Качай пример.Там быстро разберешся (5сек. не более).

[adminua1]

А можно чтобы CommonDialog1.ShowOpen работал на выбор папки, а не файла? Нужно получить путь, но не к файлу - надо найти путь к папке). Т.е. выбираем папку в диалоге( заходим в нее) и жмем открыть. Типа как в setup`ах - укажите куда устанавливать.
Может это и не через Commondialog делается. Подскажите как сделать такую штуку.

А как єту штуку CommonDialog1.ShowOpen вызвать. Я совсем новенький
Дайте пожалуйста простейший пример

[lord0n]

поставь на форму этот контрол и юзай