ПОиск и выделение слов в документе Word

[Nikbor]

Необходимо написать макрос, который бы находил и выделял (например красным цветом) необходимые слова в документе Word. Список слов хранится в текстовом файле. Написал следующий код:

Sub ChDoc()
intFH = FreeFile
Open "c:\Docs\CheckWords.txt" For Input As intFH
Do Until EOF(intFH)
Line Input #intFH, strString
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find.Replacement.Font
.Color = wdColorRed
End With
With Selection.Find
.Text = strString
.Replacement.Text = strString
.Forward = True
End With
Selection.Find.Execute Replace:=wdReplaceAll
Loop
Close #intFH
End Sub

Но этот код ищет каждое отдельное слово по всему документу, поэтому экран мельтешит при выполнении. Список слов довольно большой.
А как можно сделать, чтобы поиск и выделение происходил построчно? Тогда думаю, что экран бы не мелькал.

[corgi]

чтоб экран не мельтешил в начале процедуры поставь
Application.ScreenUpdating = False
а в конце
Application.ScreenUpdating = True

[Tanya]

Чтобы экран не мельтешил никогда не используй SELECTION!!!
Если, конечно тебе не нужны эти спецэффекты
Можно попробовать так:

Код: Выделить всё

Sub ChDoc()
Dim i As Integer, sBuff As String, mas() As String, FileName As String
i = FreeFile
FileName = "c:\Docs\CheckWords.txt"
Open FileName For Input As #i
    sBuff = Input(FileLen(FileName), #i)
Close
mas = Split(sBuff, vbCrLf)
With Application.ActiveDocument.Range.Find
Debug.Print Application.ActiveDocument.Name
    For i = 0 To UBound(mas)
        If Trim(mas(i)) <> "" Then
            .ClearFormatting
            .Replacement.ClearFormatting
            .Replacement.Font.Color = wdColorRed
            .Text = mas(i)
            .Replacement.Text = mas(i)
            .Forward = True
            .Execute Replace:=wdReplaceAll
        End If
    Next i
End With
End Sub

[Tanya]

Sorrrrrrry!!! Переумничала
Конечно, если искать в выделенном фрагменте, то SELECTION!!!

corgi - бог, он прав!!!

[Annabel]

Глупый вопрос от чайника. У меня сходная задача - есть текстовый файл, в котором содержится список слов, выглядит вот так:
слово1 [tab] термин1
слово2 [tab] термин2
слово3 [tab] термин3

и т.д.

Мне нужен макрос, который находил бы в тексте по-очереди слово1, слово2 и т.д. и заменял его на термин1, 2, соответственно.

Не подскажете, как это сделать?


Спасибо!