Внешний ЕХЕ в своей MDI форме

[shady]

Есть программа написанная на Delphi для удобства пользователей хотелось бы "встроить" ее в свое MDI приложение.
Это реально?

[xqz_me]

Угу. Через SetParent. Даже пример буквально пару дней назад в теме про "аэро" выкладывали (потом, видимо, потёрли).

[Alex[fj]]

Вот...

Код: Выделить всё

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As Long, ByVal lpWindowName As Long) As Long
Private Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function LockWindowUpdate Lib "user32" (ByVal hwndLock As Long) As Long
Private Declare Function GetDesktopWindow Lib "user32" () As Long
Private Declare Function DestroyWindow Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function TerminateProcess Lib "kernel32" (ByVal hProcess As Long, ByVal uExitCode As Long) As Long
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function Putfocus Lib "user32" Alias "SetFocus" (ByVal hwnd As Long) As Long
Const GW_HWNDNEXT = 2
Dim mWnd As Long
Function InstanceToWnd(ByVal target_pid As Long) As Long
    Dim test_hwnd As Long, test_pid As Long, test_thread_id As Long
    'находим окно
    test_hwnd = FindWindow(ByVal 0&, ByVal 0&)
    Do While test_hwnd <> 0
        'проверяем на "родителей"
        If GetParent(test_hwnd) = 0 Then
           
            test_thread_id = GetWindowThreadProcessId(test_hwnd, test_pid)
            If test_pid = target_pid Then
                InstanceToWnd = test_hwnd
                Exit Do
            End If
        End If
       
        test_hwnd = GetWindow(test_hwnd, GW_HWNDNEXT)
    Loop
End Function
Private Sub Form_Load()
   
    Dim Pid As Long
        LockWindowUpdate GetDesktopWindow
    'открываем блокнот
    Pid = Shell("c:\windows\notepad.exe", vbNormalFocus)
    If Pid = 0 Then MsgBox "Error starting the app"
   
    mWnd = InstanceToWnd(Pid)
    'задаем родителя блокноту
    SetParent mWnd, Me.hwnd
   
    Putfocus mWnd
   
    LockWindowUpdate False
End Sub
Private Sub Form_Unload(Cancel As Integer)
    'выгружаем блокнот
    DestroyWindow mWnd
    'завершаем программу
    TerminateProcess GetCurrentProcess, 0
End Sub