Помогите с кодом.

[olegvikt]

Как написать такую программу,которая показывает содержимое каталога, включая содержимое подкаталогов?

[Александр Андреев]

Воспользуйся апишными функциями FindFirstFile и FindNextFile.
Далее сдалай процедуру, которая будет вызываться рекурсивно для каждого найденного подкаталога. Пусть она принимает путь к каталогу и возвращает массив найденных в этом каталоге файлов.

[Cyrax]

блин... третий раз в форум этот пример отправляю
первый раз еще на старом было. вы что товарищи поиском пользоваться не умеете? или книжек у вас нет?

ладно вот вам пример и ссылка на умную книжку (а вдруг кому пригодится)

Введите этот код в модуль новой формы, запустите программу, и в текущем рабочем каталоге появится файл FILETREE.TXT. Закончив работу, программа автоматически завершится.

Код: Выделить всё

Option Explicit

Sub RecurseTree(CurrentPath As String)
    Dim nI As Integer, nDirectory As Integer
    Dim sFileName As String, sDirectoryList() As String
    ' сначала перечисляем все обычные файлы в текущем каталоге
    sFileName = Dir(CurrentPath)
    Do While sFileName <> ""
        Print #1, CurrentPath & sFileName
        sFileName = Dir
    Loop
    ' теперь формируем временный список подкаталогов
    sFileName = Dir(CurrentPath, vbDirectory)
    Do While sFileName <> ""
        ' игнорируем текущий и родительские каталоги
        If sFileName <> "." And sFileName <> ".." Then
            ' игнорируем все отличное от каталогов
            If GetAttr(CurrentPath & sFileName) And vbDirectory Then
                nDirectory = nDirectory + 1
                ReDim Preserve sDirectoryList(nDirectory)
                sDirectoryList(nDirectory) = CurrentPath & sFileName
            End If
        End If
        sFileName = Dir
        ' обрабатываем другие события
        DoEvents
    Loop
    ' рекурсивно обрабатываем каждый каталог
    For nI = 1 To nDirectory
        RecurseTree sDirectoryList(nI) & ""
    Next nI
End Sub

Private Sub Form_Load()
    Dim sStartPath As String
    Me.Show
    Print "Working..."
    Me.MousePointer = vbHourglass
    sStartPath = "C:"
    Open "FILETREE.TXT" For Output As #1
    RecurseTree sStartPath
    Close
    Me.MousePointer = vbDefault
    Unload Me
End Sub


[viking]

использовал твой код в своей программе, но почемуто программа может работать только с каталогом С:\, a c ocтальными не хочет
вот код

Option Explicit

Sub RecurseTree(CurrentPath As String)
Dim nI As Integer, nDirectory As Integer
Dim sFileName As String, sDirectoryList() As String
sFileName = Dir(CurrentPath & "*.txt")
Do While sFileName <> ""
List1.AddItem CurrentPath & sFileName
sFileName = Dir
Loop
sFileName = Dir(CurrentPath, vbDirectory)
Do While sFileName <> ""
If sFileName <> "." And sFileName <> ".." Then
If GetAttr(CurrentPath & sFileName) And vbDirectory Then
nDirectory = nDirectory + 1
ReDim Preserve sDirectoryList(nDirectory)
sDirectoryList(nDirectory) = CurrentPath & sFileName
End If
End If
sFileName = Dir
DoEvents
Loop
For nI = 1 To nDirectory
RecurseTree sDirectoryList(nI) & "\"
Next nI
End Sub

Private Sub Command1_Click()
Dim startpath As String
startpath = Dir1.Path
RecurseTree startpath
End Sub

Private Sub Drive1_Change()
Dir1.Path = Drive1.Drive
End Sub

[ANDLL]

А ты не пробовал:
startpath = Dir1.Path & "\"

[_NeoN_]

А смысл спрашивать если данный тебе код даже не смотришь???? не понимаю...