воспроизведение midi файлов

[кофейник]

Помогите пожалуйста новичку в следующем вопросе:
Сделал я форму с двумя кнопками Command1 и Command2
Задумка в том чтобы при нажатии на кнопку Command1 начинал проигрываться файл 1.mid, а при нажатии на Command2 либо закрытии формы воспроизведение прекращалось. При этом при загрузке формы доступна только Command1, и при нажатии на Command1 она становиться недоступной, но становиться доступной Command2
В итоге написал я вот такой код:

Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long
Private Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" (ByVal lpszSoundName As String, ByVal uFlags As Long) As Long

Private Sub Command1_Click()
Const m_MIDI = "1.mid"
Const m_MIDIAlias = "MyFile"
sndPlaySound "1.mid", 1
mciSendString "OPEN " + m_MIDI + " TYPE SEQUENCER ALIAS " + m_MIDIAlias, 0&, 0, 0
mciSendString "PLAY " + m_MIDI + " FROM 0", 0&, 0, 0
mciSendString "CLOSE ANIMATION", 0&, 0, 0
Command1.Enabled = False
Command2.Enabled = True
End Sub

Private Sub Command2_Click()
Const m_MIDI = "1.mid"
Const m_MIDIAlias = "MyFile"
sndPlaySound "1.mid", 1
mciSendString "OPEN " + m_MIDI + " TYPE SEQUENCER ALIAS " + m_MIDIAlias, 0&, 0, 0
mciSendString "STOP " + m_MIDI, 0&, 0, 0
mciSendString "CLOSE ANIMATION", 0&, 0, 0
Command2.Enabled = False
Command1.Enabled = True
End Sub

Private Sub Form_Load()
Command2.Enabled = False
End Sub

Private Sub Form_Unload(Cancel As Integer)
Const m_MIDI = "1.mid"
Const m_MIDIAlias = "MyFile"
sndPlaySound "1.mid", 1
mciSendString "OPEN " + m_MIDI + " TYPE SEQUENCER ALIAS " + m_MIDIAlias, 0&, 0, 0
mciSendString "STOP " + m_MIDI, 0&, 0, 0
mciSendString "CLOSE ANIMATION", 0&, 0, 0
End Sub

В итоге все вроде бы работает. Однако, проблема в следующем. Когда я нажимаю на Command2 воспроизведение музыки прекращается, однако когда я после этого не закрывая формы нажимаю на Command1 то воспроизведение снова не начинается, и комп. зависает
Вопросы:
1. Почему это происходит?
2. Как это устранить, то есть сделать так, чтобы при нажатии на Command1 музыка начинала играть, после нажатия на Command2 воспроизведение останавливалось, после чего при нажатии на Command1 начинала играть снова.

По возможности дайте ответ более «разжованный» так как я новичок и многих аспектов VB еще не знаю.
Заранее благодарю.

[Vovik]

У меня есть пример проги для проигрывания миди, но она работает через DirectX 7.... Если хошь, я могу скинуть на мыло!

[кофейник]

Да если можно
rtuu@rambler.ru
спасибо!

[Vovik]

Да если можно
спасибо!

Конечно мона!!! Даже нуна...

[Amed]

'А зачем DirectX

'На форме 2 CommandButton
Option Explicit

Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, ByVal uRetrunLength As Long, ByVal hwndCallback As Long) As Long

Private Sub Command1_Click()
'Playing
Call mciSendString("play midi1", 0, 0, 0)
Command2.Enabled = True
Command1.Enabled = False
End Sub

Private Sub Command2_Click()
Command2.Enabled = False
Command1.Enabled = True
'Stopping
Call mciSendString("stop midi1", 0, 0, 0)
End Sub

Private Sub Form_Load()
'Opening
Call mciSendString("open C:\midi_file.mid type sequencer alias midi1", 0, 0, 0)
End Sub

Private Sub Form_Unload(Cancel As Integer)
'Stopping & Closing
Call mciSendString("stop midi1", 0, 0, 0)
Call mciSendString("close midi1", 0, 0, 0)
End Sub

[Oxygen]

Кстати, если через DirectX, то у меня есть небольшая компонента, которая это дело облегчает (там Direct Sound и Direct Music можно юзать). Тока писала для себя и она немного сырая. Но если хочешь, могу дать.

[Amed]

А всё-таки, зачем DirectX, если можно проще?

Возможно, в приложении (скажем, DirectX игре) будет целесообразнее использовать методы DX, но где компьютер более "свободен" по части ресурсов? Мне кажется, методы API более быстры и менее ресурсоёмки... Подскажите, профессионалы! Может, кто-нибудь тест проведёт, а?

[Oxygen]

А ты хоть раз пробывал одновременно воспроизводить 3-4 миди (или wav) файла через API? У меня не получилось... Для этого -то как раз Direct Sound и Direct Music и юзают.

[Amed]

Несколько wav'ов у меня получалось, с midi не пробовал...

Кстати, если не трудно, выложи здесь исходник на DX или кинь на мыло svinets@rambler.ru

[Oxygen]

Тут 2 архива - один исходник (только проект я не нашла - только сам ctl файл). А второй компонетта - может кому пригодится, там краткая справка есть.

[Vovik]

Спорьте, не спорьте, а DirectX - FOREVER

[Yurich]

Ого, какие жаркие дебаты! У меня проблема чуть в другом:
Если запущен WinAmp, то при попытке запуска проги с DirectSound система стает колом ...

[Oxygen]

А какой у тебя WinAmp и система какая? У меня все нормально.

[Vovik]

Хм...странно...и у меня всё работает...

[Yurich]

У меня VinAmp 3.0 beta , Win98, Creative 128. Правда, я не уверен, что в проге абсолютно все правильно.

[кофейник]

Amed и Vovik спасибо оба Ваши совета работают!
Все отлично, спасибо за помощь.

[FaKk2]

У Винампа, есть различные плагини воспроизведения
Один из них DirectSound...

[Vovik]

Amed и Vovik спасибо оба Ваши совета работают!
Все отлично, спасибо за помощь.

Не стоит.... Если что, обращайся...

[GreenT]

Люди ПАМАГИТЕ !!!

Вот как описано тут, все просто супер работает

Private Sub Command1_Click()
'Playing
Call mciSendString("play midi1", 0, 0, 0)
Command2.Enabled = True
Command1.Enabled = False
End Sub

Private Sub Command2_Click()
Command2.Enabled = False
Command1.Enabled = True
'Stopping
Call mciSendString("stop midi1", 0, 0, 0)
End Sub

Private Sub Form_Load()
'Opening
Call mciSendString("open C:\midi_file.mid type sequencer alias midi1", 0, 0, 0)
End Sub

Private Sub Form_Unload(Cancel As Integer)
'Stopping & Closing
Call mciSendString("stop midi1", 0, 0, 0)
Call mciSendString("close midi1", 0, 0, 0)
End Sub

Только единственная проблема. Если в пути файла (в имени папки) есть пробел то оно отказывается проигрывать файл!!!

Что делать???

[GSerg]

А не заключить ли этот путь в кавычки?

[GreenT]

Пишет - синтаксис эрор!!! Народ ну должен же быть какой то способ???

[GSerg]

Бейсик пишет? Так кавычки как вставляются в строку?! Парами!!

[GreenT]

Если пишешь вот так

Call mciSendString("open "c:\midi_file.mid" type sequencer alias midi1", 0, 0, 0)

то пишет синтакси эррор. Т.е. пишешь кавычки вокруг пути и имени файла.
Но я кажется нашел как обойти это бяку. Можно переписать файл и директории программы в c:\ и такой путь не будет содержать пробелов.
Но более грамотно будет переписать этот файл во времменую папку виндовз. Остаётся только 1 вопрос. Как узнать имя и путь времменой папки.

[RayShade]

могу посоветовать также просто писать 2 кавычки подряд, говорят, помогает

[A.A.Z.]

А

Код: Выделить всё

Call mciSendString("open " & Chr(34) & "c:\midi_file.mid" & Chr(34) & " type sequencer alias midi1", 0, 0, 0)


не подойдёт?

[GreenT]

Супер

Код: Выделить всё

Private Sub Form_Load()
temp = "open " + Chr(34) + "c:\t emp\kolobki.mid" + Chr(34) + " type sequencer alias midi1"
Call mciSendString(temp, 0, 0, 0)
End Sub


Вот так работает даже если пробел есть.