Пауза на VB

[learnet]

Как сделать паузу, чтоб скажем в мс её можно было задавать

[Amed]

Код: Выделить всё

'This project needs a button
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub Command1_Click()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Me.Caption = "Your system will sleep 5 sec."
    'Sleep for 5000 milliseconds
    Sleep 5000
    Me.Caption = ""
End Sub
Private Sub Form_Load()
    Me.Caption = ""
    Command1.Caption = "Sleep ..."
End Sub

[kirrun]

Нууу... первое что приходит в голову - сделать таймер. Когда надо сделать паузу ты его енаблишь, а остаток кода дописываешь в таймер...

Не самый лучший вариант...

[kirrun]

Код: Выделить всё

'This project needs a button
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub Command1_Click()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Me.Caption = "Your system will sleep 5 sec."
    'Sleep for 5000 milliseconds
    Sleep 5000
    Me.Caption = ""
End Sub
Private Sub Form_Load()
    Me.Caption = ""
    Command1.Caption = "Sleep ..."
End Sub

Имхо немного не то... Это штука прогу подвешивает, а надо паузу сделать...

[xolod]

Имхо немного не то... Это штука прогу подвешивает, а надо паузу сделать...

А что такое пауза, по вашему?
Она замораживает тред (thread), а не вешает программу.

[Faust]

Может быть, человек хочет дать юзеру время полюбоваться результатами, а потом работать дальше? Тогда где-то так:

Код: Выделить всё

Dim t as single
t=timer
while timer-t<10
Doevents
wend

[kirrun]

Имхо немного не то... Это штука прогу подвешивает, а надо паузу сделать...

А что такое пауза, по вашему?
Она замораживает тред (thread), а не вешает программу.

П онашему пауза - промежуток времени между выполнением кода. А Sleep именно вешает программу. Убедится легко: замораживаем, разворачиваем любое окно, потом сворачиваем его. И убеждаемся, что прога в чистом виде поисла. Да и еще минус: Все команды, выполненые (кнопки, нажатые) потом выполняются.

[Ruslan Demidow]

Имхо немного не то... Это штука прогу подвешивает, а надо паузу сделать...

А что такое пауза, по вашему?
Она замораживает тред (thread), а не вешает программу.

П онашему пауза - промежуток времени между выполнением кода. А Sleep именно вешает программу.

В окнах все программы работают за счет событий и сообщений (по крайней мере те, которые имеют форму). Если ты говоришь программе "спать минуту" - она это честно делает (т.е. не реагирует на сообщения и не генерирует событий). А ты чего хотел?
А вот если ты хотел сделать просто остановку выполнения основного когда программы, но при этом обрабатывать события от некоторых контролов - это уже другое.

[xolod]

Да он ничего не хотел. Он только догадки строит.
Это learnet'у надо что-то конкретное, просто объяснение не совсем развернутое дал.

[learnet]

А вот если ты хотел сделать просто остановку выполнения основного когда программы, но при этом обрабатывать события от некоторых контролов - это уже другое.

Вот мне так и надо

[GSerg]

Тогда есть мнение о неправильной организации программы вообще
Чё она делает?

[kirrun]

Я ж уже предложил, правда не лучший вариант (тот, что с таймером)...

[learnet]

Тогда есть мнение о неправильной организации программы вообще
Чё она делает?

В общем мнение было правильное Спасибо за беспокойство, НО, всеравно неужели нет паузы обыкновенной????

[Amed]

Обыкновенной - нет.

[ALX_2002]

Так норм ?

Код: Выделить всё

Private Declare Function GetTickCount Lib "kernel32" () As Long
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub Form_Activate()
MsgBox "Пауза началась"
Pause 1000
MsgBox "Пауза закончилась"
End Sub
Sub Pause(PauseTime As Long)
Dim TM As Long
TM = GetTickCount
Do
If GetTickCount - TM > PauseTime Then
   Exit Do
End If
Sleep 2
DoEvents
Loop
End Sub


[learnet]

Хм, работает спасибо!!!!!!!!!!!!

[hCORe]

ALX_2002:
А теперь проверь загрузку процессора. 100%
А вот у таймеров такого эффекта нет

[kirrun]

Это да... Вывод: kirrun прав с самого начала. Надо делать таймер =)

[learnet]

У меня почемуто нет такой загрузки
Может у меня ООООчень крутой комп
До 2 % поднялась мах

[ALX_2002]

2 hCORE: проверил, и желаю проверить и тебе

у меня даже на процент не грузит проц

[ALX_2002]

Хотите таймер вот вам реальный таймер, который не нужно на форму пихать

пример с www.allapi.net

Код: Выделить всё

' This project requires a Form and a Module
' The Form must have two command buttons (Command1
' and Command2) on it.
'
'In a form
Private Declare Function CreateTimerQueue Lib "kernel32.dll" () As Long
Private Declare Function CreateTimerQueueTimer Lib "kernel32.dll" (ByRef phNewTimer As Long, ByVal TimerQueue As Long, ByVal Callback As Long, ByVal Parameter As Long, ByVal DueTime As Long, ByVal Period As Long, ByVal Flags As Long) As Long
Private Declare Function DeleteTimerQueue Lib "kernel32.dll" (ByVal TimerQueue As Long) As Long
Private Declare Function DeleteTimerQueueTimer Lib "kernel32.dll" (ByVal TimerQueue As Long, ByVal Timer As Long, ByVal CompletionEvent As Long) As Long
Private hQueue As Long
Private hTimer As Long
Private Sub Form_Load()
    'KPD-Team 2002
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@allapi.net
    hQueue = CreateTimerQueue()
    Command1.Caption = "Start"
    Command2.Caption = "Stop"
End Sub
Private Sub Form_Unload(Cancel As Integer)
    DeleteTimerQueue hQueue
End Sub
Private Sub Command1_Click()
    If hTimer = 0 Then
        CreateTimerQueueTimer hTimer, hQueue, AddressOf TimerCallBack, ByVal 0&, 0, 1000, 0
    End If
End Sub
Private Sub Command2_Click()
    If hTimer <> 0 Then
        DeleteTimerQueueTimer hQueue, hTimer, ByVal 0&
        hTimer = 0
    End If
End Sub

'In a module
Public Sub TimerCallBack(ByVal lpParameter As Long, ByVal TimerOrWaitFired As Long)
    Debug.Print "Timer callback..."
End Sub