Поиск подстроки в cmbBox'e и регистр

[netfrog]

Вроде должно работать и рабает, но если не соответствует регистр символов, то не хотит можно как нить объехать ????

Код: Выделить всё

Private Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Private Declare Function RegEnumKey Lib "advapi32.dll" Alias "RegEnumKeyA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, ByVal cbName As Long) As Long

Private Sub Form_Load()
Combo1.AddItem "ааа"
Combo1.AddItem "ббб"
Combo1.AddItem "ВВВВ"
End Sub

Private Sub Combo1_KeyUp(KeyCode As Integer, Shift As Integer)
Dim st As Long
If KeyCode <> vbKeyReturn And KeyCode <> vbKeyBack And KeyCode <> vbKeySpace Then
st = Len(Combo1.Text)
If st < 3 Then
For X = 0 To Combo1.ListCount - 1
If Left(Combo1.List(X), st) = Combo1.Text Then
Combo1.ListIndex = X
Combo1.SelStart = st
Combo1.SelLength = Len(Combo1.Text) - st
Exit For
End If
Next X
End If
End If
End Sub

[RayShade]

я бы объехал примерно так:

Код: Выделить всё

If LCase(Left(Combo1.List(X), st)) = LCase(Combo1.Text) Then


или вообще так:

Код: Выделить всё

If Left(Combo1.List(X), st) LIKE Combo1.Text Then


[netfrog]

Like я тоже попробовал, не помогает, а первый вариант - самое то.
Спасибо

[alibek]

Или в декларации напиши

Код: Выделить всё

Option Compare Text

Но еще лучше искать при помощи API SendMessage hWnd, CB_FINDSTRING, ?, ?

[netfrog]

чем лучше, ну и пример в студию

[alibek]

Ну примерно так:

Код: Выделить всё

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const CB_FINDSTRING As Long = &H14C&

...

Private Sub Combo1_KeyUp(KeyCode As Integer, Shift As Integer)
Dim st As Long, I As Long
If KeyCode <> vbKeyReturn And KeyCode <> vbKeyBack And KeyCode <> vbKeySpace Then
  st = Len(Combo1.Text)
  If st < 3 Then
    I = SendMessage(Combo1.hWnd, CB_FINDSTRING, ByVal 1&, ByVal (Combo1.Text & Chr$(0)))
    If I => 0 Then
      Combo1.ListIndex = I
      Combo1.SelStart = st
      Combo1.SelLength = Len(Combo1.Text) - st
    End If
  End If
End If
End Sub


Только это... не проверял я. Но должно работать.