Обработка сообщений Windows

[Александр Андреев]

Привет!

Подскажите как мне перехватить сообщение в VB.
Например, в моем проекте имеется форма fMain, для которой я хочу перехватить сообщение WM_GETMINMAXINFO, чтобы запретить изменение ее размеров, если они меньше неких допустимых.

[RayShade]

Обрабатывай событие Form_Resize() и все

[Александр Андреев]

Плохо получается... Становятся видны дефекты перерисовки формы.
Мне бы хотелось узнать, есть ли вообще способ подключения обработчиков виндовых сообщений, или же все ограничивается стандартными?

[alibek]

Вот пример из MSDN:

Это в форму:

Код: Выделить всё

Option Explicit

Private Sub Form_Load()
  'Save handle to the form.
  gHW = Me.hwnd
  'Begin subclassing.
  Hook
End Sub

Private Sub Form_Unload(Cancel As Integer)
  'Stop subclassing.
  Unhook
End Sub


А это в модуль:

Код: Выделить всё

Option Explicit

Private Const GWL_WNDPROC = -4
Private Const WM_GETMINMAXINFO = &H24

Private Type POINTAPI
  x As Long
  y As Long
End Type

Private Type MINMAXINFO
  ptReserved As POINTAPI
  ptMaxSize As POINTAPI
  ptMaxPosition As POINTAPI
  ptMinTrackSize As POINTAPI
  ptMaxTrackSize As POINTAPI
End Type

Global lpPrevWndProc As Long
Global gHW As Long

Private Declare Function DefWindowProc Lib "user32" Alias _
   "DefWindowProcA" (ByVal hwnd As Long, ByVal wMsg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function CallWindowProc Lib "user32" Alias _
   "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
   ByVal hwnd As Long, ByVal Msg As Long, _
   ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias _
   "SetWindowLongA" (ByVal hwnd As Long, _
   ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Sub CopyMemoryToMinMaxInfo Lib "KERNEL32" Alias _
   "RtlMoveMemory" (hpvDest As MINMAXINFO, ByVal hpvSource As Long, _
   ByVal cbCopy As Long)
Private Declare Sub CopyMemoryFromMinMaxInfo Lib "KERNEL32" Alias _
   "RtlMoveMemory" (ByVal hpvDest As Long, hpvSource As MINMAXINFO, _
    ByVal cbCopy As Long)

Public Sub Hook()
  'Start subclassing.
  lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, AddressOf WindowProc)
End Sub

Public Sub Unhook()
  Dim temp As Long
  'Cease subclassing.
  temp = SetWindowLong(gHW, GWL_WNDPROC, lpPrevWndProc)
End Sub

      Function WindowProc(ByVal hw As Long, ByVal uMsg As Long, _
         ByVal wParam As Long, ByVal lParam As Long) As Long
          Dim MinMax As MINMAXINFO

          'Check for request for min/max window sizes.
          If uMsg = WM_GETMINMAXINFO Then
              'Retrieve default MinMax settings
              CopyMemoryToMinMaxInfo MinMax, lParam, Len(MinMax)

              'Specify new minimum size for window.
              MinMax.ptMinTrackSize.x = 200
              MinMax.ptMinTrackSize.y = 200

              'Specify new maximum size for window.
              MinMax.ptMaxTrackSize.x = 500
              MinMax.ptMaxTrackSize.y = 500

              'Copy local structure back.
              CopyMemoryFromMinMaxInfo lParam, MinMax, Len(MinMax)

              WindowProc = DefWindowProc(hw, uMsg, wParam, lParam)
          Else
              WindowProc = CallWindowProc(lpPrevWndProc, hw, uMsg, _
                 wParam, lParam)
          End If
      End Function


Только учти, прежде чем завершать задачу, тебе надо вернуть стандартный обработчик. Если ты остановишь этот пример в IDE, то слетит IDE.

[Александр Андреев]

Мда, перехватывать сообщения через хуки это конечно высший пилотаж
Спасибо.

[v-adix]

не совсем понял вопрос, какие именно сообщения надо перехватывать. MIN,MAX,щелчок по заголовку могу сказать как отловить. ты об этом спрашивал?

[Александр Андреев]

Нет. Есть такое сообщение в Виндосе - WM_GETMINMAXINFO, которое посылается окну при попытке изменения его размеров, и запрашивает у этого окна границы, в пределах которых можно эти размеры менять. Я хотел узнать как такое сообщение обрабатывать в VB. Узнал, благодаря alibek'у. Но тебе тоже спасибо.