Создание пользовательского меню

[Annushka]

Всем доброго времени суток!
Хочу добавить в стандартное меню свой пункт и 2 подменю.
Получаю пункт меню "Мое меню" и рядом еще 2 пустых пукта.
Подскажите, пожалуйста, что не так делаю.

Текст:

Код: Выделить всё


Private Sub Workbook_Open()

Const menuname = "Мое меню"

Dim num As Integer
num = Application.CommandBars("Worksheet Menu Bar").Controls.Count
num = num + 1

Dim a As CommandBarControl
Set a = Application.CommandBars("Worksheet Menu Bar").Controls.Add(Type:=msoControlPopup, Before:=num)
a.Caption = menuname

With Application.CommandBars("Worksheet Menu Bar")
    Set mButton = .Controls.Add(Type:=msoControlButton)
    With mButton
         .Caption = "Подменю1"
         .OnAction = "MySub1"
    End With
    Set mButton1 = .Controls.Add(Type:=msoControlButton)
    With mButton1
         .Caption = "Подменю2"
         .OnAction = "MySub2"
    End With
End With

End Sub


[GSerg]

Код: Выделить всё

with Application.CommandBars("Worksheet Menu Bar").Controls.Add(Type:=msoControlPopup)
  .Caption = menuname
  with .Controls.Add(Type:=msoControlButton)
    .Caption = "Подменю1"
    .OnAction = "MySub1"
  end with
  with .Controls.Add(Type:=msoControlButton)
    .Caption = "Подменю2"
    .OnAction = "MySub2"
  end with
end with

[Annushka]

Спасибо огромное, GSerg
И отдельное спасибо за оперативность.
Все получилось